net-libs/gnome-online-accounts: add 3.56.4

Signed-off-by: Vladislav Mikhailikov <vmikhailikov@gmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/45821
Closes: https://github.com/gentoo/gentoo/pull/45821
Signed-off-by: Pacho Ramos <pacho@gentoo.org>
This commit is contained in:
Vladislav Mikhailikov
2026-02-22 11:15:35 +01:00
committed by Pacho Ramos
parent dba9f4fa02
commit 2f26188e7a
2 changed files with 84 additions and 0 deletions
+1
View File
@@ -1,3 +1,4 @@
DIST gnome-online-accounts-3.54.6.tar.xz 487156 BLAKE2B f4b9605240a3ce47b04a339fb5dd6d02c6bfeff3572f027317a0d9d9cb5fe0c482c25cb5df520c2d26ff9d3780879c4ea5355ca8df6587fabe6423dffad8d279 SHA512 4157c43b84094a8c4ca8e846a2e29a032d653a23fc63eaa37068ce0a44aa6c7741163719835dd6ce141e0af3b1258bf6bcef7f957d3fcfb5b0248e55cf67985a
DIST gnome-online-accounts-3.54.8.tar.xz 488420 BLAKE2B 6ac673f13722f2471f3acea07583e2e6b1088bfa6dd4e207df409e1e8daa01a1131c5fed45e65f9329c999a1682d578569242ff298bbfc235bed668fcb06c352 SHA512 796658a0249548b457300d92c845fbf17333c3aff97a0edde776a441f1cd3e2d772d07703681a09aa3dd6f55d27aa578a02727f4bf4ca66ccfbace1d9ec7e087
DIST gnome-online-accounts-3.56.2.tar.xz 493696 BLAKE2B 8a4d466b8d9aeeefcb03a7c9aff32d5c913d06a2048b920dd9448acb3d4f6a147b8312a5bce26d21d590cb1062ec2788004a3ac2a523c2f17dd244e5817d1c6a SHA512 798b8e5706dcf6fb9ddcc879d9ecd0c9d65821457ea248365ed82bd8c927ac4fc8d0b85d4ee9bd5e8bb79ac6bcb79b7ea88fd638e3b00a509df5a8dac6951b2b
DIST gnome-online-accounts-3.56.4.tar.xz 496860 BLAKE2B 17a389eabc0536be7bbddf0045d4796a12397759f4bdbe937d6ebb75c65351b21f802ca7b5b5c2199caee0b518f5090a1e012c19a81e9b75b48ece9d8da9fc38 SHA512 bfb5ad7ebcd4dde70f1c43b95730312bc7e38fbb2f2223f708135ca75387acadbeb07b71254576d37533877216119a0a884e951d86d1ab4502a6ba6de51c7d9c
@@ -0,0 +1,83 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit gnome.org meson vala xdg
DESCRIPTION="GNOME framework for accessing online accounts"
HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-online-accounts"
LICENSE="LGPL-2+"
SLOT="0/1"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="debug doc gnome +introspection kerberos ms365 +vala"
REQUIRED_USE="vala? ( introspection )"
# libsoup used in goaoauthprovider
# goa kerberos provider is incompatible with app-crypt/heimdal, see
# https://bugzilla.gnome.org/show_bug.cgi?id=692250
# json-glib-0.16 needed for bug #485092
RDEPEND="
>=dev-libs/glib-2.67.4:2
sys-apps/dbus
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
>=gui-libs/libadwaita-1.6_beta
>=gui-libs/gtk-4.15.2:4
>=dev-libs/json-glib-0.16
>=app-crypt/libsecret-0.5
>=net-libs/libsoup-3.0:3.0
>=sys-apps/keyutils-1.6.2
dev-libs/libxml2:2=
>=net-libs/rest-0.9.0:1.0
kerberos? (
>=app-crypt/gcr-4.1.0:4=[gtk]
app-crypt/mit-krb5
)
"
# goa-daemon can launch gnome-control-center
PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
DEPEND="${RDEPEND}
vala? ( $(vala_depend) )
dev-libs/libxslt
>=dev-util/gdbus-codegen-2.80.5-r1
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
gnome-base/gnome-common
"
BDEPEND="doc? ( dev-util/gi-docgen )"
src_prepare() {
default
use vala && vala_setup
}
src_configure() {
# TODO: Give users a way to set the G/FB/Windows Live secrets
local emesonargs=(
-Dgoabackend=true
-Dexchange=true
-Dfedora=false
-Dgoogle=true
-Dimap_smtp=true
$(meson_use kerberos)
-Downcloud=true
-Dwebdav=true
$(meson_use doc documentation)
$(meson_use ms365 ms_graph)
$(meson_use introspection)
-Dman=true
$(meson_use vala vapi)
)
meson_src_configure
}
src_install() {
meson_src_install
if use doc; then
mv "${ED}"/usr/share/doc/${PN} "${ED}"/usr/share/doc/${PF} || die
fi
}