media-sound/wildmidi: add 0.4.5

Signed-off-by: Azamat H. Hackimov <azamat.hackimov@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/29153
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

media-sound/wildmidi/Manifest

@@ -1 +1,2 @@
 DIST wildmidi-0.4.4.tar.gz 197597 BLAKE2B 5f5b11bec70b24b4798ac39d4d30420916609f3d65497ef88b48ef292f41d0cc81cc8d9c8c47ffc68705d6297a9ce55ef5d7ebdf63f8c18b8b0f7982c1f60bfc SHA512 5b74ee83f1d7ce3b45d2f996aaa30ec6e7d7808eab294a3eaf6fcef77443523df1f54bb0fb1b3105edd0d72d75885fda1a2e97c68defb5bbd687bda5077d3454
+DIST wildmidi-0.4.5.tar.gz 197793 BLAKE2B a0b43e19b4e4ced6c4f536dd5e1ac313acd26ad0c3c9deed7068181666a175f4dfdf5cb522d70fdaf0636cc4b3b1af3cedfda54a6c048b05e828a4d1ad185b77 SHA512 0229914ecc60091b649b790a82ad5e755a2b9dfab7443fb3e3c19f4ae64b82817cafe74d78c27f05c68c3c8fb30092c96da732d27ff82fbd7dd7d577facc23d6

media-sound/wildmidi/wildmidi-0.4.5.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake readme.gentoo-r1
+
+DESCRIPTION="MIDI processing library and player using the GUS patch set"
+HOMEPAGE="http://www.mindwerks.net/projects/wildmidi/"
+SRC_URI="https://github.com/Mindwerks/${PN}/archive/${P}.tar.gz"
+
+LICENSE="GPL-3+ LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
+IUSE="+alsa openal oss +player"
+
+DEPEND="
+	player? (
+		alsa? ( media-libs/alsa-lib )
+		openal? ( media-libs/openal )
+	)
+"
+RDEPEND="${DEPEND}
+	media-sound/timidity-freepats
+"
+
+REQUIRED_USE="player? ( ^^ ( alsa oss openal ) )"
+
+DOC_CONTENTS="${PN} is using timidity-freepats for midi playback.
+	A default configuration file was placed on /etc/${PN}/${PN}.cfg.
+	For more information please read the ${PN}.cfg manpage."
+
+S="${WORKDIR}/${PN}-${P}"
+
+src_prepare() {
+	cmake_src_prepare
+	# Fix location of media-sound/timidity-freepats
+	# See #749759
+	sed -i -e "s:midi/freepats:timidity/freepats:" cfg/wildmidi.cfg || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWANT_ALSA=$(usex alsa)
+		-DWANT_OPENAL=$(usex openal)
+		-DWANT_OSS=$(usex oss)
+		-DWANT_PLAYER=$(usex player)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	insinto /etc/${PN}/
+	doins cfg/wildmidi.cfg
+
+	readme.gentoo_create_doc
+}