dev-python/tox: Bump to 3.25.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/tox/Manifest

@@ -1 +1,2 @@
 DIST tox-3.25.0.tar.gz 307073 BLAKE2B 2dda34fc6d6518897bdc587ca6a31b92f2add463c3bcce9df3f4e511d2588dc75265b60809195c2d78a9c1b0d08d79c32811aab1e2c01934faf40019a1882042 SHA512 9c10524c5a67b32a01cb0dd4d25cc01d0641e46ca4e0c03a4c76eb8913f6038075aeb21e647a94d6b8d99c80edb7701b1c62893ebd6a20584121fdf33b9d9010
+DIST tox-3.25.1.gh.tar.gz 307697 BLAKE2B 2c778df22388b101e6e68423636c9753f0e6faac2360184fd6b9022dc3bbb5662840cf24e7907dd4c652f6401723be3be35bcdeb0f290f9839325babf5ec776d SHA512 e0443cb72378fc18c9bc001413261d9bac2d6f89bb0ebff618a3848ffd5b02c80902cefbd90f7b0d0e3119f1df3cd22b46be23077db0ee90c03a9780ba4b248b

dev-python/tox/tox-3.25.1.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+SRC_URI="
+	https://github.com/tox-dev/tox/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	dev-python/py[${PYTHON_USEDEP}]
+	>=dev-python/six-1.14[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/flaky-3.4.0[${PYTHON_USEDEP}]
+		>=dev-python/freezegun-0.3.11[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken without Internet
+		tests/unit/session/test_provision.py::test_provision_non_canonical_dep
+		tests/integration/test_provision_int.py::test_provision_interrupt_child
+
+		# expects python2 to exist
+		tests/unit/interpreters/test_interpreters.py::test_tox_get_python_executable
+	)
+
+	[[ ${EPYTHON} != pypy3 ]] && EPYTEST_DESELECT+=(
+		# capfd doesn't seem to work for some non-obvious reason
+		tests/unit/test_z_cmdline.py::TestSession::test_summary_status
+		tests/unit/session/test_provision.py::test_provision_bad_requires
+
+		# TODO?
+		tests/unit/interpreters/test_interpreters.py::test_find_alias_on_path
+	)
+
+	epytest --no-network
+}