app-text/gspell: add 1.14.0

Signed-off-by: Sam James <sam@gentoo.org>

app-text/gspell/Manifest

@@ -1 +1,2 @@
 DIST gspell-1.12.2.tar.xz 442824 BLAKE2B 6a574339dfa4930e5506d63d5f0cf27d8433c2914ce1204edc8366992ebf05bf78d4777029fa17f05be73291510897862c63479e59e72522a4c4943647f66539 SHA512 c13df805f6128cfd19c41e4936fbb49516f80e09d27e79380d5638cbd1a8a3bfc6aae5ef8a4faa748495fe529bde92805bbd5530610b113c58daa36f273a5af8
+DIST gspell-1.14.0.tar.xz 116624 BLAKE2B ca42448dcb99b0d2d4563fff6c9209eeaae0f50dc00d8d3b3032b3d6fa332aea083ce737f15665a2cf2977ed715837a6c850bea0d3eaa82c7f01429ef92ab7ed SHA512 d2e9931f4c37170b483ece9ee50b0af8aa281cf1bde5ac009d2a0c7dd2dbfc90e591df13dd555465c04cccdc2864b788d372625be9f71d6541e6e6b0fd3c4370

app-text/gspell/gspell-1.14.0.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2 meson vala virtualx
+
+DESCRIPTION="Spell check library for GTK+ applications"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gspell"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/2" # subslot = libgspell-1 soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="gtk-doc +introspection test +vala"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	>=app-text/enchant-2.2:2
+	>=dev-libs/glib-2.44:2
+	>=x11-libs/gtk+-3.20:3[introspection?]
+	dev-libs/icu:=
+	introspection? ( >=dev-libs/gobject-introspection-1.42.0:= )
+"
+DEPEND="${RDEPEND}
+	test? ( sys-apps/dbus )
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.6
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+	vala? ( $(vala_depend) )
+	test? (
+		app-text/enchant:2[hunspell]
+		|| (
+			app-dicts/myspell-en[l10n_en(+)]
+			app-dicts/myspell-en[l10n_en-US(+)]
+		)
+	)
+"
+# Tests require a en_US dictionary and fail with deprecated enchant aspell backend:
+# So enchant[hunspell] + myspell-en ensure they pass (hunspell is ordered before aspell),
+# however a different backend like hspell or nuspell + their en_US dict might be fine too,
+# but we don't support them at this time (2020-04-12) in enchant:2
+
+src_prepare() {
+	use vala && vala_setup
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dinstall_tests=false
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection gobject_introspection)
+		$(meson_use test tests)
+		$(meson_use vala vapi)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}