app-arch/file-roller: Version bump to 3.40.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

app-arch/file-roller/Manifest

@@ -1 +1,2 @@
 DIST file-roller-3.38.1.tar.xz 875572 BLAKE2B 29a05d48971c2172177bd1aa52448ed5432a69733644b131517dbd7dd50cab971801d1bff5837dba74ae48ea0487614c7c7ebd4669f04f7d42e6257161fe1776 SHA512 b1936481140084c84d7bdbf361859b0ff1fed8329e26b692f0f0c8d1a3a1ec494b493aa0fb4de9f0ea5004b18e4bd69859656fe424bf413d720b04fc56e453f6
+DIST file-roller-3.40.0.tar.xz 876424 BLAKE2B fa2483677869d5a6b4ac91938eac6bf09965177ffa07bab76a77a0be58e331466f939e7e0728d5eeeb5703c6ff12f178f8080922f8ae9d726e77700bbbd518ed SHA512 224dbe4f4358aa62589d084d67244ad8d65d718f9b6adf708ba1425b38fca68e08b07a6163f66d95c6acfd164b6062939cfeb27873ea41353e0551e322b0eb26

app-arch/file-roller/file-roller-3.40.0.ebuild

@@ -0,0 +1,93 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+inherit gnome.org gnome2-utils meson python-any-r1 readme.gentoo-r1 xdg
+
+DESCRIPTION="Archive manager for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/FileRoller"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+SLOT="0"
+IUSE="libnotify nautilus"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+# gdk-pixbuf used extensively in the source
+# cairo used in eggtreemultidnd.c
+# pango used in fr-window
+RDEPEND="
+	>=app-arch/libarchive-3.2:=
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/json-glib-0.14
+	>=x11-libs/gtk+-3.22.0:3
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	libnotify? ( >=x11-libs/libnotify-0.4.3:= )
+	nautilus? ( >=gnome-base/nautilus-3.28.0 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="
+${PN} is a frontend for several archiving utilities. If you want a
+particular archive format support, see ${HOMEPAGE}
+and install the relevant package. For example:
+7-zip   - app-arch/p7zip
+ace     - app-arch/unace
+arj     - app-arch/arj
+brotli  - app-arch/brotli
+cpio    - app-arch/cpio
+deb     - app-arch/dpkg
+iso     - app-cdr/cdrtools
+jar,zip - app-arch/zip and app-arch/unzip
+lha     - app-arch/lha
+lzop    - app-arch/lzop
+lz4     - app-arch/lz4
+rar     - app-arch/unrar or app-arch/unar
+rpm     - app-arch/rpm
+unstuff - app-arch/stuffit
+zstd    - app-arch/zstd
+zoo     - app-arch/zoo"
+
+src_prepare() {
+	# File providing Gentoo package names for various archivers
+	cp -v "${FILESDIR}"/3.36-packages.match data/packages.match || die
+
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Drun-in-place=false
+		$(meson_feature nautilus nautilus-actions)
+		$(meson_feature libnotify notification)
+		-Dpackagekit=false
+		-Dlibarchive=enabled
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}