media-sound/kid3: add 3.9.3

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2023-01-12 21:42:15 +01:00
parent 2758c14d79
commit 32a35f85be
2 changed files with 101 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST kid3-3.9.2.tar.xz 1952344 BLAKE2B 5a44a05f614f97dc7ddab39694a1773e1e6c55af7a9dc4ac7b793a520e54a8892c2181903a58f150885b3b4e17ebf921db719863f7ac4fd540f711a444990df3 SHA512 fc0b9db33ea948a2345968ab5da65f959bea829130f4250604d68df778218173d49f92b015d9be4e43f57ba5ae3388b0e97f558774df590b5959aa6f6293acd3
DIST kid3-3.9.3.tar.xz 1820640 BLAKE2B ea030328d88f583e88959e7536f4e3e086354befc40395700fac8314a1e7c3da7a2f9a614ff9ad98491d9ec4d8b24ead05a2214b94f55786a5e493c1a585056c SHA512 f40c7eaa186eb7d3163635286a8ad89bf6b29dce851b4fadc0814eec7759ed7fbac37e4596365bac4df93c5b655a7e943f8414e7c8f661b29aea7bde5367ed73
+100
View File
@@ -0,0 +1,100 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..11} )
inherit cmake kde.org python-any-r1 xdg
DESCRIPTION="Simple tag editor based on Qt"
HOMEPAGE="https://kid3.kde.org/"
if [[ ${KDE_BUILD_TYPE} != live ]]; then
SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="GPL-2+"
SLOT="5"
IUSE="acoustid flac kde mp3 mp4 +mpris +taglib test vorbis"
REQUIRED_USE="flac? ( vorbis )"
RESTRICT="!test? ( test )"
RDEPEND="
dev-qt/qtcore:5
dev-qt/qtdeclarative:5
dev-qt/qtgui:5
dev-qt/qtmultimedia:5
dev-qt/qtnetwork:5
dev-qt/qtwidgets:5
dev-qt/qtxml:5
sys-libs/readline:=
acoustid? (
media-libs/chromaprint:=
media-video/ffmpeg:=
)
flac? (
media-libs/flac:=[cxx]
media-libs/libvorbis
)
kde? (
kde-frameworks/kconfig:5
kde-frameworks/kconfigwidgets:5
kde-frameworks/kcoreaddons:5
kde-frameworks/kio:5
kde-frameworks/kwidgetsaddons:5
kde-frameworks/kxmlgui:5
)
mp3? ( media-libs/id3lib )
mp4? ( media-libs/libmp4v2 )
mpris? ( dev-qt/qtdbus:5 )
taglib? ( >=media-libs/taglib-1.9.1 )
vorbis? (
media-libs/libogg
media-libs/libvorbis
)
"
DEPEND="${RDEPEND}
test? ( dev-qt/qttest:5 )
"
BDEPEND="${PYTHON_DEPS}
dev-qt/linguist-tools:5
kde? ( kde-frameworks/extra-cmake-modules:5 )
"
pkg_setup() {
use test && python-any-r1_pkg_setup
}
src_prepare() {
# overengineered upstream build system
cmake_src_prepare
# applies broken python hacks, bug #614950
cmake_comment_add_subdirectory doc
sed -e "/^find_package.*QT NAMES/s/Qt6 //" \
-i CMakeLists.txt || die # ensure Qt5 build
}
src_configure() {
local mycmakeargs=(
-DPython3_EXECUTABLE="${PYTHON}"
-DWITH_CHROMAPRINT=$(usex acoustid)
-DWITH_DBUS=$(usex mpris)
-DWITH_FLAC=$(usex flac)
-DWITH_ID3LIB=$(usex mp3)
-DWITH_MP4V2=$(usex mp4)
-DWITH_TAGLIB=$(usex taglib)
-DBUILD_TESTING=$(usex test)
-DWITH_VORBIS=$(usex vorbis)
)
if use kde ; then
mycmakeargs+=( "-DWITH_APPS=KDE;CLI" )
else
mycmakeargs+=( "-DWITH_APPS=Qt;CLI" )
fi
cmake_src_configure
}