dev-util/seer: add 2.1

I'll keyword it later after some more testing. Hard-switches to Qt 6 given upstream
don't really support Qt 5 now.

Signed-off-by: Sam James <sam@gentoo.org>

dev-util/seer/Manifest

@@ -1,2 +1,3 @@
 DIST seer-1.17.tar.gz 410347 BLAKE2B 6ac10aecc862a669cf9c0a2f25104604bddb3791d48cf8653483edb14a913f8214e7a316f335e115e0df80703610c97d395f6b896406cc19814701f234e319cf SHA512 93a0b148685dcd52eb567c1d58848e65c43208af9505b3bc02202c1be02ed7f94af500a1b5fdb295f0d3cd13dd88e3d6d9a524396c9c37c74435532d3dfbec2d
 DIST seer-2.0.tar.gz 409888 BLAKE2B c39cc0a186a68bad8477262d8900f0b8e632dc2e21504b4157d881b7a2cd6c75d9c0d60e28767bf490c6420e1ca1f17e52c13ef642986d9d94b44b46148270b2 SHA512 ea01ccbc7e457d7a42bf8703da24c2d42c37d81c7c5223b30f5c3837200a8e3137cd5ff5fd6531cf3b3c22b1cf1bec576c68191bfb63a5d55a8527ab8283c04a
+DIST seer-2.1.tar.gz 419994 BLAKE2B b2f2842d3515721f27b9fe5cb5dfc7585feb89cd38ba6f8fff20a62752d1f355887d3956f8c2e31388d887476a8ca63ec878f3a28698b24b99ccee327f9dfa74 SHA512 6e16b4a459e2dc033a03a5c62709553de9f50e770f463a59cf5f6077fce5d2c59d1aba05e163602b11b24e4e560da8b9e9b8708c727421ee6a1943e617a30955

dev-util/seer/seer-2.1.ebuild

@@ -0,0 +1,56 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake desktop xdg
+
+DESCRIPTION="A GUI frontend to gdb"
+HOMEPAGE="https://github.com/epasveer/seer"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/epasveer/seer"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/epasveer/seer/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+	# Unkeyworded until tested a bit more
+	#KEYWORDS="~amd64 ~arm64 ~ppc64"
+fi
+
+S="${WORKDIR}"/${P}/src
+
+# Upstream keep 'debian/copyright' up to date
+# https://github.com/epasveer/seer/issues/86
+LICENSE="GPL-3+ CC-BY-3.0 CC-BY-4.0"
+SLOT="0"
+
+DEPEND="
+	dev-qt/qtbase:6[gui,widgets]
+	dev-qt/qtcharts:6
+	dev-qt/qtsvg:6
+"
+RDEPEND="
+	${DEPEND}
+	sys-devel/gdb
+"
+
+src_configure() {
+	local mycmakeargs=(
+		# Upstream don't really support Qt 5 for >= 2.0:
+		# https://github.com/epasveer/seer/wiki/Building-Seer---Qt5.
+		-DQTVERSION=QT6
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	domenu resources/seergdb.desktop
+
+	local size
+	for size in 32 64 128 256 512 ; do
+		newicon -s ${size} resources/seergdb_${size}x${size}.png seergdb.png
+	done
+}

dev-util/seer/seer-9999.ebuild

@@ -25,11 +25,9 @@ LICENSE="GPL-3+ CC-BY-3.0 CC-BY-4.0"
 SLOT="0"
 
 DEPEND="
-	dev-qt/qtcharts:5
-	dev-qt/qtcore:5
-	dev-qt/qtgui:5
-	dev-qt/qtprintsupport:5
-	dev-qt/qtwidgets:5
+	dev-qt/qtbase:6[gui,widgets]
+	dev-qt/qtcharts:6
+	dev-qt/qtsvg:6
 "
 RDEPEND="
 	${DEPEND}
@@ -38,9 +36,9 @@ RDEPEND="
 
 src_configure() {
 	local mycmakeargs=(
-		# TODO: Support Qt 6 once it's unmasked
-		# Note that >= 2.0 barely supports Qt 5, see https://github.com/epasveer/seer/wiki/Building-Seer---Qt5.
-		-DQTVERSION=QT5
+		# Upstream don't really support Qt 5 for >= 2.0:
+		# https://github.com/epasveer/seer/wiki/Building-Seer---Qt5.
+		-DQTVERSION=QT6
 	)
 
 	cmake_src_configure