net-irc/kvirc: Version bump (20170202154736).

2026-09-24 04:59:14 -07:00 · 2017-02-02 18:33:25 +01:00
parent be6e0043a4
commit 331f5a6ba4
2 changed files with 140 additions and 0 deletions
--- a/net-irc/kvirc/Manifest
+++ b/net-irc/kvirc/Manifest
@@ -1,2 +1,3 @@
 DIST kvirc-5.0_pre20160801092805.tar.gz 6459791 SHA256 1ddc0e962238b2959ed0aacab83071e6237fa48b040201790be07e6e9cc94fee SHA512 8bc184f4c1e87d557d6fcb0bc6f8370d602ea5b869f557c69d70cf32638cbbb6cd78907dbb13bc9cc70ff661cd556a54db3a5732dbb3e3a1f8241c8f4a4e5668 WHIRLPOOL 9b6a24421cabb0d61a3f5e6fd322a230123bbb3d93f56f2bd044812a1d0a83cbd04cff38ea228757fc7938d2a32516068b3db5244307ff2e4328c6664c29a20b
 DIST kvirc-5.0_pre20161201011150.tar.gz 6096540 SHA256 a1a44995e12ada79338b38f9e1f7b750df7acf849c91878fbfe61617de0e8a8e SHA512 82b52996fc6d761d71ea54e967aa813b6420c7dc218a98d9faab7ad8e3ff4a3953e6931ce5bc4231a1034966194b1ad6715fdd2f6df725bec85fa59204e9db49 WHIRLPOOL f67f3177efb0e032dc949acee11fa422032d4edbf6b2ec5b7613c4803cb95a0fcceb11de7ca2a57fcfbafc44d811d0ce90faa5bd67ab3a52e87280b1c41abe13
+DIST kvirc-5.0_pre20170202154736.tar.gz 6106786 SHA256 a17a214fb24b44d9c799cc85e98ec1a92a50401c3f662587ef355532329293ad SHA512 b2055f6c06426639f87499a8242c97b0dfb7168edfafa3c2a124dfb70799c361d8e5ae14e71605819372e2c66c4c97a18a919423a3ce2f64b276ea20edd02b18 WHIRLPOOL bc8d74142b21a6f80816bef6840d344ce92154a081bf1bd9cc6bdcd2213ebb8313bdc209ecb20e916cf7e97c0ec49f1294f2e04a57fa00eadfbd478fdf417787
--- a/net-irc/kvirc/kvirc-5.0_pre20170202154736.ebuild
+++ b/net-irc/kvirc/kvirc-5.0_pre20170202154736.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+PYTHON_COMPAT=(python2_7)
+
+inherit cmake-utils flag-o-matic multilib python-single-r1
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
+	KVIRC_GIT_REVISION=""
+	KVIRC_GIT_SOURCES_DATE=""
+else
+	inherit vcs-snapshot
+
+	KVIRC_GIT_REVISION="a497da7ec7f7db9f37a35568d1bea535929c97d2"
+	KVIRC_GIT_SOURCES_DATE="${PV#*_pre}"
+	KVIRC_GIT_SOURCES_DATE="${KVIRC_GIT_SOURCES_DATE:0:4}-${KVIRC_GIT_SOURCES_DATE:4:2}-${KVIRC_GIT_SOURCES_DATE:6:2}"
+fi
+
+DESCRIPTION="Advanced IRC Client"
+HOMEPAGE="http://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/kvirc/KVIrc/archive/${KVIRC_GIT_REVISION}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="kvirc"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="audiofile +dbus dcc_video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
+
+RDEPEND="dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	sys-libs/zlib:0=
+	x11-libs/libX11
+	audiofile? ( media-libs/audiofile )
+	dbus? ( dev-qt/qtdbus:5 )
+	dcc_video? ( dev-qt/qtmultimedia:5[widgets] )
+	kde? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/ki18n:5
+		kde-frameworks/knotifications:5
+		kde-frameworks/kservice:5
+		kde-frameworks/kwindowsystem:5
+		kde-frameworks/kxmlgui:5
+	)
+	perl? ( dev-lang/perl:0= )
+	phonon? ( media-libs/phonon:0[qt5] )
+	python? ( ${PYTHON_DEPS} )
+	spell? ( app-text/enchant )
+	ssl? ( dev-libs/openssl:0= )
+	theora? (
+		media-libs/libogg
+		media-libs/libtheora
+		media-libs/libvorbis
+	)
+	webkit? ( dev-qt/qtwebkit:5 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	x11-proto/scrnsaverproto
+	doc? ( app-doc/doxygen )
+	kde? ( kde-frameworks/extra-cmake-modules:5 )
+	nls? ( sys-devel/gettext )"
+RDEPEND="${RDEPEND}
+	gsm? ( media-sound/gsm )"
+REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+DOCS=(ChangeLog doc/FAQ)
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	if [[ "${PV}" == "9999" ]]; then
+		KVIRC_GIT_REVISION="$(git show -s --format=%H)"
+		KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
+	fi
+	einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
+	sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" (${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE})\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIB_SUFFIX=${libdir#lib}
+		-DMANUAL_REVISION=${KVIRC_GIT_REVISION}
+		-DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
+		-DWANT_ENV_FLAGS=yes
+		-DWANT_VERBOSE=yes
+
+		-DWANT_CRYPT=yes
+		-DWANT_DCC_VOICE=yes
+		-DWANT_IPC=yes
+		-DWANT_IPV6=yes
+		-DWANT_TRANSPARENCY=yes
+
+		-DWANT_AUDIOFILE=$(usex audiofile)
+		-DWANT_DCC_VIDEO=$(usex dcc_video)
+		-DWANT_DEBUG=$(usex debug)
+		-DWANT_DOXYGEN=$(usex doc)
+		-DWANT_GETTEXT=$(usex nls)
+		-DWANT_GSM=$(usex gsm)
+		-DWANT_KDE=$(usex kde)
+		-DWANT_MEMORY_PROFILE=$(usex profile)
+		-DWANT_OGG_THEORA=$(usex theora)
+		-DWANT_OPENSSL=$(usex ssl)
+		-DWANT_OSS=$(usex oss)
+		-DWANT_PERL=$(usex perl)
+		-DWANT_PHONON=$(usex phonon)
+		-DWANT_PYTHON=$(usex python)
+		-DWANT_QTDBUS=$(usex dbus)
+		-DWANT_QTWEBKIT=$(usex webkit)
+		-DWANT_SPELLCHECKER=$(usex spell)
+
+		# COMPILE_SVG_SUPPORT not used in source code.
+		-DWANT_QTSVG=no
+	)
+
+	cmake-utils_src_configure
+}