dev-python/logbook: Bump to 1.7.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/logbook/Manifest

@@ -1 +1,2 @@
 DIST logbook-1.6.0.gh.tar.gz 364463 BLAKE2B f1e2187f87c9a0530e8cf62032285afcf08742b927aab269cf2e4707a040d15e1ab3c0e994b3cbc56857bebbea5d598f3981a24f94c2aa9d8322e9f0f7ec76d8 SHA512 7037c93bcaf0d3b53456869269c7317920f111ecfb3ebe930f471e031376819afd018ddf0b25a46f2a7d1a3111cd5d35828da1885935ee9508e2712e5bb7c724
+DIST logbook-1.7.0.gh.tar.gz 364752 BLAKE2B a801c2ec55a257250336748007bdb95206372cf8cf3492785c5c50829e3e3c467de564401ed6f758f3e6b14d708d889860a4bb93da5119fc134df5167976bebb SHA512 50b52f54e894be303a7e910602cfbbceee04280cb134ad89f32f0a79c21d509ae0f6ae83beac9a9e22726d1c394e9893eea884ff43b56aae9dbad6dd1221d96f

dev-python/logbook/logbook-1.7.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A logging replacement for Python"
+HOMEPAGE="
+	https://logbook.readthedocs.io/en/stable/
+	https://github.com/getlogbook/logbook/
+	https://pypi.org/project/Logbook/
+"
+SRC_URI="
+	https://github.com/getlogbook/logbook/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+BDEPEND="
+	test? (
+		app-arch/brotli[${PYTHON_USEDEP},python]
+		>=dev-python/execnet-1.0.9[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/pip[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/pyzmq[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.4[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	!!dev-python/contextvars
+	!!dev-python/gevent
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs
+
+python_configure_all() {
+	export DISABLE_LOGBOOK_CEXT=1
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Delete test file requiring local connection to redis server
+		tests/test_queues.py
+		# https://github.com/getlogbook/logbook/issues/318
+		tests/test_ticketing.py::test_basic_ticketing
+	)
+
+	epytest -p no:flaky
+}