app-editors/gedit: Drop old versions

Signed-off-by: Matt Turner <mattst88@gentoo.org>
This commit is contained in:
Matt Turner
2023-09-05 16:28:24 -04:00
parent f57d0c7cf2
commit 35649aa078
2 changed files with 0 additions and 90 deletions
-1
View File
@@ -1,2 +1 @@
DIST gedit-44.2.tar.xz 2741932 BLAKE2B ef069084b0a11d86a081f10542ddfe39e9a6989dd0d7e5749af3f62267ea52c6885bf3a50065227307cca6062098c460b05da89f1cd2de0b8d2e6c9c81feb8ad SHA512 c9dd412a16d7d0ba17214164017948bd1184ee5f9c44475e9e02880c0597b2fd9840f9488df7262cb413baedf5e16ce49dd32410b02ed0f53cf4bc94d3e3a4c7
DIST gedit-46.1.tar.xz 2756336 BLAKE2B b79c04b12b0220429d6284c9d966e7a8cc2a454b0cd0b7ef807576b4a3e0dccab52f5fdbdaf9f774880c801eb842484260818036e30e5853d573c1fbb4dd14b6 SHA512 42cf210afd35df8d6d3590ebb5ff310b74ccf9da803277cd375474629e2bd32bc542f34e3c307a1f591c04e861b92e153e4c9a2daa852e5250fc1294d4bbf72d
-89
View File
@@ -1,89 +0,0 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit gnome.org gnome2-utils meson python-single-r1 vala xdg
DESCRIPTION="A text editor for the GNOME desktop"
HOMEPAGE="https://wiki.gnome.org/Apps/Gedit"
LICENSE="GPL-2+ CC-BY-SA-3.0"
SLOT="0"
IUSE="+python gtk-doc"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc x86"
DEPEND="
>=dev-libs/glib-2.70:2
>=x11-libs/gtk+-3.22.0:3[introspection]
>=gui-libs/amtk-5.6:=
>=gui-libs/tepl-6.4:=
>=dev-libs/libpeas-1.14.1[gtk]
>=dev-libs/gobject-introspection-1.54:=
>=app-text/gspell-0.2.5:0=
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/pycairo[${PYTHON_USEDEP}]
>=dev-python/pygobject-3:3[cairo,${PYTHON_USEDEP}]
dev-libs/libpeas[python,${PYTHON_SINGLE_USEDEP}]
')
)
>=x11-libs/gtksourceview-4.0.2:4[introspection,vala]
"
RDEPEND="${DEPEND}
x11-themes/adwaita-icon-theme
gnome-base/gsettings-desktop-schemas
gnome-base/gvfs
"
BDEPEND="
$(vala_depend)
app-text/docbook-xml-dtd:4.1.2
dev-util/glib-utils
gtk-doc? ( >=dev-util/gtk-doc-1 )
dev-util/itstool
>=sys-devel/gettext-0.18
virtual/pkgconfig
"
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
default
vala_setup
xdg_environment_reset
}
src_configure() {
local emesonargs=(
$(meson_use gtk-doc gtk_doc)
-Duser_documentation=true
)
meson_src_configure
}
src_install() {
meson_src_install
if use python; then
python_optimize
python_optimize "${ED}/usr/$(get_libdir)/gedit/plugins/"
fi
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}