games-roguelike/angband: Version bump to 4.2.3, EAPI 8

Bug: https://bugs.gentoo.org/820500
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

games-roguelike/angband/Manifest

@@ -1,2 +1,4 @@
 DIST angband-4.2.2-man.tar.gz 105892 BLAKE2B 226210bd45f463e2b6bc099f889393832b5ce9bf5f95b5de1bc38fbcef61287515435ceef83a717bd62220fe01d5acf33e3fe240c08e3cf7d04e9d59fee132f1 SHA512 f373ea55c5f2349c615c47207c1dbbcc6a77246fbb0615d00a1fcb2a2a0cdf839bb5d57c2e29a2f2698f2d6b72698fbaec6bb221994566be04046ce03ea6253a
 DIST angband-4.2.2.tar.gz 24992436 BLAKE2B 6beab7d0481167538714f540e9825e930d57457c923b77e2a9be71e8a6e382b70f375e85e68f0ebf9a65b61b835d62df0a5958a21198d9049088cdbe32c81efc SHA512 07a9b6a10a47afafde8f5db1e463c70198d386e07737666e044de291eab4b425d76bc8124153b7c371248f0c9aedc01578a90e513d744e3f30d26ab22c940698
+DIST angband-4.2.3-man.tar.gz 112114 BLAKE2B 1e203386a5aa01f70b2906a8641e47cd01fdfc5132c18d580ea12f9d9bf82e9241bd34db171c6a206e623a0788f86449ac14c27c35515de3cfcb953fc9a9e199 SHA512 a2ee36daffbca36d9b72e157fe2b986346ea27bc6382c8a24fe2873d3319ff29a06d9a98d9d55c2ac7be8cc0f7d5959688a5504a4df47a8e9caa8dd69a61842f
+DIST angband-4.2.3.tar.gz 25175745 BLAKE2B ee9878bb93fd268c5fdd8535750d6446ebf8e30a4bc794170b60cf6a77fc0470f91261f4963dda8865c95ead1b522210c8536da36866adeb084689fcf2bc7e5c SHA512 f80a16c40d877c50194be370795acb437778ca88a658a8c95bef637625ab8a88ceb98f45d742e698709b6c81e8b5de6f563f88e957cd71eca208673bb4179e88

games-roguelike/angband/angband-4.2.3.ebuild

@@ -0,0 +1,104 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools desktop xdg-utils
+
+DESCRIPTION="A roguelike dungeon exploration game based on the books of J.R.R. Tolkien"
+HOMEPAGE="https://rephial.org/"
+SRC_URI="https://github.com/angband/angband/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz
+	https://dev.gentoo.org/~chewi/distfiles/${P}-man.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="+ncurses sdl sound +X"
+
+REQUIRED_USE="sound? ( sdl )
+	|| ( X ncurses )"
+
+RDEPEND="X? (
+		media-fonts/font-misc-misc
+		x11-libs/libX11
+	)
+	ncurses? ( sys-libs/ncurses:=[unicode(+)] )
+	sdl? (
+		media-libs/libsdl2[video,X]
+		media-libs/sdl2-image[png]
+		media-libs/sdl2-ttf
+		sound? (
+			media-libs/libsdl2[sound]
+			media-libs/sdl2-mixer[mp3]
+		)
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i -e '/libpath/s#datarootdir#datadir#' configure.ac || die
+	sed -i -e "/^.SILENT/d" mk/buildsys.mk.in || die
+
+	if use !sound ; then
+		sed -i -e 's/sounds//' lib/Makefile || die
+	fi
+
+	# Game constant files are now system config files in Angband, but
+	# users will be hidden from applying updates by default
+	{
+		echo "CONFIG_PROTECT_MASK=\"/etc/${PN}/customize/\""
+		echo "CONFIG_PROTECT_MASK=\"/etc/${PN}/gamedata/\""
+	} > "${T}"/99${PN} || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--bindir="${EPREFIX}"/usr/bin
+		--with-private-dirs
+		$(use_enable X x11)
+		$(use_enable ncurses curses)
+	)
+	if use sdl; then
+		myconf+=(
+			--enable-sdl2
+			$(use_enable sound sdl2-mixer)
+		)
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	dodoc changes.txt README.md
+	doman "${WORKDIR}"/${PN}.1
+	doenvd "${T}"/99${PN}
+
+	if use X || use sdl; then
+		use X && make_desktop_entry "angband -mx11" "Angband (X11)" "${PN}"
+		use sdl && make_desktop_entry "angband -msdl2" "Angband (SDL2)" "${PN}"
+
+		local s
+		for s in 16 32 128 256 512; do
+			newicon -s ${s} lib/icons/att-${s}.png "${PN}.png"
+		done
+		newicon -s scalable lib/icons/att.svg "${PN}.svg"
+	fi
+}
+
+pkg_postinst() {
+	if use X || use sdl; then
+		xdg_icon_cache_update
+	fi
+}
+
+pkg_postrm() {
+	if use X || use sdl; then
+		xdg_icon_cache_update
+	fi
+}