gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-31 09:08:08 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/protobuf-python: Version bump (3.16.0).

Browse Source 
Signed-off-by: Arfrever Frehtes Taifersar Arahesis <Arfrever@Apache.Org>
Signed-off-by: Mike Gilbert <floppym@gentoo.org>
This commit is contained in:
Arfrever Frehtes Taifersar Arahesis
2021-05-28 02:00:00 +00:00
committed by Mike Gilbert
parent cf5d2a2052
commit 35d306f6da
2 changed files with 67 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/protobuf-python/Manifest
View File

@@ -9,3 +9,4 @@ DIST protobuf-3.15.5.tar.gz 5283712 BLAKE2B 0da6255302014c885aee47d48344a75ee480
DIST protobuf-3.15.6.tar.gz 5284018 BLAKE2B 5895f618e233edd5744253821036857aa23f64b76ee3318b99f3530d9dd0c49cc8c386ef15c7394475c2bf0fa33fb631e481fa3fb927c2ab8a88af31234bd0b1 SHA512 673d61b492ce0e85f5c63f3fd7a0174737cc65f7871f79d24380bffa59ea1b312065137ecc63b0f4d4ffa3eb168a09e9c1129c21b0e6c5c3a8c2fabb2cecabb5
DIST protobuf-3.15.7.tar.gz 5284817 BLAKE2B 43821bb283a0c1f87930593046a5c55f6efae3f644337289fd438c0612a9b7ef9531b61e48940b74dc5d20253ee1b6a805b902284a442dec2efe8c79f82c5aad SHA512 2b18ccba1ff8a0623c52abed0e0674bc6cfa2cd10d49764031a47e68f654f54083f4a4f9e3a94d833a6808426904ee642f173641063e79cb41a61fc348d603ac
DIST protobuf-3.15.8.tar.gz 5285277 BLAKE2B 798fc011ac03cdc2406acf5845c667d8482082044bdace06c2c1d02b5b1b69c1b1f30e29774180dc1801a1d21d62e2ce50325105859564a1e36d3fe478e64d8b SHA512 56fc6df2dae14eee0fb67dd4204fc1ec54a18d994a69c9e42c7888d0cd50d269d1c5e1445d74f0fa705850d4ac86a22d86781e09769a716e5c6f829b15b05592
DIST protobuf-3.16.0.tar.gz 5299781 BLAKE2B 9ace02a6038c31b7393671fb2ccd6a4866a3f8b7d87d2bc8371f49d65b9180f10792ca2430a83449dfa7d785a1244dac23c20756414c9d1e7c7e871a8038b123 SHA512 0191e5a6a23d03f691e883e259f6d06a0ac8eef427455bc7d1cc70b6f0ed260e4ad8f360c836fd4bdc95ec0ca314c887cbf7acbcda60e03cdfe69e4cd275bff5

66
dev-python/protobuf-python/protobuf-python-3.16.0.ebuild Normal file
View File

@@ -0,0 +1,66 @@
# Copyright 2008-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="7"
PYTHON_COMPAT=(python{3_7,3_8,3_9})
DISTUTILS_USE_SETUPTOOLS="bdepend"
inherit distutils-r1
if [[ "${PV}" == "9999" ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/protocolbuffers/protobuf"
EGIT_SUBMODULES=()
fi
DESCRIPTION="Google's Protocol Buffers - Python bindings"
HOMEPAGE="https://developers.google.com/protocol-buffers/ https://github.com/protocolbuffers/protobuf"
if [[ "${PV}" == "9999" ]]; then
SRC_URI=""
else
SRC_URI="https://github.com/protocolbuffers/protobuf/archive/v${PV}.tar.gz -> protobuf-${PV}.tar.gz"
fi
LICENSE="BSD"
SLOT="0/27"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
IUSE=""
BDEPEND="${PYTHON_DEPS}
~dev-libs/protobuf-${PV}
dev-python/namespace-google[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]"
DEPEND="${PYTHON_DEPS}
~dev-libs/protobuf-${PV}"
RDEPEND="${BDEPEND}
!<dev-libs/protobuf-3[python(-)]"
S="${WORKDIR}/protobuf-${PV}/python"
if [[ "${PV}" == "9999" ]]; then
EGIT_CHECKOUT_DIR="${WORKDIR}/protobuf-${PV}"
fi
python_prepare_all() {
pushd "${WORKDIR}/protobuf-${PV}" > /dev/null || die
eapply "${FILESDIR}/${PN}-3.13.0-google.protobuf.pyext._message.PyUnknownFieldRef.patch"
eapply_user
popd > /dev/null || die
distutils-r1_python_prepare_all
}
python_configure_all() {
mydistutilsargs=(--cpp_implementation)
}
python_test() {
esetup.py test
}
python_install_all() {
distutils-r1_python_install_all
find "${ED}" -name "*.pth" -type f -delete || die
}