dev-python/jaraco-collections: bump to 1.5

Package-Manager: portage-2.3.0

dev-python/jaraco-collections/Manifest

@@ -1,2 +1,3 @@
 DIST jaraco.collections-1.4.1.tar.gz 10456 SHA256 43d0221be38fa0d8da339a149829800c8c3f843f379c09f3f8f1d99125110936 SHA512 1f9eca787efb427a73b5f03e144a2a95e5740580e21e9857a376d76dd35f39066c3a06056eaf78f72de2f97e4fc70805467fcc516f989ba4785e3f3d9354a538 WHIRLPOOL c37a851f1ab041554c1d9a54565e5671350bc750d31d1569a4415c5c215557739145b3a4992546d715a013695ef86cb788c47b4eb72940a29fdc17a9300399bb
 DIST jaraco.collections-1.4.tar.gz 9615 SHA256 82af38e4f8ef59ef5b44738561dd766f944e145a7ce39751744783f70f779ccb SHA512 dbb7c07bd6a7b4ef41aad1fef55b760447c94aea7036b56ed6fc02deba0720c2cb644fa47598f3997a307343dd1672d4afdd745fad3e02e37257ea714c02634a WHIRLPOOL 05c22e5b1c0d3725c4f0f486ff628991103643264c0e3338172d585be155eb2ba509182b652ed5484cd07cad13b0486829df2e8e9abd5450d7417ffb19d491f4
+DIST jaraco.collections-1.5.tar.gz 10615 SHA256 7af6aedcf1601eca23d4411727caa201c0fdb80d2ec40f63d5f0942529f971d6 SHA512 7e2d3849d26422d687cfeb560f8096fb099a9c7b99b3061a06f9ad7037c3805b577754f62e5d5ead3f6f89bcd7dbf574df2844aa3c28928941ea2c99d50fc161 WHIRLPOOL 91a5c6c09d8b46231a409abea40e43a80a165a17e4f23be05d5341446630cf31d94880f37bbba0cd8c9cc1cb27fc6b698cd18d07e9342f1cec0fc2453ad88378

dev-python/jaraco-collections/jaraco-collections-1.5.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Models and classes to supplement the stdlib collections module"
+HOMEPAGE="https://github.com/jaraco/jaraco.collections"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+PDEPEND="dev-python/jaraco-text[${PYTHON_USEDEP}]"
+RDEPEND="dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.9[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/rst-linker[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_prepare_all() {
+	if use test && ! has_version "dev-python/jaraco-text"; then
+		die "Ensure dev-python/jaraco-text is installed or the" \
+			"test suite will fail"
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	PYTHONPATH=. py.test || die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	distutils-r1_python_install_all
+}

dev-python/jaraco-collections/metadata.xml

@@ -13,5 +13,6 @@
 		<remote-id type="pypi">jaraco.collections</remote-id>
 		<remote-id type="github">jaraco/jaraco.collections</remote-id>
 		<bugs-to>https://github.com/jaraco/jaraco.collections/issues</bugs-to>
+		<changelog>https://github.com/jaraco/jaraco.collections/blob/master/CHANGES.rst</changelog>
 	</upstream>
 </pkgmetadata>