mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
media-video/obs-studio: add version 24.0.5
Package-Manager: Portage-2.3.81, Repoman-2.3.20 Signed-off-by: Jimi Huotari <chiitoo@gentoo.org> Closes: https://github.com/gentoo/gentoo/pull/13991 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Jimi Huotari
committed by
Andreas Sturmlechner
Andreas Sturmlechner
parent
011154dcca
commit
2fe2645dcb
@@ -1,2 +1,3 @@
|
||||
DIST obs-studio-23.2.1.tar.gz 6204515 BLAKE2B bd025a1ec2809e8a0b47fba79c6a3d40feb255a03a461725501a9c7cdbc40c04b75ff714fa4b3787f876a3f524f3371119a3ea9666c3aeb003184f1eb2a63123 SHA512 aabc23d825c2ca3f40274a8e2c4935939dab4955d929c44b28cebde114e808543c1c0dc05791bb6d9f2611effb0f2cb3e20c9a653154c30a9851ea94e74c8169
|
||||
DIST obs-studio-24.0.3.tar.gz 6285359 BLAKE2B f799e93e9c35c22e5d7f6e4da04e30b06a3a1ad1b3bfd0a75acdbb5d1f28a717d84809a1f35a858252ff30094fa80521d752a35b5285b0a606d0d77ff88fb3cf SHA512 57cef700076457da1eee344042261e1ada6d6744fcb3033a1d4eaffb9e84dd350aa198984fba3de82d4e727706f562c7c3568d95de6859a4942d9fa6368a02ab
|
||||
DIST obs-studio-24.0.5.tar.gz 7901198 BLAKE2B 79c9712f3523114a70e0df3e0631c19067fd7ead5fd9031123dd4c82d9b92dee69473fb51a495f938430540505a5cf45258eeee01d61a7aaa6654255fee14aca SHA512 99be46046b70597474f25a85036ebe5a2f704eef47c77bc27e2ba8890b877da346ff6008c5922d7a83a4cead9df7214c6a3be885430693e609a42d9d06fedfaf
|
||||
|
||||
132
media-video/obs-studio/obs-studio-24.0.5.ebuild
Normal file
132
media-video/obs-studio/obs-studio-24.0.5.ebuild
Normal file
@@ -0,0 +1,132 @@
|
||||
# Copyright 1999-2019 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
CMAKE_REMOVE_MODULES_LIST=( FindFreetype )
|
||||
PYTHON_COMPAT=( python3_{5,6,7} )
|
||||
|
||||
inherit cmake-utils python-single-r1 xdg-utils
|
||||
|
||||
if [[ ${PV} == *9999 ]]; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://github.com/obsproject/obs-studio.git"
|
||||
EGIT_SUBMODULES=()
|
||||
else
|
||||
SRC_URI="https://github.com/obsproject/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
fi
|
||||
|
||||
DESCRIPTION="Software for Recording and Streaming Live Video Content"
|
||||
HOMEPAGE="https://obsproject.com"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
IUSE="+alsa fdk imagemagick jack luajit nvenc pulseaudio python speex +ssl truetype v4l vlc"
|
||||
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
|
||||
|
||||
BDEPEND="
|
||||
luajit? ( dev-lang/swig )
|
||||
python? ( dev-lang/swig )
|
||||
"
|
||||
DEPEND="
|
||||
>=dev-libs/jansson-2.5
|
||||
dev-qt/qtcore:5
|
||||
dev-qt/qtdeclarative:5
|
||||
dev-qt/qtgui:5
|
||||
dev-qt/qtmultimedia:5
|
||||
dev-qt/qtnetwork:5
|
||||
dev-qt/qtquickcontrols:5
|
||||
dev-qt/qtsql:5
|
||||
dev-qt/qtsvg:5
|
||||
dev-qt/qtwidgets:5
|
||||
dev-qt/qtx11extras:5
|
||||
media-video/ffmpeg:=[x264]
|
||||
net-misc/curl
|
||||
x11-libs/libXcomposite
|
||||
x11-libs/libXinerama
|
||||
x11-libs/libXrandr
|
||||
alsa? ( media-libs/alsa-lib )
|
||||
fdk? ( media-libs/fdk-aac:= )
|
||||
imagemagick? ( media-gfx/imagemagick:= )
|
||||
jack? ( virtual/jack )
|
||||
luajit? ( dev-lang/luajit:2 )
|
||||
nvenc? (
|
||||
|| (
|
||||
<media-video/ffmpeg-4[nvenc]
|
||||
>=media-video/ffmpeg-4[video_cards_nvidia]
|
||||
)
|
||||
)
|
||||
pulseaudio? ( media-sound/pulseaudio )
|
||||
python? ( ${PYTHON_DEPS} )
|
||||
speex? ( media-libs/speexdsp )
|
||||
ssl? ( net-libs/mbedtls )
|
||||
truetype? (
|
||||
media-libs/fontconfig
|
||||
media-libs/freetype
|
||||
)
|
||||
v4l? ( media-libs/libv4l )
|
||||
vlc? ( media-video/vlc:= )
|
||||
"
|
||||
RDEPEND="${DEPEND}"
|
||||
|
||||
pkg_setup() {
|
||||
use python && python-single-r1_pkg_setup
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local libdir=$(get_libdir)
|
||||
local mycmakeargs=(
|
||||
-DDISABLE_ALSA=$(usex !alsa)
|
||||
-DDISABLE_FREETYPE=$(usex !truetype)
|
||||
-DDISABLE_JACK=$(usex !jack)
|
||||
-DDISABLE_LIBFDK=$(usex !fdk)
|
||||
-DDISABLE_PULSEAUDIO=$(usex !pulseaudio)
|
||||
-DDISABLE_SPEEXDSP=$(usex !speex)
|
||||
-DDISABLE_V4L2=$(usex !v4l)
|
||||
-DDISABLE_VLC=$(usex !vlc)
|
||||
-DLIBOBS_PREFER_IMAGEMAGICK=$(usex imagemagick)
|
||||
-DOBS_MULTIARCH_SUFFIX=${libdir#lib}
|
||||
-DOBS_VERSION_OVERRIDE=${PV}
|
||||
-DUNIX_STRUCTURE=1
|
||||
-DWITH_RTMPS=$(usex ssl)
|
||||
)
|
||||
|
||||
if use luajit || use python; then
|
||||
mycmakeargs+=(
|
||||
-DDISABLE_LUA=$(usex !luajit)
|
||||
-DDISABLE_PYTHON=$(usex !python)
|
||||
-DENABLE_SCRIPTING=yes
|
||||
)
|
||||
else
|
||||
mycmakeargs+=( -DENABLE_SCRIPTING=no )
|
||||
fi
|
||||
|
||||
cmake-utils_src_configure
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_icon_cache_update
|
||||
|
||||
if ! use alsa && ! use pulseaudio; then
|
||||
elog
|
||||
elog "For the audio capture features to be available,"
|
||||
elog "either the 'alsa' or the 'pulseaudio' USE-flag needs to"
|
||||
elog "be enabled."
|
||||
elog
|
||||
fi
|
||||
|
||||
if ! has_version "sys-apps/dbus"; then
|
||||
elog
|
||||
elog "The 'sys-apps/dbus' package is not installed, but"
|
||||
elog "could be used for disabling hibernating, screensaving,"
|
||||
elog "and sleeping. Where it is not installed,"
|
||||
elog "'xdg-screensaver reset' is used instead"
|
||||
elog "(if 'x11-misc/xdg-utils' is installed)."
|
||||
elog
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
xdg_icon_cache_update
|
||||
}
|
||||
Reference in New Issue
Block a user