dev-python/qscintilla-python: add 2.11.6

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Davide Pesavento <pesa@gentoo.org>

dev-python/qscintilla-python/Manifest

@@ -1 +1,2 @@
 DIST QScintilla-2.11.5.tar.gz 3007564 BLAKE2B e1eb7794b2e09f7bbfebde69a7c62c1a952e36b95f9c7a38c3db0b6bbdab8d0bad4a6d780dc9bf9b5e8d64111046f1741c6710d8444504230ee0f4154ce0a304 SHA512 46bc3c896b4ab71fbcc821ce3a248ecc4200378e0b621adef8d39092f940928806c76abe529b7f27ce4280e7e49091d8cbeafe6f303ca85cf5675df2887fd99b
+DIST QScintilla-2.11.6.tar.gz 3027764 BLAKE2B 1eb5d9ba44040cbff30e8b0028e164cf2aa86c565a5368890500614b9395dbe861c5cd268cf6a4ec06e2c7d77860b2ad6064bc3d07fd63a6ede2b060f44a7117 SHA512 8055d72a40f9f5a7d45c6592055c1b8eb5e5c50ce9e51673babd5e567c769d60c64d244ba5a7def5731a3120099e9528d01ed94327a06bb56ae2fa2e5e37b198

dev-python/qscintilla-python/qscintilla-python-2.11.6.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+inherit python-r1 qmake-utils
+
+DESCRIPTION="Python bindings for QScintilla"
+HOMEPAGE="https://www.riverbankcomputing.com/software/qscintilla/intro"
+
+MY_PN=QScintilla
+MY_P=${MY_PN}-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+else
+	SRC_URI="https://www.riverbankcomputing.com/static/Downloads/${MY_PN}/${PV}/${MY_P}.tar.gz"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="debug"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/PyQt5-5.12[gui,printsupport,widgets,${PYTHON_USEDEP}]
+	>=dev-python/PyQt5-sip-4.19.22:=[${PYTHON_USEDEP}]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwidgets:5
+	~x11-libs/qscintilla-${PV}:=
+"
+DEPEND="${RDEPEND}
+	>=dev-python/sip-4.19.22[${PYTHON_USEDEP}]
+"
+
+S=${WORKDIR}/${MY_P}/Python
+
+src_configure() {
+	configuration() {
+		local myconf=(
+			"${PYTHON}"
+			"${S}"/configure.py
+			--pyqt=PyQt5
+			--qmake="$(qt5_get_bindir)"/qmake
+			$(usex debug '--debug --trace' '')
+			--verbose
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+
+		# Fix parallel install failure
+		sed -i -e '/INSTALLS += distinfo/i distinfo.depends = install_subtargets install_pep484_stubs install_api' \
+			${MY_PN}.pro || die
+
+		# Run eqmake to respect toolchain and build flags
+		eqmake5 -recursive ${MY_PN}.pro
+	}
+	python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		emake INSTALL_ROOT="${D}" install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installation
+}