gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-23 16:49:10 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/hypothesis: Bump to 6.14.8

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2021-08-17 08:06:35 +02:00
parent 27174cb152
commit 3666d03478
2 changed files with 63 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hypothesis/Manifest
View File

@@ -1,2 +1,3 @@
DIST hypothesis-python-6.14.5.tar.gz 9135819 BLAKE2B 2e42949f81024038b901231a8446203388c8052ebaacf4a87d21356265fd1c09c9aa8b191dcd65780d45cc52ed9d48bb16440fc553addb4671e0ad901213ef64 SHA512 d047eea19129d5855bee5f012f5c91fe1f0de40228600fadad9c76709f951c003450f613f59848064b58f9d0e559b54b44744ae0aae689687488b6506cc8fe1a
DIST hypothesis-python-6.14.7.tar.gz 9136527 BLAKE2B 46176df0ffac48d3bff68a83b03b316506236e8a89365c419d61d0e8dae98a54961da3715377475ba7ce89d9d989e63b75eed1473758896c13bc8c0937617b12 SHA512 bb04434893c7cf937c1f1fc733fc424b48e87ec00d3f650ad85b1749b37f18b3a4718c346739d9121b4461d46516ee1af934a34922cc6ec626defa5ffb1e531b
DIST hypothesis-python-6.14.8.tar.gz 9137594 BLAKE2B 421c3fdb13e172bdb93cd15f625dd1fbae576ab37b48181eb82e6f1ebed92284a3c2ea4d0314f9dfd735f3ccd968465b28b94525614a7cb0834985f8cdae79df SHA512 3f99bf54e01a7d6945d898b8065b3241a1d9fc871adc9e3bec9cfe187e36651aee78eb57fa69e28405a668a0f784a5dc90acf213211d0c060a1e9a82de8e243e

62
dev-python/hypothesis/hypothesis-6.14.8.ebuild Normal file
View File

@@ -0,0 +1,62 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{8..10} pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 multiprocessing optfeature
DESCRIPTION="A library for property based testing"
HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
IUSE="cli"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' python3_{7..9})
)
"
BDEPEND="
test? (
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
!!dev-python/pytest-describe
!!<dev-python/typing-3.7.4.1
)
"
distutils_enable_tests --install pytest
python_prepare() {
if ! use cli || ! has "${EPYTHON}" python3.{7..9}; then
sed -i -e '/console_scripts/d' setup.py || die
fi
}
python_test() {
distutils_install_for_testing
epytest tests/cover tests/pytest tests/quality \
-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}