dev-cpp/eigen: Port SLOT=2 ebuild to EAPI 6

Package-Manager: Portage-2.3.5, Repoman-2.3.2

dev-cpp/eigen/eigen-2.0.17.ebuild

@@ -1,7 +1,7 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=4
+EAPI=6
 
 inherit cmake-utils
 
@@ -10,24 +10,20 @@ HOMEPAGE="http://eigen.tuxfamily.org/"
 SRC_URI="https://bitbucket.org/eigen/eigen/get/${PV}.tar.bz2 -> ${P}.tar.bz2"
 
 LICENSE="GPL-3"
-KEYWORDS="alpha amd64 ~arm ~hppa ia64 ppc ppc64 sparc x86 ~amd64-fbsd ~amd64-linux ~x86-linux"
 SLOT="2"
-IUSE="debug doc examples"
+KEYWORDS="alpha amd64 ~arm ~hppa ia64 ppc ppc64 sparc x86 ~amd64-fbsd ~amd64-linux ~x86-linux"
+IUSE="debug doc examples test"
+# bugs 426236, 455460, 467288
+RESTRICT="test"
 
-COMMON_DEPEND="
+RDEPEND="
 	examples? (
 		dev-qt/qtgui:4
 		dev-qt/qtopengl:4
-	)"
-DEPEND="${COMMON_DEPEND}
-	doc? ( app-doc/doxygen )"
-RDEPEND="${COMMON_DEPEND}
+	)
 	!dev-cpp/eigen:0"
-
-MAKEOPTS+=" -j1"
-
-# bugs 426236, 455460, 467288
-RESTRICT="test"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
 
 src_unpack() {
 	unpack ${A}
@@ -35,44 +31,32 @@ src_unpack() {
 }
 
 src_configure() {
-	# benchmarks (BTL) brings up damn load of external deps including fortran
-	# compiler
+	# benchmarks (BTL) brings up a damn load of external deps including fortran
 	# library hangs up complete compilation proccess, test later
-	mycmakeargs=(
+	local mycmakeargs=(
 		-DEIGEN_BUILD_LIB=OFF
 		-DEIGEN_BUILD_BTL=OFF
 		-DEIGEN_BUILD_PKGCONFIG=ON
-		$(cmake-utils_use examples EIGEN_BUILD_DEMOS)
+		-DEIGEN_BUILD_DEMOS=$(usex examples)
+		-DEIGEN_BUILD_TESTS=$(usex test)
 	)
 	cmake-utils_src_configure
 }
 
 src_compile() {
-	cmake-utils_src_compile
+	cmake-utils_src_compile -j1
+
 	if use doc; then
-		cd "${CMAKE_BUILD_DIR}"
-		emake doc
+		cmake-utils_src_compile -j1 doc
+		HTML_DOCS=( "${BUILD_DIR}"/html/. )
 	fi
 }
 
 src_install() {
-	cmake-utils_src_install
-	if use doc; then
-		cd "${CMAKE_BUILD_DIR}"/doc
-		dohtml -r html/*
-	fi
+	cmake-utils_src_install -j1
+
 	if use examples; then
-		cd "${CMAKE_BUILD_DIR}"/demos
+		cd "${BUILD_DIR}"/demos || die
 		dobin mandelbrot/mandelbrot opengl/quaternion_demo
 	fi
 }
-
-src_test() {
-	mycmakeargs=(
-		-DEIGEN_BUILD_TESTS=ON
-		-DEIGEN_TEST_NO_FORTRAN=ON
-	)
-	cmake-utils_src_configure
-	cmake-utils_src_compile
-	cmake-utils_src_test
-}