net-misc/lldpd-1.0.9: Version bump

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

net-misc/lldpd/Manifest

@@ -1 +1,2 @@
 DIST lldpd-1.0.7.tar.gz 1815150 BLAKE2B 53bd73ce4cadf9c49f93a7ec5459adba0076d40156ba25c9ea6985b10a2cfec74a741318e74fa59bf560ce129eed2faf2964c093019b27e922c3dd10ed7daa13 SHA512 32fc153d0376db797163e4654c75cc8d10c35b85d7bb611996920bf67dfd2f30e154328a6e81837d9f77e8b4b7dd9ba76c81c5dd5847faa083654b8405d0bd69
+DIST lldpd-1.0.9.tar.gz 1961522 BLAKE2B 83a853bb3bde7abd15b4aa167d213d97677db817aba773b152f032b0d0bf299d5cc891c56871182b2f11fc3bfb2d6c88153f32973fdec5844df5c6fc6bc97b8b SHA512 5f5d5abed7fc73efc59932a1f2ee07eedbdca6f82d002221886b4ddf704955aef432acb92084adc72a965fef3e660f3c95b2a1b8892cf05d9616921501e6aae0

net-misc/lldpd/lldpd-1.0.9.ebuild

@@ -0,0 +1,98 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit systemd bash-completion-r1 autotools tmpfiles
+
+DESCRIPTION="Implementation of IEEE 802.1ab (LLDP)"
+HOMEPAGE="https://vincentbernat.github.com/lldpd/"
+SRC_URI="http://media.luffy.cx/files/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/4.9.0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cdp doc +dot1 +dot3 edp fdp graph +lldpmed old-kernel sanitizers
+	seccomp sonmp snmp static-libs test readline xml zsh-completion"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-group/lldpd
+	acct-user/lldpd
+	dev-libs/libbsd
+	>=dev-libs/libevent-2.1.11:=
+	sys-libs/readline:0=
+	seccomp? ( sys-libs/libseccomp:= )
+	snmp? ( net-analyzer/net-snmp[extensible(+)] )
+	xml? ( dev-libs/libxml2:= )
+	zsh-completion? ( app-shells/zsh )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check )
+"
+BDEPEND="virtual/pkgconfig
+	doc? (
+		graph? ( app-doc/doxygen[dot] )
+		!graph? ( app-doc/doxygen )
+	)
+"
+
+REQUIRED_USE="graph? ( doc )"
+
+src_prepare() {
+	default
+
+	eautoreconf
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		--without-embedded-libevent \
+		--with-privsep-user=${PN} \
+		--with-privsep-group=${PN} \
+		--with-privsep-chroot=/run/${PN} \
+		--with-lldpd-ctl-socket=/run/${PN}.socket \
+		--with-lldpd-pid-file=/run/${PN}.pid \
+		$(use_enable cdp) \
+		$(use_enable doc doxygen-man) \
+		$(use_enable doc doxygen-pdf) \
+		$(use_enable doc doxygen-html) \
+		$(use_enable dot1) \
+		$(use_enable dot3) \
+		$(use_enable edp) \
+		$(use_enable fdp) \
+		$(use_enable graph doxygen-dot) \
+		$(use_enable lldpmed) \
+		$(use_enable old-kernel oldies) \
+		$(use_enable sonmp) \
+		$(use_enable static-libs static) \
+		$(use_with readline) \
+		$(use_enable sanitizers) \
+		$(use_with seccomp) \
+		$(use_with snmp) \
+		$(use_with xml)
+}
+
+src_compile() {
+	emake
+	use doc && emake doxygen-doc
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	find "${D}" -name '*.la' -delete || die
+
+	newinitd "${FILESDIR}"/${PN}-initd-5 ${PN}
+	newconfd "${FILESDIR}"/${PN}-confd-1 ${PN}
+	newbashcomp src/client/completion/lldpcli lldpcli
+
+	use doc && dodoc -r doxygen/html
+
+	insinto /etc
+	doins "${FILESDIR}/lldpd.conf"
+	keepdir /etc/${PN}.d
+
+	systemd_dounit "${FILESDIR}"/${PN}.service
+	newtmpfiles "${FILESDIR}"/tmpfilesd ${PN}.conf
+}