dev-java/compile-testing: new package, add 0.23.0

test dependency of dev-java/auto-value

Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>
Part-of: https://github.com/gentoo/gentoo/pull/43470
Signed-off-by: Sam James <sam@gentoo.org>

dev-java/compile-testing/Manifest

@@ -0,0 +1 @@
+DIST compile-testing-0.23.0.tar.gz 64643 BLAKE2B b67aa411b0fa96ec6dd4d3d01da73b333b2ef3edaea4db85af6a3b890497bba80849ee8cddbaa56225704bba72a570cc44ac11c62fb84993b2bbb13c88decdb1 SHA512 691c1b02bfc12992f5167d33568e487a25855a4bca32e876a8e4fedb7893a0b6a4df81d58e0999c30698c70e5fcfb2ec91be268efafb7513f665625427cc40dc

dev-java/compile-testing/compile-testing-0.23.0.ebuild

@@ -0,0 +1,63 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Trouble with 'doc', seems to need '--add-exports'?
+JAVA_PKG_IUSE="source test"
+JAVA_TESTING_FRAMEWORKS="junit-4"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Testing tools for javac and annotation processors"
+HOMEPAGE="https://github.com/google/compile-testing"
+SRC_URI="https://github.com/google/compile-testing/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	dev-java/auto-value:0
+	dev-java/checker-framework-qual:0
+	dev-java/error-prone-annotations:0
+	dev-java/escapevelocity:0
+	>=dev-java/guava-33.4.8:0
+	dev-java/incap:0
+	dev-java/javapoet:0
+	dev-java/junit:4
+	dev-java/truth:0
+	>=virtual/jdk-1.8:*
+	test? (
+		>=dev-java/guava-testlib-33.4.8:0
+		dev-java/jspecify:0
+	)
+"
+
+RDEPEND=">=virtual/jre-1.8:*"
+
+JAVA_CLASSPATH_EXTRA="auto-value checker-framework-qual error-prone-annotations guava junit-4 truth"
+JAVA_SRC_DIR="src/main/java"
+JAVA_TEST_GENTOO_CLASSPATH="guava-testlib jspecify junit-4"
+JAVA_TEST_RESOURCE_DIRS="src/test/resources"
+JAVA_TEST_SRC_DIR="src/test/java"
+
+src_compile() {
+	# get processorpath
+	local pp="$(java-pkg_getjar --build-only auto-value auto-value.jar)"	# processor
+	pp="${pp}:$(java-pkg_getjar --build-only auto-value auto-common.jar)"	# dependencies
+	pp="${pp}:$(java-pkg_getjars --build-only escapevelocity,guava,incap,javapoet)"
+
+	JAVAC_ARGS=" -processorpath ${pp} -s src/main/java"
+
+	java-pkg-simple_src_compile
+}
+
+src_test() {
+	local vm_version="$(java-config -g PROVIDES_VERSION)"
+	if ver_test "${vm_version}" -ge 17; then
+		JAVA_TEST_EXTRA_ARGS=( --add-exports=jdk.compiler/com.sun.tools.javac.{api,file,parser,tree,util}=ALL-UNNAMED)
+	fi
+	java-pkg-simple_src_test
+}

dev-java/compile-testing/metadata.xml

@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>java@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">google/compile-testing</remote-id>
+	</upstream>
+</pkgmetadata>