app-emacs/lsp-mode: bump to 9.0.0

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

app-emacs/lsp-mode/Manifest

@@ -1 +1,2 @@
 DIST lsp-mode-8.0.1_pre20231218.tar.gz 16396690 BLAKE2B e841e1cda6e26ba1d646ea8ffeee7212fb3352e4ed73c323212e9bd883ddbe3461918b3ab435a16e6568d2fdaf97b165accd8876625415dfa428259c0c93998f SHA512 d3f5a26e40b7b569ba185d605208bd888aed6430f1fa5b608db47ba727e72fb540646a3908b80ab04db763d9be9adb8b58ef88165f31c874749ed26f7086c0fc
+DIST lsp-mode-9.0.0.tar.gz 16407602 BLAKE2B beb4ea41d098a05e6eb6b2fc1a6eac67a47b99e081d16c298b92914236b740489eb2442fe8f0f46fe098514a259a97aad943b4ba7d9e152944f7bc29b3a98ced SHA512 99ed55853a27b0c4ed4a79a7aec1c48bb1dda00069a897d67fe3fcf570d73126b770791bc4986e791cc7c918349c0c16698b2c4f7d3d7d292898102d67d0f22e

app-emacs/lsp-mode/lsp-mode-9.0.0.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+NEED_EMACS=27.1
+
+inherit elisp
+
+DESCRIPTION="Emacs client/library for the Language Server Protocol"
+HOMEPAGE="https://emacs-lsp.github.io/lsp-mode/
+	https://github.com/emacs-lsp/lsp-mode/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/emacs-lsp/${PN}.git"
+else
+	SRC_URI="https://github.com/emacs-lsp/${PN}/archive/${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+	KEYWORDS="~amd64 ~arm64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+RDEPEND="
+	>=app-emacs/dash-2.18.0
+	>=app-emacs/f-0.20.0
+	app-emacs/ht
+	app-emacs/lv
+	app-emacs/markdown-mode
+	app-emacs/spinner
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		app-emacs/deferred
+		app-emacs/ecukes
+		app-emacs/el-mock
+		app-emacs/espuds
+		app-emacs/flycheck
+		app-emacs/undercover
+	)
+"
+
+BYTECOMPFLAGS="-L . -L clients"
+ELISP_REMOVE="
+	test/lsp-clangd-test.el
+	test/lsp-common-test.el
+	test/lsp-integration-test.el
+"                                                       # Remove failing tests.
+
+DOCS=( AUTHORS CHANGELOG.org README.md refcard )
+SITEFILE="50${PN}-gentoo.el"
+
+elisp-enable-tests ert-runner "${S}" -t "!no-win" -t "!org"
+
+src_compile() {
+	elisp_src_compile
+	elisp-compile clients/*.el
+}
+
+src_install() {
+	elisp_src_install
+	elisp-install "${PN}/clients" clients/*
+}