games-emulation/dosbox-staging: add 0.82.0

Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

games-emulation/dosbox-staging/Manifest

@@ -1 +1,2 @@
 DIST dosbox-staging-0.81.1.tar.gz 7021582 BLAKE2B dfee4255db923aba1be2941e0c70fbd0bccc894a245c68907b25d111209cdac3c8cf7854427197915f55a37bdf32b3450e7afa048ee4200ea36de11facfefbae SHA512 6856612dc45ec768cd5bb73a1e5d9a351ff779e1c74de2389675c0f5fe4276037eea4e953d1d38387d5e8c8d88f109805ec0fdeed144d0814662b0c5de2ae287
+DIST dosbox-staging-0.82.0.tar.gz 7196080 BLAKE2B 0d4067ae8f9ec7eb348d1a25bc8e842a4c3328ba3fccdc589137ff61e88f92e34594cf46c8f54d0936f8c50afa5b158bceca37091557c6d1fe856af03c9a43b1 SHA512 d3a7316d31111c89db1f157ee25f6a14d1fd0c6b2f00e524f16a47bf958d6037c82b051e2e9b62ccf2380ef1671d59523a164e68c8525e61903ec639effcfaf0

games-emulation/dosbox-staging/dosbox-staging-0.82.0.ebuild

@@ -0,0 +1,71 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit flag-o-matic meson xdg
+
+DESCRIPTION="Modernized DOSBox soft-fork"
+HOMEPAGE="https://dosbox-staging.github.io/"
+SRC_URI="https://github.com/dosbox-staging/dosbox-staging/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="+alsa debug dynrec +fluidsynth mt-32 network opengl slirp test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	debug? ( sys-libs/ncurses:0= )
+	fluidsynth? (
+		media-sound/fluid-soundfont
+		media-sound/fluidsynth
+	)
+	mt-32? ( media-libs/munt-mt32emu )
+	network? ( media-libs/sdl2-net )
+	opengl? ( virtual/opengl )
+	slirp? ( net-libs/libslirp )
+	media-libs/iir1
+	media-libs/libpng:0=
+	media-libs/libsdl2[joystick,opengl?,video,X]
+	media-libs/opusfile
+	media-libs/speexdsp
+	sys-libs/zlib
+	!games-emulation/dosbox"
+DEPEND="${RDEPEND}"
+BDEPEND="test? ( dev-cpp/gtest )"
+
+DOCS=( AUTHORS README THANKS )
+
+src_prepare() {
+	default
+
+	# We do not have default.sf2, use actual name from fluid-soundfont
+	sed -e "s/default.sf2/FluidR3_GM.sf2/" \
+		-i src/midi/midi_fluidsynth.cpp || die
+
+	# Disable license and docs install (handled by ebuild)
+	sed -e "/licenses_dir\|doc_dir/d" -i meson.build || die
+}
+
+src_configure() {
+	# -Werror=odr
+	# https://bugs.gentoo.org/926078
+	# https://github.com/dosbox-staging/dosbox-staging/issues/3519
+	filter-lto
+
+	# xinput2 comes with libsdl2[X]
+	local emesonargs=(
+		-Duse_xinput2=true
+		$(meson_use alsa use_alsa)
+		$(meson_use debug)
+		-Ddynamic_core=$(usex dynrec dynrec dyn-x86)
+		$(meson_use fluidsynth use_fluidsynth)
+		$(meson_use mt-32 use_mt32emu)
+		$(meson_use network use_sdl2_net)
+		$(meson_use opengl use_opengl)
+		$(meson_use slirp use_slirp)
+		$(meson_feature test unit_tests)
+	)
+	meson_src_configure
+}