sys-libs/libosinfo: bump to 1.2.0

Package-Manager: Portage-2.3.40, Repoman-2.3.9

sys-libs/libosinfo/Manifest

@@ -1 +1,2 @@
 DIST libosinfo-1.1.0.tar.gz 904154 BLAKE2B b34d1aaf2d53ac43613cfbdfd05bc12de505d37a743d64e43af379351f640759ad0ec2f30af74bf82a97b3e12b4a02b097bbdd6e0d3e83f7befa2af5340724a2 SHA512 c4f9e67bb5538e31e7d2ed3d764547ba0a2263da5bbf4d1ef930a32d5953fab59abc672e5f86a1f7f5ac1ebd0c5195986193f699a6b0efbcb6769917c0ed7102
+DIST libosinfo-1.2.0.tar.gz 916787 BLAKE2B 652910ca1e70071d88adb771e458f0c19159a772eec1178c94ea5f65c5045bb00e4b1354b1ce4229d28821b6b1557424e419c1505b721883731a36b0761a1b5d SHA512 d98a107a08c5e2cddd746631b3ceac4278184ea5561ad2372d772b8ae253dc1363f217778d105387e5b5c5e86be9607668aa94929ad9b4ee48ab7abf50fb6a01

sys-libs/libosinfo/libosinfo-1.2.0.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 udev vala
+
+DESCRIPTION="GObject library for managing information about real and virtual OSes"
+HOMEPAGE="https://libosinfo.org/"
+SRC_URI="https://releases.pagure.org/libosinfo/${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+
+IUSE="+introspection +vala test"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# Unsure about osinfo-db-tools rdep, but at least fedora does it too
+RDEPEND="
+	>=dev-libs/glib-2.36.0:2
+	>=dev-libs/libxml2-2.6.0
+	>=dev-libs/libxslt-1.0.0
+	sys-apps/hwids[pci,usb]
+	sys-apps/osinfo-db-tools
+	sys-apps/osinfo-db
+	introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )
+"
+# perl dep is for pod2man, and configure.ac checks for it too now
+# Tests can use net-misc/curl, but they are automatically skipped if curl is not found, and
+# if it is found, then those tests are skipped at runtime if LIBOSINFO_NETWORK_TESTS is unset.
+# Due to potential network-sandbox we aren't enabling them (and one of them fails at 1.2.0).
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	dev-libs/gobject-introspection-common
+	>=dev-util/gtk-doc-am-1.10
+	>=dev-util/intltool-0.40.0
+	virtual/pkgconfig
+	test? (
+		>=sys-apps/osinfo-db-20180612
+	)
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--with-usb-ids-path=/usr/share/misc/usb.ids \
+		--with-pci-ids-path=/usr/share/misc/pci.ids \
+		--disable-static \
+		$(use_enable test tests) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		--disable-coverage
+}