x11-libs/vte: bump to 0.54.4

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
This commit is contained in:
Mart Raudsepp
2019-04-09 11:32:27 +03:00
parent 0a1439fb54
commit 33172e53b4
2 changed files with 89 additions and 0 deletions
+1
View File
@@ -4,3 +4,4 @@ DIST vte-0.48.4.tar.xz 1008296 BLAKE2B 9f946d6909d38896ec80db2a02666d809155997b2
DIST vte-0.54.1-command-notify.patch.xz 3428 BLAKE2B 75b0c22720276300be2e49e8444aa68fed77fb7a6cc6b0e93a5c2d41257626bd60ff1084d68579769cb3d85e7ec567927591746de48e860b138d0c1f24f64cc7 SHA512 a53da569f8168c8e9e21e186dcfc00bf9fdb78a0c767ba35033c1c1e4f836406b4d9bf70ee3e071f6c749fd6f72101a6960d201617bd0bc23021e1eeaac6fd0c
DIST vte-0.54.1.tar.xz 1083552 BLAKE2B 1e52275c953b5fbf51a1cc727dfca0bde3cc8f51a18055cd0c65c949479d0b4d926466016fa7d6f6dbebc9117c1b6fbde9a4bde38c5d82bb44ecce8612290de6 SHA512 5cb866e75c35e1b5728d17b0433641ceb4837495d59185a04fde9dd8c9849ab905a6b2718a50b27cc70323c7a6c5db31a808816576c30d7f18ece889a329fb61
DIST vte-0.54.3.tar.xz 1087424 BLAKE2B becb668d6b3f56ebd1eb6d076c5cac2fc9623bfa012c877d8d3cf374cfbded6ff16ef1e0b1fc9e92ba1255f9653be25df1b81c7c85f42749449e5df12c530411 SHA512 dd7d2ac361ed9ac0550599bb3164a3bd6ba95535275c9b559c81ce0af1bbf4b3d150a7489f987b2e626b32d4a8adc82d1ff78e8c8640e5b1c036fe4076c5d8ce
DIST vte-0.54.4.tar.xz 1087748 BLAKE2B 65fb762414e832930ce1519dc99fe306b3c9c3860bf8116c29e66b758178d1f0a52705cd6f7ab1be30374fb2956a01aaccc8f6859d0af971f2037809421bb502 SHA512 7e0f4140a4c474fad9a48eaf0e4c29f83e7bf50719087983c238b362c6303824836c34485eb2ca135be0961fa4b83a318d08ef70d4cf0dab0d37dc2e36710c41
+88
View File
@@ -0,0 +1,88 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
VALA_USE_DEPEND="vapigen"
VALA_MIN_API_VERSION="0.32"
inherit gnome2 vala
DESCRIPTION="Library providing a virtual terminal emulator widget"
HOMEPAGE="https://wiki.gnome.org/Apps/Terminal/VTE"
LICENSE="LGPL-2+"
SLOT="2.91"
IUSE="+crypt debug glade +introspection vala vanilla"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
REQUIRED_USE="vala? ( introspection )"
SRC_URI="${SRC_URI} !vanilla? ( https://dev.gentoo.org/~leio/distfiles/${PN}-0.54.1-command-notify.patch.xz )"
RDEPEND="
>=dev-libs/glib-2.40:2
>=dev-libs/libpcre2-10.21
>=x11-libs/gtk+-3.16:3[introspection?]
>=x11-libs/pango-1.22.0
sys-libs/ncurses:0=
sys-libs/zlib
crypt? ( >=net-libs/gnutls-3.2.7:0= )
glade? ( >=dev-util/glade-3.9:3.10 )
introspection? ( >=dev-libs/gobject-introspection-0.9.0:= )
"
DEPEND="${RDEPEND}
dev-libs/libxml2:2
dev-util/glib-utils
>=dev-util/gtk-doc-am-1.13
>=dev-util/intltool-0.35
sys-devel/gettext
virtual/pkgconfig
vala? ( $(vala_depend) )
"
RDEPEND="${RDEPEND}
!x11-libs/vte:2.90[glade]
"
src_prepare() {
if ! use vanilla; then
# First half of http://pkgs.fedoraproject.org/cgit/rpms/vte291.git/tree/vte291-command-notify-scroll-speed.patch
# Adds OSC 777 support for desktop notifications in gnome-terminal or elsewhere
eapply "${WORKDIR}"/${PN}-0.54.1-command-notify.patch
fi
use vala && vala_src_prepare
# build fails because of -Werror with gcc-5.x
sed -e 's#-Werror=format=2#-Wformat=2#' -i configure || die "sed failed"
gnome2_src_prepare
}
src_configure() {
local myconf=""
if [[ ${CHOST} == *-interix* ]]; then
myconf="${myconf} --disable-Bsymbolic"
# interix stropts.h is empty...
export ac_cv_header_stropts_h=no
fi
gnome2_src_configure \
--disable-static \
--with-gtk=3.0 \
--with-iconv \
$(use_enable debug) \
$(use_enable glade glade-catalogue) \
$(use_with crypt gnutls) \
$(use_enable introspection) \
$(use_enable vala) \
${myconf}
}
src_install() {
gnome2_src_install
mv "${ED}"/etc/profile.d/vte{,-${SLOT}}.sh || die
}