dev-util/sysdig: Bump to 0.23.1 (bugfixes)

dev-util/sysdig/Manifest

@@ -1,2 +1,3 @@
 DIST sysdig-0.22.1.tar.gz 825171 BLAKE2B aa4836ed0be30fb3d8318b151c3f60586daaea15974558e7d81ba2da6d9c511bedc67fe8bc518697b6a268ea93bd112f64ae5772ef75c10d8b57d06e1468ff13 SHA512 e9f5ca594dc31832b4ea365a624208f5319add1480cfe9fb3d0e960757229fbe6ce46b906a390a667147ae1a7c0a31fd7ffeb9a1a0b376376530d4f60f397453
 DIST sysdig-0.23.0.tar.gz 829716 BLAKE2B d507d28ef606e4ccd96fec1fa735bf305ceb2b2d0292b872309d877c7492def92b7305866316977f0e12325f3b8ae180a1633c8d969b1761eb2197b5250f4d43 SHA512 e6ad3f5bba1ad7307a7e0769b1a9a0c20659fff5bcc06b741cb9ce23428d4de38b5acf32a37d10bb1b41e839cc3a86b89075bde577c3f200e9fa5b4bad33a77d
+DIST sysdig-0.23.1.tar.gz 830420 BLAKE2B 31a8c4cd8b570a308c81b4df53494cff2619d05724e509634671968025ebee0e46c5e59a7c877e6d9f1f1eba86a8a27a0cd9c5b66e75723ec8eec66c6782d4c0 SHA512 059a564a5d31381efae4bc50d2b83f83a1d051f1cfb9fa6bfb75a341305149073a6eb3b9a3ce4da12fa293e75b71f8b30c9021ac8d4c4a2f59a40e35a5ffd482

dev-util/sysdig/sysdig-0.23.1.ebuild

@@ -0,0 +1,92 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+MODULES_OPTIONAL_USE=modules
+inherit linux-mod bash-completion-r1 cmake-utils
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="https://www.sysdig.org/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl +modules"
+
+RDEPEND="
+	app-misc/jq:0=
+	dev-lang/luajit:2=
+	>=dev-libs/jsoncpp-0.6_pre:0=
+	dev-libs/libb64:0=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:0=
+	libressl? ( dev-libs/libressl:0= )
+	!libressl? ( dev-libs/openssl:0= )
+	net-misc/curl:0="
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/os-headers"
+
+# needed for the kernel module
+CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS ~TRACEPOINTS"
+
+pkg_pretend() {
+	linux-mod_pkg_setup
+}
+
+pkg_setup() {
+	linux-mod_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# we will use linux-mod for that
+		-DBUILD_DRIVER=OFF
+		# libscap examples are not installed or really useful
+		-DBUILD_LIBSCAP_EXAMPLES=OFF
+
+		# unbundle the deps
+		-DUSE_BUNDLED_DEPS=OFF
+	)
+
+	cmake-utils_src_configure
+
+	# setup linux-mod ugliness
+	MODULE_NAMES="sysdig-probe(extra:${S}/driver:)"
+	BUILD_PARAMS='KERNELDIR="${KERNEL_DIR}"'
+	BUILD_TARGETS="all"
+
+	if use modules; then
+		cmake-utils_src_make configure_driver
+
+		cp "${BUILD_DIR}"/driver/Makefile.dkms driver/Makefile || die
+	fi
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	linux-mod_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	linux-mod_src_install
+
+	# remove sources
+	rm -r "${ED%/}"/usr/src || die
+
+	# move bashcomp to the proper location
+	dobashcomp "${ED%/}"/usr/etc/bash_completion.d/sysdig || die
+	rm -r "${ED%/}"/usr/etc || die
+}