dev-python/pygobject: Version bump to 3.40.1

Signed-off-by: Matt Turner <mattst88@gentoo.org>

dev-python/pygobject/Manifest

@@ -1,2 +1,3 @@
 DIST pygobject-3.38.0.tar.xz 553892 BLAKE2B d6add416c3f87ee9d5a56f30dbcaa599682ec5932b204f7c743d50475503ea2705e7943e6a93610d6f1c9d322723d1df6ea0f19c1cf245b2ca7d49395ca36170 SHA512 d63313dea2c143cf8c08a4678f1aa8e5908d503ad29c596eeb9fa1070e1231de57cf934c33031f9c4920b85e391f3b4143b46491ffd16e04e8d48871cb05e5df
 DIST pygobject-3.40.0.tar.xz 555920 BLAKE2B e7b3fa926066ddc6992c3087a582e25207ffb34f5c847be705953d8498f307661822462ceaa6362d120e96556a50882ed78540fce5cd2e97f0a4fd11232fe01c SHA512 c0c617e5678f942db33bdff6e149e438bd7d5f4e0a4e0a112476515d1face1c6e992457f998a5077a08bdacc1bda24711b29a4312bd3ee825b526d54a7ca3db7
+DIST pygobject-3.40.1.tar.xz 556104 BLAKE2B e6a092bee68121d9ef82f41f21c9811f384b8578c48de445f707f1b0de124cf38d899d34b8f4269a154ebd4e323afdfa7afef5c0c5cc5dc451b2cd68b30da04b SHA512 a8350f43ea99c93aa66a23102d4ee2ca3c7f8ec2c8bcf5cd142dd097b4fb38167f1713efff3584aa323c34656c911fb940e462c83c02b107e4aad93d005022f7

dev-python/pygobject/pygobject-3.40.1.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit gnome.org meson python-r1 virtualx xdg
+
+DESCRIPTION="Python bindings for GObject Introspection"
+HOMEPAGE="https://pygobject.readthedocs.io/"
+
+LICENSE="LGPL-2.1+"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="+cairo examples test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-libs/glib-2.56:2
+	>=dev-libs/gobject-introspection-1.56:=
+	dev-libs/libffi:=
+	cairo? (
+		>=dev-python/pycairo-1.16.0[${PYTHON_USEDEP}]
+		x11-libs/cairo[glib] )
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-libs/atk[introspection]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		x11-libs/gdk-pixbuf:2[introspection,jpeg]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/pango[introspection]
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	configuring() {
+		meson_src_configure \
+			$(meson_feature cairo pycairo) \
+			$(meson_use test tests) \
+			-Dpython="${EPYTHON}"
+	}
+
+	python_foreach_impl configuring
+}
+
+src_compile() {
+	python_foreach_impl meson_src_compile
+}
+
+src_test() {
+	local -x GIO_USE_VFS="local" # prevents odd issues with deleting ${T}/.gvfs
+	local -x GIO_USE_VOLUME_MONITOR="unix" # prevent udisks-related failures in chroots, bug #449484
+
+	testing() {
+		local -x XDG_CACHE_HOME="${T}/${EPYTHON}"
+		meson_src_test || die "test failed for ${EPYTHON}"
+	}
+	virtx python_foreach_impl testing
+}
+
+src_install() {
+	installing() {
+		meson_src_install
+		python_optimize
+	}
+	python_foreach_impl installing
+	use examples && dodoc -r examples
+}