gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-01-05 14:07:27 -08:00
Code Issues Projects Releases Wiki Activity

sci-physics/fastjet: drop 3.4.0-r1, 3.4.2, 3.5.1-r1

Browse Source 
Signed-off-by: Alexander Puck Neuwirth <apn-pucky@gentoo.org>
This commit is contained in:
Alexander Puck Neuwirth 2025-10-01 22:45:31 +02:00
parent 2dd8abd99a
commit 2f54fa06d1
No known key found for this signature in database
GPG Key ID: ED7C252ACED415EF
4 changed files with 0 additions and 243 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

2
sci-physics/fastjet/Manifest
View File

@ -1,4 +1,2 @@
DIST fastjet-3.4.0.tar.gz 2959127 BLAKE2B c99e89ee5cea3fd4e3edebdfebb50efd3c58e7ab15215a384c44120ac930882bd2d4e446b61977fe65dcc49056b958c6510abb7c5889024ae49776b1955bd023 SHA512 af8aeb6197f6bd82ec5f127647f49cd5d455c20e614c23d928b850fc97bc12c70cf6e3b09f1bb0308c2a080fcd4fa13416eea0195695060efaa0e400a687d7b7
DIST fastjet-3.4.2.tar.gz 2973605 BLAKE2B f51b26fdb2611084679a79905c6da460edcf3ad3139bdb2384fe95600e474f4bdb028b24c43456e018c5fb9535491c929d1ec2032d184536efd6b2ef16d54ae1 SHA512 e7702699e67ba5af73f1fe931fe5f67b9f52bb2f0cfdc57dbacf408741e6271ed160503fe6142c92621287df49b441ce7562af589353b199fed09a4c4c839f3f
DIST fastjet-3.4.3.tar.gz 2984798 BLAKE2B ba203a21c5658555606e4ed83fce4cb3dc0a077b0407c336255a7be2ea861a196d57c2f7db03dbd4dad946b8c68827d0d967b3c009d62232d39827342c7ae492 SHA512 9df7fb6ea1082473929d5963eb58c3d420557a2f52e793432f5bd838e8f7212d0a3c3606b98c3dfeeb3a76ffac73926cb7822aaf499d64a65b2cb2bb845fdb77
DIST fastjet-3.5.1.tar.gz 3069022 BLAKE2B 031f833fc3b387ab44e76e0712001972708e2a477076095dc661ad16d42958df570d72a8786483bef2f13eecba4147104b301209d7428b77e41f6f8bbdcde98e SHA512 b5551eea8f9304e732c169227b0a8a005eb4c44534843e14e2270aef06aad56ba52fb42e5397120615b14f0edc34e825eb547b4e6ac578dcd9806d47e41fa3ca

78
sci-physics/fastjet/fastjet-3.4.0-r1.ebuild
View File

@ -1,78 +0,0 @@
# Copyright 2022-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
FORTRAN_NEEDED=plugins
PYTHON_COMPAT=( python3_{9..11} )
DOCS_BUILDER="doxygen"
DOCS_DEPEND="
media-gfx/graphviz
media-libs/freetype
virtual/latex-base
"
inherit autotools docs flag-o-matic fortran-2 python-single-r1
DESCRIPTION="A software package for jet finding in pp and e+e- collisions"
HOMEPAGE="https://fastjet.fr/"
SRC_URI="https://fastjet.fr/repo/${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="cgal examples python +plugins"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
# cgal is header-only in version 5.4 and up. We need to use the
# special --enable-cgal-header-only argument to use these versions.
DEPEND="
cgal? ( >=sci-mathematics/cgal-5.4:=[shared(+)] )
plugins? ( sci-physics/siscone:= )
python? ( ${PYTHON_DEPS} )
"
RDEPEND="${DEPEND}"
BDEPEND="virtual/fortran"
PATCHES=(
"${FILESDIR}"/${P}-system-siscone.patch
"${FILESDIR}"/${P}-gfortran.patch
)
src_prepare() {
default
eautoreconf
}
src_configure() {
use cgal && \
has_version 'sci-mathematics/cgal[gmp]' && append-libs -lgmp
econf \
$(use_enable cgal cgal-header-only) \
$(use_enable plugins allplugins) \
$(use_enable plugins allcxxplugins) \
--enable-shared \
--enable-static=no \
--disable-static \
--disable-auto-ptr \
$(use_enable python pyext)
}
src_compile() {
default
docs_compile
}
src_install() {
default
if use examples; then
emake -C example maintainer-clean
find example -iname 'makefile*' -delete || die
docinto examples
dodoc -r example/.
docompress -x /usr/share/doc/${PF}/examples
fi
find "${ED}" -name '*.la' -delete || die
}

