media-gfx/ahoviewer: add a snapshot version 2.0.0_pre20211126

- lots of fixes after 2.0-beta release.

Closes: https://bugs.gentoo.org/827306
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

media-gfx/ahoviewer/Manifest

@@ -1 +1,2 @@
 DIST ahoviewer-2.0.0_beta.tar.gz 488564 BLAKE2B 325d9689e13fc2847d00be3e77eb5cd8234c98d0c516d3427d4275beaf6cc08ba8a054dfa047ec5e00e4693f8b14f730694358dc22a15e8d503bf67f232c1772 SHA512 6a38da0810c93886233a41d1fdc3f9779158c54b328c13cb2eea9e921057913fd3bb48370b95526f2bc8635ca4ba0967e7edeb95052ea689b05fb8555d826cf0
+DIST ahoviewer-2.0.0_pre20211126.tar.gz 502643 BLAKE2B fdfb4def35f6f1024ae47c114395f45e86abfb23a54275abf98a16bc8b7bae879e57034401b5effb340a2855af64b66ae09d86bcbbdd50e39f43f4f300232e2f SHA512 4facaa1938308e82b1743cb97186925b18ee843456a75bb2639e303e35e40fbee4b6bdebf1aa977fed03b2a4cf6a2b558c488720156db5f821da30578362303f

media-gfx/ahoviewer/ahoviewer-2.0.0_pre20211126.ebuild

@@ -0,0 +1,81 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+MY_COMMIT="92f2b2f57c8a6ebf0d10cb95bfc9b685bf98be5c"
+
+DESCRIPTION="A GTK image viewer, manga reader, and booru browser"
+HOMEPAGE="https://github.com/ahodesuka/ahoviewer"
+SRC_URI="https://github.com/ahodesuka/ahoviewer/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome-keyring gnutls +gstreamer plugins +rar +ssl +zip"
+
+DEPEND="dev-cpp/atkmm:0
+	dev-cpp/glibmm:2
+	dev-cpp/gtkmm:3.0
+	dev-cpp/pangomm:1.4
+	dev-libs/glib:2
+	dev-libs/libconfig:=[cxx]
+	dev-libs/libsigc++:2
+	dev-libs/libxml2:2
+	media-libs/libnsgif
+	net-misc/curl
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	gnome-keyring? ( app-crypt/libsecret )
+	gstreamer? (
+		media-libs/gst-plugins-bad:1.0
+		media-libs/gstreamer:1.0
+	)
+	plugins? (
+		dev-libs/gobject-introspection
+		dev-libs/libpeas
+	)
+	rar? ( app-arch/unrar:= )
+	ssl? (
+		gnutls? (
+			dev-libs/libgcrypt:=
+			net-libs/gnutls:=
+			net-misc/curl[curl_ssl_gnutls]
+		)
+		!gnutls? (
+			dev-libs/openssl:=
+			net-misc/curl[curl_ssl_openssl]
+		)
+	)
+	zip? ( dev-libs/libzip:= )
+"
+RDEPEND="${DEPEND}
+	gstreamer? (
+		media-libs/gst-plugins-base:1.0[X]
+		media-libs/gst-plugins-good:1.0
+		|| (
+			media-plugins/gst-plugins-vpx
+			media-plugins/gst-plugins-libav
+		)
+	)"
+
+# In future (-beta), pull https://github.com/ahodesuka/ahoviewer-plugins
+# directly via SRC_URI="plugins? ( )", or add as a separate package. It
+# depends on how the plugins are handled.
+#PDEPEND="plugins? ( x11-misc/ahoviewer-plugins )"
+
+S="${WORKDIR}/ahoviewer-${MY_COMMIT}"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature gnome-keyring libsecret)
+		$(meson_feature gstreamer)
+		$(meson_feature plugins libpeas)
+		$(meson_feature rar libunrar)
+		$(meson_feature zip libzip)
+	)
+
+	meson_src_configure
+}