xfce-base/thunar: Bump to 4.18.6

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/thunar/Manifest

@@ -1,2 +1,3 @@
 DIST thunar-4.18.4.tar.bz2 2836333 BLAKE2B 22ab64ae14bbd15e16d314f2252f02fc8a5ae3043502bfc6a1f43c3e28e735e42d1e040db4dc9c3c7d4df6426c16233da78f30284b1679d59b9ada2cf9051fe2 SHA512 c182abc9fbde79f802c2fac01375be8b29b5da36c665f1de1c005ec09561a865c502e9741a3336ef467d05b215041b452200b063bc33d572b0857f901728d9ae
 DIST thunar-4.18.5.tar.bz2 2831920 BLAKE2B 7923c110d4c2bd2ee1f9f0a99638750e41b3da02d3ca32b188f84859ba942c243cb050e14290c390b9766070f72ac4ef006dd2a8c6622740fa7802f1f8fb5c6a SHA512 bee561e63e6732022a9434dd6c297e89ecff901ffbdbb4b4063a74ab9e51dadc09b52123586a82b7e16d69cf4205fa7dcc2a29261e4e9c0b62daa03cf38380ca
+DIST thunar-4.18.6.tar.bz2 2831580 BLAKE2B 76b17464737b1cd7649fbfb14e3512cc215cb101c74dbe091f909cb5de6c8c9cf4b1e813620cf6595f4486789cd056533f9f7fee21e206cb80514d4d85d65221 SHA512 fa55a50b164926db39d80fc8588fc7924f3810cbf4128447d3a27142759c9f15f1fd1bbf34676611568b6924f7a9a888500c279f82a03598ae68d2a1a27426b9

xfce-base/thunar/thunar-4.18.6.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/thunar/start
+	https://gitlab.xfce.org/xfce/thunar/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="exif introspection libnotify pcre +trash-panel-plugin udisks"
+
+DEPEND="
+	>=dev-libs/glib-2.66.0
+	>=x11-libs/gdk-pixbuf-2.40.0
+	>=x11-libs/gtk+-3.24.0:3
+	>=xfce-base/exo-4.17.0:=
+	>=xfce-base/libxfce4ui-4.17.6:=
+	>=xfce-base/libxfce4util-4.17.2:=
+	>=xfce-base/xfconf-4.12:=
+	exif? ( >=media-libs/libexif-0.6.19:= )
+	introspection? ( dev-libs/gobject-introspection:= )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	pcre? ( >=dev-libs/libpcre2-10.0:= )
+	trash-panel-plugin? ( >=xfce-base/xfce4-panel-4.10:= )
+	udisks? ( dev-libs/libgudev:= )
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	trash-panel-plugin? (
+		>=gnome-base/gvfs-1.18.3
+	)
+	udisks? (
+		>=gnome-base/gvfs-1.18.3[udisks,udev]
+		virtual/udev
+	)
+"
+BDEPEND="
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable udisks gudev)
+		$(use_enable libnotify notifications)
+		$(use_enable exif)
+		$(use_enable pcre pcre2)
+		$(use_enable trash-panel-plugin tpa-plugin)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	elog "If you were using an older Xfce version and Thunar fails to start"
+	elog "with a message similar to:"
+	elog "  Failed to register: Timeout was reached"
+	elog "you may need to reset your xfce4 session:"
+	elog "  rm ~/.cache/sessions/xfce4-session-*"
+	elog "See https://bugs.gentoo.org/698914."
+
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}