84
sci-physics/fastjet/fastjet-3.4.2.ebuild
View File

@ -1,84 +0,0 @@
# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
FORTRAN_NEEDED=plugins
PYTHON_COMPAT=( python3_{10..12} )
DOCS_BUILDER="doxygen"
DOCS_DEPEND="
media-gfx/graphviz
media-libs/freetype
virtual/latex-base
"
inherit autotools docs flag-o-matic fortran-2 python-single-r1
DESCRIPTION="A software package for jet finding in pp and e+e- collisions"
HOMEPAGE="https://fastjet.fr/"
SRC_URI="https://fastjet.fr/repo/${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="cgal examples python +plugins"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
# cgal is header-only in version 5.4 and up. We need to use the
# special --enable-cgal-header-only argument to use these versions.
DEPEND="
cgal? ( >=sci-mathematics/cgal-5.4:=[shared(+)] )
plugins? ( sci-physics/siscone:= )
python? ( ${PYTHON_DEPS} )
"
RDEPEND="${DEPEND}"
BDEPEND="app-shells/bash"
PATCHES=(
"${FILESDIR}"/${PN}-3.4.0-system-siscone.patch
"${FILESDIR}"/${PN}-3.4.0-gfortran.patch
)
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
default
eautoreconf
}
src_configure() {
use cgal && \
has_version 'sci-mathematics/cgal[gmp]' && append-libs -lgmp
# only bash compatible
sed -i 's#/bin/sh#/bin/bash#g' ./configure || die
econf \
$(use_enable cgal cgal-header-only) \
$(use_enable plugins allplugins) \
$(use_enable plugins allcxxplugins) \
--enable-shared \
--enable-static=no \
--disable-static \
--disable-auto-ptr \
$(use_enable python pyext)
}
src_compile() {
default
docs_compile
}
src_install() {
default
use python && python_optimize
if use examples; then
emake -C example maintainer-clean
find example -iname 'makefile*' -delete || die
docinto examples
dodoc -r example/.
docompress -x /usr/share/doc/${PF}/examples
fi
find "${ED}" -name '*.la' -delete || die
}

79
sci-physics/fastjet/fastjet-3.5.1-r1.ebuild
View File

@ -1,79 +0,0 @@
# Copyright 2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
FORTRAN_NEEDED=plugins
PYTHON_COMPAT=( python3_{11..13} )
DOCS_BUILDER="doxygen"
DOCS_DEPEND="
media-gfx/graphviz
media-libs/freetype
virtual/latex-base
"
inherit cmake docs fortran-2 python-single-r1
DESCRIPTION="A software package for jet finding in pp and e+e- collisions"
HOMEPAGE="https://fastjet.fr/"
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://gitlab.com/fastjet/fastjet"
else
SRC_URI="https://fastjet.fr/repo/${P}.tar.gz"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
fi
LICENSE="GPL-2+"
SLOT="0"
IUSE="cgal examples python +plugins"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
# cgal is header-only in version 5.4 and up. We need to use the
# special --enable-cgal-header-only argument to use these versions.
DEPEND="
cgal? ( >=sci-mathematics/cgal-5.4:=[shared(+)] )
plugins? ( >=sci-physics/siscone-3.1.2-r1:= )
python? (
${PYTHON_DEPS}
dev-lang/swig
)
"
RDEPEND="${DEPEND}"
pkg_setup() {
use python && python-single-r1_pkg_setup
fortran-2_pkg_setup
}
src_configure() {
local mycmakeargs=(
-DFASTJET_ENABLE_CGAL=$(usex cgal)
-DFASTJET_ENABLE_ALLPLUGINS=$(usex plugins)
-DFASTJET_ENABLE_ALLCXXPLUGINS=$(usex plugins)
-DFASTJET_ENABLE_PYTHON=$(usex python)
-DFASTJET_BUILD_EXAMPLES=$(usex examples)
-DFASTJET_HAVE_AUTO_PTR_INTERFACE=OFF
-DFASTJET_USE_INSTALLED_SISCONE=ON
)
use python && mycmakeargs+=(
-DFASTJET_CUSTOM_PYTHON_INSTALL="$(python_get_sitedir)"
)
cmake_src_configure
}
src_compile() {
cmake_src_compile
docs_compile
}
src_install() {
cmake_src_install
use python && python_optimize
if use examples; then
docinto examples
dodoc -r example/.
docompress -x /usr/share/doc/${PF}/examples
fi
find "${ED}" -name '*.la' -delete || die
}