media-gfx/mypaint: Version bump. Ebuild by darkstalker <slayerbeast@gmail.com>. Bug #572300

Package-Manager: portage-2.2.27

media-gfx/mypaint/Manifest

@@ -1,2 +1,3 @@
 DIST mypaint-1.0.0.tar.bz2 36748957 SHA256 ced440ec0307e29bfe4f612604fe27ec9bfaea3f4f9c8019ffaa50ef12dc7131 SHA512 91434f6d352d4f5dde3d919772a678a17f15a6d2914fb2377b40e4a0fea042e3c96b5618e1864eacdbfa52f449be03062da2ecb8ec08bae168e3a12904047bf2 WHIRLPOOL a4693b6436485126a033dacb014586e85c448863bbb14acb30aff739a96d8d2abdd2c920ad3e9a5be7790d18e13e4a8e15ebcde85fafcaafe9d2a901b53d5f52
 DIST mypaint-1.1.0.tar.bz2 37416388 SHA256 780d57e50dd90afd586873bc5120261930ea4c309d4d0958020916932122e838 SHA512 a3eef378ddcaa0a33f9afc49cc587489ecfff6f3e46e2238aab83f89d682f2407e2760e6029eaac3591f0a8955c95280c12839adcb42ec452cefbcdb142ab9b9 WHIRLPOOL bfd7356ad393dd85b91ccc010b5d0be23a6d82a33866edade0ef6eb739a1cbdb6823d7bffbdc943f96cdac9059abb7ac1edacf31d4ac2cd3871444594e23557a
+DIST mypaint-1.2.0.tar.xz 37895196 SHA256 cdab33dd0c146cf678c97bcdd44e561f97a0aec40421b8c6785a74b33b9728e2 SHA512 b4e75393cf6ed9b0c3c5a96979607c848d463987e3ac0f711738940ba97be6922e0cce735c56f91261bfce3e0730d69393dd57a45b3b04824c63c74cf1306790 WHIRLPOOL aee266e09258cbf23bf1fc8e78f0d717ecf5a2a1c03898193901b24e38266922d575744a01f4a31aa4fe6da566d05f246b16cad690d21f40a9ff90ad1596cc49

media-gfx/mypaint/mypaint-1.2.0.ebuild

@@ -0,0 +1,84 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit fdo-mime gnome2-utils multilib scons-utils toolchain-funcs python-single-r1
+
+DESCRIPTION="fast and easy graphics application for digital painters"
+HOMEPAGE="http://mypaint.org/"
+SRC_URI="https://github.com/mypaint/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+LANGS="cs de en_CA en_GB es fr hu id it ja ko nb nn_NO pl pt_BR ro ru sl sv uk zh_CN zh_TW"
+for x in ${LANGS}; do
+	IUSE+="linguas_${x} "
+done
+
+RDEPEND="
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pycairo-1.4[${PYTHON_USEDEP}]
+	dev-libs/protobuf[python,${PYTHON_USEDEP}]
+	>=dev-libs/json-c-0.11:=
+	media-libs/lcms:2
+	media-libs/libpng:0=
+	gnome-base/librsvg
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}
+	dev-lang/swig
+	virtual/pkgconfig"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# multilib support
+	sed -i -e "s:lib\/${PN}:$(get_libdir)\/${PN}:" \
+		SConstruct SConscript || die
+}
+
+src_compile() {
+	#workaround scons bug with locales. Bug #352700
+	export LANG="en_US.UTF-8"
+	tc-export CC CXX
+	escons
+}
+
+src_install () {
+	escons prefix="${D}/usr" install
+	newicon pixmaps/${PN}_logo.png ${PN}.png
+	for x in ${LANGS}; do
+		if ! has ${x} ${LINGUAS}; then
+			rm -rf "${ED}"/usr/share/locale/${x} || die
+		fi
+	done
+
+	python_optimize "${D}"usr/share/${PN}
+	# not used and broken
+	rm -rf "${ED}"/usr/{include/,lib/libmypaint.a,lib/pkgconfig/} || die
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}