dev-embedded/openocd: version bump, 0.12.0_rc2

drop virtual/libusb:0

Closes: https://bugs.gentoo.org/886637
Signed-off-by: Yixun Lan <dlan@gentoo.org>

dev-embedded/openocd/Manifest

@@ -1 +1,2 @@
 DIST openocd-0.11.0.tar.gz 7233889 BLAKE2B 272088c261a066d0a99cbbf2ebbc324fc34bc168290bbf0beb4012655b6b54848cc48324f36c65860518160c3fe43abb8c9a5f5b03f0cbaf7cdfb928f8fb8eea SHA512 667c5bea4144653f7c1309457b3aed1e14713f222dab8f2bb67a8e6c69e124a0efc24cd8f76e2b929d4ced045de14517f3587870682d0394ec95ba52e343e19b
+DIST openocd-0.12.0-rc2.tar.gz 8437679 BLAKE2B 3d1ec6fc758ace9d975956ecb2a4152a067e8be9a2e03a4c69c1020b4dbe752d52bb7be626ec78028953ba5d918b4ca9bf0a38ae0d83bf86d06ac12cb29ac5b3 SHA512 1b20f2cc8e511d02beb60b191b0b66d0ef53ab1dfb966773ddd8e72570eddc295768b3b8a340f70c9cc7bb061a25e649061435b844307b3bdd9177866f4e2f4a

dev-embedded/openocd/openocd-0.12.0_rc2.ebuild

@@ -0,0 +1,105 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools udev
+
+if [[ ${PV} == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="	https://repo.or.cz/openocd.git"
+else
+	MY_PV="${PV/_/-}"
+	MY_P="${PN}-${MY_PV}"
+	S="${WORKDIR}"/${MY_P}
+	KEYWORDS="~amd64 ~arm ~x86"
+	SRC_URI="mirror://sourceforge/project/${PN}/${PN}/${MY_PV}/${MY_P}.tar.gz"
+fi
+
+DESCRIPTION="OpenOCD - Open On-Chip Debugger"
+HOMEPAGE="http://openocd.sourceforge.net"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="capstone +cmsis-dap dummy +ftdi +jlink parport +usb verbose-io"
+RESTRICT="strip" # includes non-native binaries
+
+RDEPEND="
+	acct-group/plugdev
+	>=dev-lang/jimtcl-0.81:=
+	capstone? ( dev-libs/capstone )
+	cmsis-dap? ( dev-libs/hidapi )
+	jlink? ( >=dev-embedded/libjaylink-0.2.0 )
+	usb? ( virtual/libusb:1 )
+	ftdi? ( dev-embedded/libftdi:= )"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	AT_NO_RECURSIVE=yes eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--enable-amtjtagaccel
+		--enable-am335xgpio
+		--enable-arm-jtag-ew
+		--enable-at91rm9200
+		--enable-bcm2835gpio
+		--enable-buspirate
+		--enable-ep93xx
+		--enable-gw16012
+		--enable-jtag_dpi
+		--enable-sysfsgpio
+		--enable-vdebug
+		--disable-internal-jimtcl
+		--disable-internal-libjaylink
+		--disable-parport-giveio
+		--disable-werror
+		$(use_with capstone)
+		$(use_enable cmsis-dap)
+		$(use_enable dummy)
+		$(use_enable ftdi openjtag)
+		$(use_enable ftdi presto)
+		$(use_enable ftdi usb-blaster)
+		$(use_enable jlink)
+		$(use_enable parport)
+		$(use_enable parport parport_ppdev)
+		$(use_enable usb aice)
+		$(use_enable usb armjtagew)
+		$(use_enable usb ftdi)
+		$(use_enable usb osbdm)
+		$(use_enable usb opendous)
+		$(use_enable usb rlink)
+		$(use_enable usb stlink)
+		$(use_enable usb ti-icdi)
+		$(use_enable usb usbprog)
+		$(use_enable usb usb-blaster-2)
+		$(use_enable usb ulink)
+		$(use_enable usb vsllink)
+		$(use_enable verbose-io verbose-jtag-io)
+		$(use_enable verbose-io verbose-usb-io)
+		$(use_enable verbose-io verbose_usb_comms)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	dostrip /usr/bin
+	udev_dorules "${ED}"/usr/share/${PN}/contrib/*.rules
+}
+
+pkg_postinst() {
+	udev_reload
+
+	elog "To access openocd devices as user you must be in the plugdev group"
+}
+
+pkg_postrm() {
+	udev_reload
+}

dev-embedded/openocd/openocd-9999.ebuild

@@ -1,12 +1,12 @@
 # Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-inherit udev
+inherit autotools udev
 
 if [[ ${PV} == *9999 ]] ; then
-	inherit autotools git-r3
+	inherit git-r3
 	EGIT_REPO_URI="	https://repo.or.cz/openocd.git"
 else
 	MY_PV="${PV/_/-}"
@@ -21,46 +21,45 @@ HOMEPAGE="http://openocd.sourceforge.net"
 
 LICENSE="GPL-2+"
 SLOT="0"
-IUSE="+cmsis-dap dummy +ftdi +jlink parport +usb verbose-io"
+IUSE="capstone +cmsis-dap dummy +ftdi +jlink parport +usb verbose-io"
 RESTRICT="strip" # includes non-native binaries
 
 RDEPEND="
 	acct-group/plugdev
-	>=dev-lang/jimtcl-0.80:=
+	>=dev-lang/jimtcl-0.81:=
+	capstone? ( dev-libs/capstone )
 	cmsis-dap? ( dev-libs/hidapi )
 	jlink? ( >=dev-embedded/libjaylink-0.2.0 )
-	usb? (
-		virtual/libusb:0
-		virtual/libusb:1
-	)
+	usb? ( virtual/libusb:1 )
 	ftdi? ( dev-embedded/libftdi:= )"
 
 DEPEND="${RDEPEND}"
-BDEPEND="
-	sys-apps/texinfo
-	virtual/pkgconfig"
+BDEPEND="virtual/pkgconfig"
 
 src_prepare() {
 	default
 
-	if [[ ${PV} == *9999 ]] ; then
-		AT_NO_RECURSIVE=yes eautoreconf
-	fi
+	AT_NO_RECURSIVE=yes eautoreconf
 }
 
 src_configure() {
 	local myconf=(
 		--enable-amtjtagaccel
+		--enable-am335xgpio
 		--enable-arm-jtag-ew
 		--enable-at91rm9200
 		--enable-bcm2835gpio
 		--enable-buspirate
 		--enable-ep93xx
 		--enable-gw16012
+		--enable-jtag_dpi
 		--enable-sysfsgpio
+		--enable-vdebug
 		--disable-internal-jimtcl
 		--disable-internal-libjaylink
+		--disable-parport-giveio
 		--disable-werror
+		$(use_with capstone)
 		$(use_enable cmsis-dap)
 		$(use_enable dummy)
 		$(use_enable ftdi openjtag)