mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-06 02:17:34 -08:00
games-roguelike/stone-soup: add 0.33.0_pre20250216
Signed-off-by: Erik Mackdanz <stasibear@gentoo.org>
This commit is contained in:
Erik Mackdanz
parent
8b5498809e
commit
30e44f0973
@ -18,6 +18,9 @@ DIST stone-soup-0.31.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d2
|
||||
DIST stone-soup-0.32.1.tar.gz 24409881 BLAKE2B 29bf6b36c858a7426b6dfc8d75aebe575540cf89a934ce9150134c68e55b23e1e2a2da0cc53db3c3f59eff2810ed68b5577d709e8515d2e51bf46206b8c0710b SHA512 0640b3af9be104963f635b61b71ee59d18f478d3266e6c3319db13584c92b19e6bea3789e6d90bb520424b6995efba4d9e8a56216a0d1a1158a2c01f00799894
|
||||
DIST stone-soup-0.32.png 1351 BLAKE2B cc31abd59701aa6f0fb0bdcd90630ceebf7b3cb8b60f0e2817f8800c5bc4b3a5b9fef63c90a97b6248f306e7e3da0df3863a2195b8771863344d2443e7956d59 SHA512 4695204c8b936f7aac1ba15b02a6115a955fb2c56aa9a0b968ff007bc9a1a59b608110d60cce5625a9b92cd2c869bbea7e15433a53c1a338622809477a5846bc
|
||||
DIST stone-soup-0.32.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d248c3fd5b06e308782bbc651814f21ec958b30c36074a2576ced4bb10f291b5236da6f6e865ce1d7cefdf96d SHA512 dca555271faf704eb8ecdf5ee8a763df42cdeba94e9c163608c438cfc73c6fbf53416547050cad57f477ade191842e701785b65b7a9f18e27ceab05df8f2f75f
|
||||
DIST stone-soup-0.33.0_pre20250216.tar.gz 26322023 BLAKE2B bb1a425b3bbfd694d5a2d4f1ec5be685e53f4fc26560f78914900c9a857a80e55bd81f5a31bc13643f7339ed09a338f6773c0ea85a4102964046a5a619e363b0 SHA512 6e7a722522dfdee4adfc5de91cca3f704df7844751a8bfa2c8a5602f7409d9a523126b8138f01f7c34f2b763013e98b3a14e6cdb70ad124a89b4e04f6a60529e
|
||||
DIST stone-soup-0.33.png 1351 BLAKE2B cc31abd59701aa6f0fb0bdcd90630ceebf7b3cb8b60f0e2817f8800c5bc4b3a5b9fef63c90a97b6248f306e7e3da0df3863a2195b8771863344d2443e7956d59 SHA512 4695204c8b936f7aac1ba15b02a6115a955fb2c56aa9a0b968ff007bc9a1a59b608110d60cce5625a9b92cd2c869bbea7e15433a53c1a338622809477a5846bc
|
||||
DIST stone-soup-0.33.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d248c3fd5b06e308782bbc651814f21ec958b30c36074a2576ced4bb10f291b5236da6f6e865ce1d7cefdf96d SHA512 dca555271faf704eb8ecdf5ee8a763df42cdeba94e9c163608c438cfc73c6fbf53416547050cad57f477ade191842e701785b65b7a9f18e27ceab05df8f2f75f
|
||||
DIST stone_soup-0.25.1.zip 95477710 BLAKE2B 0b38a6c7cb7c4c87acccb861b5aae665cd2b6b532f6e86d4a9fa594e0d363b86b4af1ea47275f7fd026ea69d85215be8cdf46258bd620e738b4850e5eceed006 SHA512 fa7e8be582c5c6615531884ade4c113542c06c164b6912095c1adf2f16a31cb2ecce057d74132b11b1b1c256a77433037948d4e54819739b7e222cc896cd5220
|
||||
DIST stone_soup-0.26.1.zip 95585384 BLAKE2B 6d1cb99fc44e918cad4144608f259e67a26df444b93c8501590ff209e8856fd08c514d4c8c78cb0848d8e6127cdf4360b47d21ced5d919da982421934b46102d SHA512 637f1a07e9f35e18eda10c17dc28449364c56aee8456497e30552acb55608a9433cff8b64af877049c21cb2a42eb2fcad28f58a7e57a1d835eb8c252e580205d
|
||||
DIST stone_soup-0.27.1.zip 96934633 BLAKE2B 8821920a4faad9474f08a34ae3c272cb9dcd3ddeb9029e033c22eb8e6650ef20bbc30e0c0ca1556d08c1b7b898fdbdd3667a3ac9a8527e0c322cd8c78ab391bb SHA512 845dafc9895ada3712903de63b95cca9eeb66160e4a04ba21193d916447fca8e7248b851f1e938f43b8d3937cf4f4437443bdc4fe2da893fe3918fed4e0b5204
|
||||
|
||||
241
games-roguelike/stone-soup/stone-soup-0.33.0_pre20250216.ebuild
Normal file
241
games-roguelike/stone-soup/stone-soup-0.33.0_pre20250216.ebuild
Normal file
@ -0,0 +1,241 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
# There are many slots for this package because people in the community
|
||||
# like to play old versions. Every release includes content changes
|
||||
# where species/spells/monsters are added or removed. The public
|
||||
# servers (e.g. http://crawl.akrasiac.org:8080) usually support playing
|
||||
# versions back to 0.11.
|
||||
|
||||
# It's not necessary for Gentoo to support these old version but it's
|
||||
# something nice that our distro can offer that others don't. If the
|
||||
# maintenance burden becomes excessive than we can revisit that
|
||||
# position.
|
||||
|
||||
EAPI=8
|
||||
|
||||
LUA_COMPAT=( lua5-1 )
|
||||
LUA_REQ_USE="deprecated"
|
||||
PYTHON_COMPAT=( python3_{10,11,12,13} )
|
||||
VIRTUALX_REQUIRED="manual"
|
||||
inherit desktop python-any-r1 lua-single xdg-utils toolchain-funcs
|
||||
|
||||
DESCRIPTION="Role-playing roguelike game of exploration and treasure-hunting in dungeons"
|
||||
HOMEPAGE="https://crawl.develz.org"
|
||||
|
||||
# Leave empty string if not a _pre release
|
||||
COMMITSHA="874f29ee333329d86c8266cbcf63b41cc999812f"
|
||||
if [ -z "${COMMITSHA}" ]; then
|
||||
# This is a tagged release
|
||||
# Note the archive URI and file layout changed upstream between 0.29.0 and 0.29.1
|
||||
SRC_URI="
|
||||
https://github.com/crawl/crawl/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz
|
||||
"
|
||||
MY_P="crawl-${PV}/crawl-ref"
|
||||
else
|
||||
# This is a _pre release
|
||||
SRC_URI="
|
||||
https://github.com/crawl/crawl/archive/${COMMITSHA}.tar.gz -> ${P}.tar.gz
|
||||
"
|
||||
MY_P="crawl-${COMMITSHA}/crawl-ref"
|
||||
fi
|
||||
# MY_SLOT to satisfy pkgcheck variable order checking
|
||||
MY_SLOT="0.33"
|
||||
SRC_URI="
|
||||
${SRC_URI}
|
||||
https://dev.gentoo.org/~stasibear/distfiles/${PN}.png -> ${PN}-${MY_SLOT}.png
|
||||
https://dev.gentoo.org/~stasibear/distfiles/${PN}.svg -> ${PN}-${MY_SLOT}.svg
|
||||
"
|
||||
|
||||
S=${WORKDIR}/${MY_P}/source
|
||||
# 3-clause BSD: mt19937ar.cc, MSVC/stdint.h
|
||||
# 2-clause BSD: all contributions by Steve Noonan and Jesse Luehrs
|
||||
# Public Domain|CC0: most of tiles
|
||||
# MIT: json.cc/json.h, some .js files in webserver/static/scripts/contrib/
|
||||
LICENSE="GPL-2 BSD BSD-2 public-domain CC0-1.0 MIT"
|
||||
SLOT="${MY_SLOT}"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
IUSE="advpng debug ncurses sound test +tiles"
|
||||
RESTRICT="!test? ( test )"
|
||||
REQUIRED_USE="${LUA_REQUIRED_USE}"
|
||||
|
||||
RDEPEND="
|
||||
${LUA_DEPS}
|
||||
dev-db/sqlite:3
|
||||
sys-libs/zlib
|
||||
!ncurses? ( !tiles? ( sys-libs/ncurses:0 ) )
|
||||
ncurses? ( sys-libs/ncurses:0 )
|
||||
tiles? (
|
||||
media-fonts/dejavu
|
||||
media-libs/freetype:2
|
||||
media-libs/libpng:0
|
||||
sound? (
|
||||
media-libs/libsdl2[X,opengl,sound,video]
|
||||
media-libs/sdl2-mixer
|
||||
)
|
||||
!sound? ( media-libs/libsdl2[X,opengl,video] )
|
||||
media-libs/sdl2-image[png]
|
||||
virtual/glu
|
||||
virtual/opengl
|
||||
)"
|
||||
DEPEND="${RDEPEND}
|
||||
test? ( <dev-cpp/catch-3.0.0:0 )
|
||||
tiles? (
|
||||
sys-libs/ncurses:0
|
||||
)
|
||||
"
|
||||
BDEPEND="
|
||||
app-arch/unzip
|
||||
dev-lang/perl
|
||||
${PYTHON_DEPS}
|
||||
$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
|
||||
app-alternatives/lex
|
||||
tiles? (
|
||||
advpng? (
|
||||
app-arch/advancecomp
|
||||
)
|
||||
!advpng? (
|
||||
media-gfx/pngcrush
|
||||
)
|
||||
)
|
||||
virtual/pkgconfig
|
||||
app-alternatives/yacc
|
||||
"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/make-v3.patch
|
||||
"${FILESDIR}"/rltiles-make.patch
|
||||
"${FILESDIR}"/avoid-musl-execinfo.patch
|
||||
)
|
||||
|
||||
python_check_deps() {
|
||||
python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
|
||||
}
|
||||
|
||||
pkg_setup() {
|
||||
python-any-r1_pkg_setup
|
||||
|
||||
if use !ncurses && use !tiles ; then
|
||||
ewarn "Neither ncurses nor tiles frontend"
|
||||
ewarn "selected, choosing ncurses only."
|
||||
ewarn "Note that you can also enable both."
|
||||
fi
|
||||
|
||||
if use sound && use !tiles ; then
|
||||
ewarn "Sound support is only available with tiles."
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
python_fix_shebang "${S}/util/species-gen.py"
|
||||
|
||||
if use advpng; then
|
||||
eapply "${FILESDIR}/make-advpng.patch"
|
||||
fi
|
||||
|
||||
sed -i -e "s/GAME = crawl$/GAME = crawl-${SLOT}/" "${S}/Makefile" \
|
||||
|| die "Couldn't append slot to executable name"
|
||||
|
||||
# File required for a _pre build
|
||||
if ! [ -f "${S}/util/release_ver" ]; then
|
||||
echo "${SLOT}" >"${S}/util/release_ver" || die "Couldn't write release_ver"
|
||||
fi
|
||||
|
||||
# Replace bundled catch2 package with system implementation
|
||||
# https://bugs.gentoo.org/829950
|
||||
if use test; then
|
||||
cp /usr/include/catch2/catch.hpp "${S}/catch2-tests" || die "Couldn't substitute system catch2"
|
||||
fi
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
|
||||
# Insurance that we're not using bundled lib sources
|
||||
rm -rf contrib || die "Couldn't delete contrib directory"
|
||||
|
||||
myemakeargs=(
|
||||
$(usex debug "FULLDEBUG=y DEBUG=y" "")
|
||||
BUILD_LUA=
|
||||
AR="$(tc-getAR)"
|
||||
CFOPTIMIZE=''
|
||||
# -DLUA_COMPAT_OPENLIB=1 is required to enable the
|
||||
# deprecated (in 5.1) luaL_openlib API (#869671)
|
||||
CFOTHERS="${CXXFLAGS} -DLUA_COMPAT_OPENLIB=1"
|
||||
CONTRIBS=
|
||||
DATADIR="/usr/share/${PN}-${SLOT}"
|
||||
FORCE_CC="$(tc-getCC)"
|
||||
FORCE_CXX="$(tc-getCXX)"
|
||||
LDFLAGS="${LDFLAGS}"
|
||||
MAKEOPTS="${MAKEOPTS}"
|
||||
PKGCONFIG="$(tc-getPKG_CONFIG)"
|
||||
RANLIB="$(tc-getRANLIB)"
|
||||
SAVEDIR="~/.crawl-${SLOT}"
|
||||
SOUND=$(usex sound "y" "")
|
||||
STRIP=touch
|
||||
USE_LUAJIT=
|
||||
V=1
|
||||
prefix="/usr"
|
||||
)
|
||||
|
||||
if use ncurses || (use !ncurses && use !tiles) ; then
|
||||
emake "${myemakeargs[@]}"
|
||||
# move it in case we build both variants
|
||||
use tiles && { mv "crawl-${SLOT}" "${WORKDIR}"/crawl-ncurses-${SLOT} || die ;}
|
||||
fi
|
||||
|
||||
if use tiles ; then
|
||||
emake "${myemakeargs[@]}" clean
|
||||
emake "${myemakeargs[@]}" "TILES=y"
|
||||
fi
|
||||
}
|
||||
|
||||
src_test() {
|
||||
emake "${myemakeargs[@]}" \
|
||||
$(usex tiles "TILES=y" "") \
|
||||
catch2-tests
|
||||
}
|
||||
|
||||
src_install() {
|
||||
emake "${myemakeargs[@]}" \
|
||||
$(usex tiles "TILES=y" "") \
|
||||
DESTDIR="${D}" \
|
||||
prefix_fp="" \
|
||||
bin_prefix="${D}/usr/bin" \
|
||||
install
|
||||
|
||||
[[ -e "${WORKDIR}/crawl-ncurses-${SLOT}" ]] && dobin "${WORKDIR}/crawl-ncurses-${SLOT}"
|
||||
|
||||
# don't relocate docs, needed at runtime
|
||||
rm -rf "${D}/usr/share/${PN}-${SLOT}"/docs/license
|
||||
|
||||
mv "${WORKDIR}/${MY_P}"/docs/crawl.6 "${WORKDIR}/${MY_P}/docs/crawl-${SLOT}.6" \
|
||||
|| die "Couldn't append slot to man page name"
|
||||
doman "${WORKDIR}/${MY_P}/docs/crawl-${SLOT}.6"
|
||||
|
||||
# icons and menu for graphical build
|
||||
if use tiles ; then
|
||||
doicon -s 48 "${DISTDIR}"/${PN}-${SLOT}.png
|
||||
doicon -s scalable "${DISTDIR}"/${PN}-${SLOT}.svg
|
||||
make_desktop_entry "crawl-${SLOT}" "crawl-${SLOT}" "crawl-${SLOT}"
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_icon_cache_update
|
||||
|
||||
elog "crawl is a slotted install that supports having"
|
||||
elog "multiple versions installed. The binary has the"
|
||||
elog "slot appended, e.g. 'crawl-"${SLOT}"'."
|
||||
|
||||
if use tiles && use ncurses ; then
|
||||
elog
|
||||
elog "Since you have enabled both tiles and ncurses frontends"
|
||||
elog "the ncurses binary is called 'crawl-ncurses-"${SLOT}"' and the"
|
||||
elog "tiles binary is called 'crawl-"${SLOT}"'."
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
xdg_icon_cache_update
|
||||
}
|
||||
Loading…
x
Reference in New Issue
Block a user