kde-apps/kwave: 24.12.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/kwave/Manifest

@@ -1 +1,2 @@
 DIST kwave-24.12.1.tar.xz 6477896 BLAKE2B 38f9eefc0e0806480aa7fdaf1f5dc2e2649d31d07bd2e374736a817ab9237eaa2df5a9862aa6447a099b93d85ba8f991ba6ef1a7626d80c8ccf743fb4ac8a9ed SHA512 43b9c979e5d96aa2da4bcc7289d67fd9c34bc2d2f5f0634446847b937f2fd185d8ccd9d202eb461b0fe9eda6a3cfa5ea23e2d601c678bf625a1cc7cd1c989b5f
+DIST kwave-24.12.2.tar.xz 6478224 BLAKE2B 35c24b4dffe4da85737e73f2a2628124809058c15d041f89424d7227741bafc19c67e9fc65857b32064870df5f1ddc8f8a5129428b34a52f384882e5727d664b SHA512 ceb1935f77b0d3fb4e9337e461c73aa997ac4f1510004cb33ab2f65402b9a1d515e923b0aab3490ca7c26aff3381fc83eb8869a0b8ce4d1f71686fbfa4e64b36

kde-apps/kwave/kwave-24.12.2.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=6.7.0
+QTMIN=6.7.2
+inherit ecm gear.kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/kwave/"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets]
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3:=
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac:=[cxx] )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:6 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-libs/libpulse )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+"
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README.md TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}