kde-plasma/drkonqi: add 6.0.4

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2024-04-16 21:50:21 +02:00
parent 5398d08cdc
commit 313f0f29a2
2 changed files with 93 additions and 0 deletions
+1
View File
@@ -1,3 +1,4 @@
DIST drkonqi-5.27.11.tar.xz 865308 BLAKE2B 62d395cd6fa18c08037886ad1b9240f080789c651d6b46a4f24eaff67ff1cd36656c1700df33d4ccff21d6cc2abad4e965fa5f678e2739ac745ef8a5490bdbe4 SHA512 c4e4e02f6b039d67e9f82c30f92576127f99e202bef4f0098dd59e7bec6071b587e79c687e5f19571c2be0fc91545258d4059a2f09836c50810021043cd300fd
DIST drkonqi-5.27.8-revert-add-sentry-support.patch.xz 11996 BLAKE2B 17bf8c3e5c9a5bad200d22fa59b84a97caeca2c164d8b92a1dea665df7e73111401e82c1bacf5ab24c40fb21767c6dea38b38afd288d32190e1c72e453a38558 SHA512 50e448f311bde34c7e77a229aa7816899b7eb743b522d41bd31cc2b18741939a028fe42e267ba440560535fcb33890e3360e20d157a2e5959d2943ce8960491d
DIST drkonqi-6.0.3.tar.xz 873932 BLAKE2B 2da067d68903f7e7d8c54f3d4e2fe658cfa53d8db4c277681e9b0efd3a039b96bfce0bf4487eb3946fac78ea3bc7d110ca35cad9ef94a838dce12c3c1acd9ec1 SHA512 32d30f332215988dd945787c53485e3068b3e69d4d004df421ade30ccf0cf10dc570fb5539ca73c68b4c60011d5f2178253d5a5b624171e60e503db0ee5a19ca
DIST drkonqi-6.0.4.tar.xz 873360 BLAKE2B 0d9e466e36ad079692c70bd58868cc16bc5e263b981a3bf62f81dd9c7abd612b7d33b930152349499a15c576c0528f99b09b8089e2a952fec6cf12d1ee106f70 SHA512 38d6a41992e508d7779c216eb0a5538a9c860d76cebe189244796e4ab596c6e0fb21025bc5a790cd4eee3601007885abc61c62d26feac79c9b9d5065b20820f2
+92
View File
@@ -0,0 +1,92 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_TEST="forceoptional"
PYTHON_COMPAT=( python3_{11..12} )
KFMIN=6.0
QTMIN=6.6.2
inherit ecm plasma.kde.org python-single-r1 systemd
DESCRIPTION="Plasma crash handler, gives the user feedback if a program crashed"
SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${PN}-5.27.8-revert-add-sentry-support.patch.xz"
LICENSE="GPL-2" # TODO: CHECK
SLOT="6"
KEYWORDS="~amd64"
IUSE="systemd"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
COMMON_DEPEND="${PYTHON_DEPS}
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets]
>=dev-qt/qtdeclarative-${QTMIN}:6
>=kde-frameworks/kcmutils-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kidletime-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kjobwidgets-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
>=kde-frameworks/kwallet-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6
>=kde-frameworks/syntax-highlighting-${KFMIN}:6
systemd? (
>=dev-qt/qtbase-${QTMIN}:6[network]
>=kde-frameworks/kservice-${KFMIN}:6
sys-apps/systemd:=
>=sys-auth/polkit-qt-0.175.0[qt6]
)
"
DEPEND="${COMMON_DEPEND}
>=dev-qt/qtbase-${QTMIN}:6[concurrent]
test? ( >=dev-qt/qtbase-${QTMIN}:6[network] )
"
RDEPEND="${COMMON_DEPEND}
>=kde-frameworks/kirigami-${KFMIN}:6
>=kde-frameworks/kitemmodels-${KFMIN}:6
$(python_gen_cond_dep '
dev-python/psutil[${PYTHON_USEDEP}]
dev-python/pygdbmi[${PYTHON_USEDEP}]
dev-python/sentry-sdk[${PYTHON_USEDEP}]
')
|| (
dev-debug/gdb
dev-debug/lldb
)
"
pkg_setup() {
ecm_pkg_setup
python-single-r1_pkg_setup
}
src_configure() {
local mycmakeargs=(
-DWITH_PYTHON_VENDORING=OFF
$(cmake_use_find_package systemd Systemd)
)
ecm_src_configure
}
src_test() {
# needs network access, bug #698510
local myctestargs=(
-E "(connectiontest)"
)
ecm_src_test
}
pkg_postinst() {
if [[ -z ${REPLACING_VERSIONS} ]] && systemd_is_booted ; then
elog "For systemd, steps are needed for integration with systemd-coredumpd."
elog "As root, run the following:"
elog "1. systemctl enable drkonqi-coredump-processor@.service"
elog "2. systemctl --user enable --now --global drkonqi-coredump-launcher.socket"
fi
}