mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-21 09:07:26 -08:00
net-misc/connman: add 1.45
Signed-off-by: Ben Kohler <bkohler@gentoo.org>
This commit is contained in:
Ben Kohler
parent
3f7dbc361b
commit
3199b90e25
@ -1,2 +1,3 @@
|
||||
DIST connman-1.43.tar.gz 800363 BLAKE2B f7d906df55e89ffe58fe4c684577be94468d24e6934f82f6461c93969743c44c227cc1caa1dc5123ffb8e521385a08bc7e59c733619c39beae34a2e8ca0b495f SHA512 60fef8fb5ac0679068794c84af7eefbc051c4fff12c86a02574d3225e5729ae9ff38d4223f72f03621db9b05624843165fee5692dc12d493676d987b9433174a
|
||||
DIST connman-1.44.tar.gz 806466 BLAKE2B 4231799c1bfb4efd6afdba0e5325a4e0375d35e3ca1e31c9d070b05955bbae16ff78bd26d7a3d82b3147d4d5d746bc869adf6d16c14e1c3595139b4a04eab026 SHA512 3aa0b3065b13df4b8f5128d20c244bb8c7c4ba636d23e065d3dcfd6629a8b04fe64ca3a03d451fc241182d221060fccf2df343aecacb0fc1001083f31db67330
|
||||
DIST connman-1.45.tar.gz 807083 BLAKE2B 9e8b94d413802d6cd27328934892df265be1a2c5aafe3fb64d2d9b987514b1a50c19c80d46a8855e51fdf329adda433186947a010165307edcdf6fb4c5229cf5 SHA512 8bf13f702d6fbc2ee4b7900246d196643342656e1448df902c90aacd07483bebdcbbc19436fbdef86af9b30a5060651cfaa31b2ccaa88a01097b568ec7c2a526
|
||||
|
||||
135
net-misc/connman/connman-1.45.ebuild
Normal file
135
net-misc/connman/connman-1.45.ebuild
Normal file
@ -0,0 +1,135 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI="8"
|
||||
inherit autotools systemd tmpfiles
|
||||
|
||||
if [[ ${PV} == *9999* ]]; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://git.kernel.org/pub/scm/network/connman/connman.git"
|
||||
else
|
||||
SRC_URI="https://git.kernel.org/pub/scm/network/connman/connman.git/snapshot/${P}.tar.gz"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
|
||||
fi
|
||||
|
||||
DESCRIPTION="Provides a daemon for managing internet connections"
|
||||
HOMEPAGE="https://git.kernel.org/pub/scm/network/connman/connman.git/"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
|
||||
IUSE="bluetooth debug doc +ethernet examples iptables iwd l2tp networkmanager
|
||||
+nftables ofono openconnect openvpn policykit pptp tools vpnc +wifi wireguard
|
||||
wispr"
|
||||
|
||||
REQUIRED_USE="^^ ( iptables nftables )"
|
||||
BDEPEND="virtual/pkgconfig"
|
||||
COMMON_DEPEND=">=dev-libs/glib-2.16
|
||||
net-libs/gnutls
|
||||
>=sys-apps/dbus-1.2.24
|
||||
sys-libs/readline:0=
|
||||
nftables? (
|
||||
>=net-libs/libnftnl-1.0.4:0=
|
||||
>=net-libs/libmnl-1.0.0:0=
|
||||
)
|
||||
openconnect? ( net-vpn/openconnect )
|
||||
openvpn? ( net-vpn/openvpn )
|
||||
pptp? ( net-dialup/pptpclient )
|
||||
vpnc? ( net-vpn/vpnc )
|
||||
wireguard? ( >=net-libs/libmnl-1.0.0:0= )"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
bluetooth? ( net-wireless/bluez )
|
||||
iptables? ( >=net-firewall/iptables-1.4.8 )
|
||||
l2tp? ( net-dialup/xl2tpd )
|
||||
ofono? ( net-misc/ofono )
|
||||
policykit? ( sys-auth/polkit )
|
||||
wifi? (
|
||||
!iwd? ( >=net-wireless/wpa_supplicant-0.7.3-r3[dbus] )
|
||||
iwd? ( net-wireless/iwd )
|
||||
)"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
>=sys-kernel/linux-headers-2.6.39"
|
||||
|
||||
PATCHES=( "${FILESDIR}/libresolv-musl-fix.patch" )
|
||||
|
||||
if [ ! -z ${COMMIT} ]; then
|
||||
S=${WORKDIR}/${PN}-${COMMIT}
|
||||
fi
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
eautoreconf
|
||||
|
||||
cp "${FILESDIR}"/connman.initd2 "${T}"
|
||||
if use iwd; then
|
||||
sed -i \
|
||||
-e "s/need dbus/need dbus iwd/" \
|
||||
-e '/start-stop-daemon --start/ s/ -- / -- --wifi=iwd_agent /' \
|
||||
"${T}"/connman.initd2 || die
|
||||
sed -i \
|
||||
-e "/^ExecStart/ s/$/ --wifi=iwd_agent/" \
|
||||
src/connman.service.in || die
|
||||
fi
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local myeconfargs=(
|
||||
--localstatedir=/var \
|
||||
--runstatedir=/run \
|
||||
--with-systemdunitdir=$(systemd_get_systemunitdir) \
|
||||
--with-tmpfilesdir="${EPREFIX}"/usr/lib/tmpfiles.d \
|
||||
--enable-client \
|
||||
--enable-datafiles \
|
||||
--enable-loopback=builtin \
|
||||
$(use_enable bluetooth bluetooth builtin) \
|
||||
$(use_enable debug) \
|
||||
$(use_enable ethernet ethernet builtin) \
|
||||
$(use_enable examples test) \
|
||||
$(use_enable l2tp l2tp builtin) \
|
||||
$(use_enable networkmanager nmcompat) \
|
||||
$(use_enable ofono ofono builtin) \
|
||||
$(use_enable openconnect openconnect builtin) \
|
||||
$(use_enable openvpn openvpn builtin) \
|
||||
$(use_enable policykit polkit builtin) \
|
||||
$(use_enable pptp pptp builtin) \
|
||||
$(use_enable tools) \
|
||||
$(use_enable vpnc vpnc builtin) \
|
||||
$(use_enable wireguard) \
|
||||
$(use_enable wispr wispr builtin) \
|
||||
--with-firewall=$(usex iptables "iptables" "nftables" ) \
|
||||
--disable-iospm \
|
||||
--disable-hh2serial-gps
|
||||
)
|
||||
# wifi USE logic to match networkmanager ebuild behavior
|
||||
if use wifi; then
|
||||
if use iwd; then
|
||||
myeconfargs+=( --enable-iwd --disable-wifi )
|
||||
else
|
||||
myeconfargs+=( --disable-iwd --enable-wifi=builtin )
|
||||
fi
|
||||
else
|
||||
myeconfargs+=( --disable-iwd --disable-wifi )
|
||||
fi
|
||||
|
||||
econf "${myeconfargs[@]}"
|
||||
}
|
||||
|
||||
src_install() {
|
||||
default
|
||||
dobin client/connmanctl
|
||||
|
||||
if use doc; then
|
||||
dodoc doc/*.txt
|
||||
fi
|
||||
keepdir /usr/lib/${PN}/scripts
|
||||
keepdir /var/lib/${PN}
|
||||
newinitd "${T}"/${PN}.initd2 ${PN}
|
||||
newconfd "${FILESDIR}"/${PN}.confd ${PN}
|
||||
|
||||
insinto /etc/connman
|
||||
doins src/main.conf
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
tmpfiles_process connman_resolvconf.conf
|
||||
}
|
||||
Loading…
x
Reference in New Issue
Block a user