www-client/opera: automated bump (83.0.4254.27)

Signed-off-by: Stephan Hartmann <sultan@gentoo.org>
This commit is contained in:
Stephan Hartmann
2022-02-06 17:35:50 +01:00
parent b34839c133
commit 2ff884f30f
3 changed files with 158 additions and 5 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST opera-ffmpeg-codecs-96.0.4655.7.tar.xz 1394152 BLAKE2B a48c1f22b5e92e40d8d5f97f02505021824823796767c1725c821b171b3ff6bf281d0123bf0b7e336f4d81b84bbf9362c6489f30b7de7c2037238c53003d6e00 SHA512 7c6815936e9a027d278a893e90e30f28a3d011ec83723c6500bee7ba0dddc5c96ae3cd75d7e16f7bbd2f9ee635fb64bdba6c2ba1df32761a6215be6eb3d5ec5c
DIST opera-stable_82.0.4227.43_amd64.deb 79663172 BLAKE2B 0f3377516cb82216974dc4e01b127b172029f103685184855774420948eb165bae8e2a128b6e7056dadbeebba1af70912647b9621dcac916a58055bcc7aadf28 SHA512 736ef3cfdb50e9553b85f23fe3532f4b34ff078bd48ec7e9812e3d4e3495cddc6554a67816f1d3bb949c677c3e75586ba782af0a7e0abc5bdc93aba1890aabf7
DIST opera-stable_83.0.4254.27_amd64.deb 79626476 BLAKE2B 4104218c095b504906496ff0e97399f69acaf501d55a49ba80919da57b62c86d63d0e3ed95f77cd5eb78e1d00284219f828215acfec49c2cb84ece7b545e5d91 SHA512 a700bede14eac92c62d2b0b622c1a58f55f1b88c82352b16e67085a821379dffd7adcdd3b275c476235f54cefd639f4d081c05eede446aac7a26d982b84a186d
-5
View File
@@ -5,11 +5,6 @@
<email>chromium@gentoo.org</email>
<name>Chromium in Gentoo Project</name>
</maintainer>
<longdescription>
Opera is a graphical Web browser available on several platforms. The desktop
version runs on GNU/Linux and FreeBSD. Versions for Macintosh and
Windows are also available.
</longdescription>
<use>
<flag name="proprietary-codecs">Enable codecs for patent-encumbered audio and video formats.</flag>
</use>
+157
View File
@@ -0,0 +1,157 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
CHROMIUM_LANGS="
be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
zh-CN zh-TW
"
# These are intended for ebuild maintainer use to force RPM if DEB is not available.
: ${OPERA_FORCE_RPM=no}
inherit chromium-2 pax-utils xdg
if [[ ${OPERA_FORCE_RPM} == yes ]]; then
inherit rpm
OPERA_ARCHIVE_EXT="rpm"
else
inherit unpacker
OPERA_ARCHIVE_EXT="deb"
fi
DESCRIPTION="A fast and secure web browser"
HOMEPAGE="https://www.opera.com/"
LICENSE="OPERA-2018"
SLOT="0"
SRC_URI_BASE=(
"https://download1.operacdn.com/pub/${PN}"
"https://download2.operacdn.com/pub/${PN}"
"https://download3.operacdn.com/pub/${PN}"
"https://download4.operacdn.com/pub/${PN}"
)
if [[ ${PN} == opera ]]; then
MY_PN=${PN}-stable
SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
else
MY_PN=${PN}
fi
KEYWORDS="-* ~amd64"
FFMPEG_VERSION="96.0.4655.7"
SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
proprietary-codecs? (
mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
)"
IUSE="+proprietary-codecs suid"
RESTRICT="bindist mirror strip"
RDEPEND="
app-accessibility/at-spi2-atk:2
app-accessibility/at-spi2-core:2
dev-libs/atk
dev-libs/expat
dev-libs/glib:2
dev-libs/nspr
dev-libs/nss
gnome-base/gsettings-desktop-schemas
media-libs/alsa-lib
media-libs/mesa[gbm(+)]
net-misc/curl
net-print/cups
sys-apps/dbus
x11-libs/cairo
x11-libs/gdk-pixbuf
x11-libs/gtk+:3
x11-libs/libdrm
x11-libs/libxcb
x11-libs/libxkbcommon
x11-libs/libxshmfence
x11-libs/libX11
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXrandr
x11-libs/pango
"
QA_PREBUILT="*"
S=${WORKDIR}
OPERA_HOME="opt/opera${PN#opera}"
pkg_pretend() {
# Protect against people using autounmask overzealously
use amd64 || die "opera only works on amd64"
}
pkg_setup() {
chromium_suid_sandbox_check_kernel_config
}
src_unpack() {
:
}
src_install() {
dodir /
cd "${ED}" || die
if [[ ${OPERA_FORCE_RPM} == yes ]]; then
rpm_src_unpack "${A[0]}"
else
unpacker
fi
# move to /opt, bug #573052
mkdir -p "${OPERA_HOME%${PN}}"
if [[ ${OPERA_FORCE_RPM} == yes ]]; then
mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
else
mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
fi
rm -r "usr/lib" || die
# disable auto update
rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
if [[ ${OPERA_FORCE_RPM} == yes ]]; then
rm "${OPERA_HOME}/setup_repo.sh" || die
else
rm -r "usr/share/lintian" || die
# fix docs
mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
gzip -d usr/share/doc/${PF}/changelog.gz || die
fi
# fix desktop file
sed -i \
-e 's|^TargetEnvironment|X-&|g' \
usr/share/applications/${PN}.desktop || die
# remove unused language packs
pushd "${OPERA_HOME}/localization" > /dev/null || die
chromium_remove_language_paks
popd > /dev/null || die
# setup opera symlink
rm "usr/bin/${PN}" || die
dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
# install proprietary codecs
rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
if use proprietary-codecs; then
mv lib_extra "${OPERA_HOME}"
fi
# pax mark opera, bug #562038
pax-mark m "${OPERA_HOME}/opera"
# enable suid sandbox if requested
use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
}