gnome-extra/evolution-ews: Version bump to 3.48.0

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/30071
Signed-off-by: Matt Turner <mattst88@gentoo.org>

gnome-extra/evolution-ews/Manifest

@@ -1,2 +1,3 @@
 DIST evolution-ews-3.46.3.tar.xz 695152 BLAKE2B 2c76f5d5769c6ac610cf8ad2cb55a78374e82793ca6fde838b263759b10f9aa5bb033171001db6a18d5cd2f45744673c063a714f755613c92537e56272683303 SHA512 99259661568fee71898b29a445e87ee110c356a98e3e415d6c2f44e7f9b6f1216b87fd9772c4a006ffde49058dfae594d31ead43ed85fb0c34925f530f8d9495
 DIST evolution-ews-3.46.4.tar.xz 695628 BLAKE2B e0504e77059efa80e55b19707ab5aa72b583e05443ede3a1a95ad2f5c46e5e2d11a6b243df3350f4dc875463b99b18075ed4b73f419c35ec2c6f784e76dea723 SHA512 29f6e1c02b332fb2442911550edd4de8fbac93e14ca0c92c9a07410ef8323988733f67afab4935b7ac9e4ca9e704548eed0bb7a71299426d8c7b2e21fc323ea4
+DIST evolution-ews-3.48.0.tar.xz 701528 BLAKE2B 0733427443fec5fe3b539d906cdc496d4c8801dd35ba3cb75fe45bbc2c96b15841fa9fe1108417b4aa39e51f4e89e3b83692846206f814f4b17710b0f73f3109 SHA512 c9d54a587682145979681ffa3fc6420596fb706a63f82073536a213c4d545fd35cd08d96881c1ddca7294c400ab064504ba42750bc80c9e7d2dee779fce3fb04

gnome-extra/evolution-ews/evolution-ews-3.48.0.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake gnome2 optfeature
+
+DESCRIPTION="Evolution module for connecting to Microsoft Exchange Web Services"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution https://gitlab.gnome.org/GNOME/evolution-ews"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="test"
+
+# libical-glib currently (2020-02-29) oddly behind USE=introspection
+RDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.68:2
+	>=dev-libs/libical-3.0.5:0=[introspection(-)]
+	>=dev-libs/json-glib-1.0.4
+	>=dev-libs/libmspack-0.4
+	dev-libs/libxml2:2
+	>=gnome-extra/evolution-data-server-${PV}:0=
+	>=mail-client/evolution-${PV}:2.0
+	>=net-libs/libsoup-3.0:3.0
+	>=x11-libs/gtk+-3.10:3
+"
+DEPEND="${RDEPEND}
+	test? ( >=net-libs/uhttpmock-0.9:1.0 )
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Unittests fail to find libevolution-ews.so
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake_src_prepare call, if that works
+src_prepare() {
+	cmake_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MSPACK=ON
+		-DENABLE_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+}
+
+pkg_postinst() {
+	optfeature "oauth support" gnome-extra/evolution-data-server[oauth]
+}

profiles/package.mask

@@ -166,6 +166,7 @@ dev-ruby/net-http-persistent:3
 >=gnome-base/librsvg-2.55.90
 >=gnome-base/nautilus-44_rc
 >=gnome-extra/evolution-data-server-3.48
+>=gnome-extra/evolution-ews-3.48
 >=gnome-extra/gnome-boxes-44_rc
 >=gnome-extra/gnome-calculator-44_rc
 >=gnome-extra/gnome-calendar-44_rc