dev-ruby/elasticsearch-api: New package, needed by Infra

dev-ruby/elasticsearch-api/Manifest

@@ -0,0 +1 @@
+DIST elasticsearch-ruby-5.0.4.tar.gz 213565 SHA256 61151bcee155c6baebace1fb5d4091dc715af53251dc32dbca7d6fb0c9f5ecac SHA512 aaa4b1a41de62128cc3cc3fe174fd7f95e6153f25f1640dbd0cde5858e77924e85bd78e2869968c498b3f2f007215504aaee322df954ae44b0a64dacc396d217 WHIRLPOOL ebe23cdee9fdb56bc1c05fa86ca8dc8667d1ef36f3cc7cbd556cd3186dbfa9a3cdd5160a3a7a5e7464d69e264136beb3d9280107904f9f7f519b65adb2a4ae2b

dev-ruby/elasticsearch-api/elasticsearch-api-5.0.4.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby22 ruby23 ruby24"
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+RUBY_FAKEGEM_TASK_DOC=doc
+
+inherit ruby-fakegem
+
+MY_P=elasticsearch-ruby-${PV}
+DESCRIPTION="Ruby integrations for ES, elasticsearch-api module"
+HOMEPAGE="https://github.com/elastic/elasticsearch-ruby"
+SRC_URI="https://github.com/elastic/elasticsearch-ruby/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+ruby_add_rdepend "
+	dev-ruby/multi_json
+"
+ruby_add_bdepend "
+	doc? ( dev-ruby/yard )
+	test? (
+		dev-ruby/ansi
+		dev-ruby/elasticsearch-transport
+		dev-ruby/mocha:1.0
+		dev-ruby/pry
+		dev-ruby/shoulda-context
+	)
+"
+
+# Tests need additional modules (at least 'turn') packaged. Then someone
+# should look into running them and so on.
+RESTRICT="test"
+
+RUBY_S=${MY_P}/${PN}
+
+all_ruby_prepare() {
+	# fix to work without git
+	sed -i -e 's/git ls-files/find -type f/' *.gemspec || die
+
+	# remove useless dependencies from Rakefile
+	sed -e '/bundler/d' \
+		-e '/require.*cane/,/end/d' \
+		-i Rakefile || die
+}

dev-ruby/elasticsearch-api/metadata.xml

@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>mgorny@gentoo.org</email>
+		<name>Michał Górny</name>
+	</maintainer>
+</pkgmetadata>