dev-util/buildbot: Version bump, removed doc use flag

Docs generation has been broken last several versions,
blockdiag dep is failing tests.
Bump EAPI.
Add RUNTIME_PYTHON setting in /etc/conf.d/buildbot to
control the desired python version used.

Package-Manager: Portage-2.3.40, Repoman-2.3.9
This commit is contained in:
Brian Dolbec
2018-06-27 08:24:11 -07:00
parent d75815b9e5
commit 2e402f7f0d
4 changed files with 193 additions and 2 deletions
+1
View File
@@ -4,3 +4,4 @@ DIST buildbot-0.9.13.tar.gz 3061713 BLAKE2B fac74d610bf0ff1cfeea1c59c46e95339d6b
DIST buildbot-0.9.15.post1.tar.gz 3088947 BLAKE2B c9a0265d3df2a9ac01872fc7106b5b787334bd899a43fcdb6ad06aab5e0e8f1ddb4374bf5211f251f26985c3b11a0b981bdd23fb668ac1717af36443831648e6 SHA512 c5c72132fd8446fbb14467851063d192dbb817506163eacc3022d563698453c66706a895613ca1c17502dd25957b31f6409996497d2e7646ab2fdbb3fb55c31d
DIST buildbot-1.1.0.docs.tar.xz 23932 BLAKE2B 81da8b86bb269efd2cd3f9146f3d9b41d64b28fdd0c878708c323d040a7e773cd277a18c82b1ef3cb07759ba8aedbc604e1de84f6477205b1708c28b6e86831e SHA512 511d244ffd205989047b4514b164e194b30fe4e0513d3bda776fb4d7a1a5bf42d8b7f00540b88e427838ab43f45686a83e556687ab75ce55eae6b834426a8ef7
DIST buildbot-1.1.0.tar.gz 3098781 BLAKE2B 5a4ba8b641765fd58c3b5e788fc20aa1fb6195655ce2d82929f0f62ff48d20672f21efe0c413387e583d095c3ffcee1055a287016fe87ec1f3eb6b0ccdefdccb SHA512 f850ba2cd93d54a8abc97503719f93f69dfdc3d03b519e2d05c02bdc11893529eb51d74b6584555689281aedb71c3aa6c23141cf5fbc68ae97e09f1c89b2c94c
DIST buildbot-1.1.2.tar.gz 3101168 BLAKE2B 35ec56440014015850a69324d475c4ca9555ad90da85b26a7a43eca74f08361137021aec72ddca37cbb24f21519ebf45948e66214291f356b4a1fbada7c0b3b8 SHA512 14c28d6fae18a10d89d41509635188d881ac76e7b61758481a9afbb22eb384d7ab5080383242e5850af13bfe46877985a91036270c3c4fbf01eafee5b7699815
+185
View File
@@ -0,0 +1,185 @@
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
PYTHON_REQ_USE="sqlite"
PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
EGIT_REPO_URI="https://github.com/buildbot/${PN}.git"
[[ ${PV} == *9999 ]] && inherit git-r3
inherit readme.gentoo-r1 user systemd distutils-r1
MY_PV="${PV/_p/.post}"
MY_P="${PN}-${MY_PV}"
DESCRIPTION="BuildBot build automation system"
HOMEPAGE="https://buildbot.net/ https://github.com/buildbot/buildbot https://pypi.org/project/buildbot/"
[[ ${PV} == *9999 ]] || SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
if [[ ${PV} == *9999 ]]; then
KEYWORDS=""
else
KEYWORDS="~amd64"
fi
IUSE="crypt docker examples irc test"
RDEPEND="
>=dev-python/jinja-2.1[${PYTHON_USEDEP}]
>=dev-python/twisted-17.9.0[${PYTHON_USEDEP}]
>=dev-python/autobahn-0.16.0[${PYTHON_USEDEP}]
>=dev-python/sqlalchemy-0.8[${PYTHON_USEDEP}]
>=dev-python/sqlalchemy-migrate-0.9[${PYTHON_USEDEP}]
dev-python/future[${PYTHON_USEDEP}]
>=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
>=dev-python/txaio-2.2.2[${PYTHON_USEDEP}]
dev-python/pyjwt[${PYTHON_USEDEP}]
>=dev-python/zope-interface-4.1.1[${PYTHON_USEDEP}]
~dev-util/buildbot-worker-${PV}[${PYTHON_USEDEP}]
crypt? (
>=dev-python/twisted-17.9.0[${PYTHON_USEDEP},crypt]
>=dev-python/pyopenssl-16.0.0[${PYTHON_USEDEP}]
dev-python/idna[${PYTHON_USEDEP}]
dev-python/service_identity[${PYTHON_USEDEP}]
)
irc? (
dev-python/txrequests[${PYTHON_USEDEP}]
)
docker? (
>=dev-python/docker-py-2.2.0[${PYTHON_USEDEP}]
)
"
DEPEND="${RDEPEND}
>=dev-python/setuptools-21.2.1[${PYTHON_USEDEP}]
test? (
>=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
dev-python/moto[${PYTHON_USEDEP}]
dev-python/boto3[${PYTHON_USEDEP}]
dev-python/pyjade[${PYTHON_USEDEP}]
dev-python/txgithub[${PYTHON_USEDEP}]
dev-python/txrequests[${PYTHON_USEDEP}]
dev-python/lz4[${PYTHON_USEDEP}]
dev-python/treq[${PYTHON_USEDEP}]
dev-python/setuptools_trial[${PYTHON_USEDEP}]
~dev-util/buildbot-worker-${PV}[${PYTHON_USEDEP}]
>=dev-python/docker-py-2.2.0[${PYTHON_USEDEP}]
)"
S=${WORKDIR}/${MY_P}
[[ ${PV} == *9999 ]] && S=${S}/master
if [[ ${PV} != *9999 ]]; then
PATCHES=(
"${FILESDIR}/Remove-distro-version-test.patch"
)
fi
pkg_setup() {
enewuser buildbot
DOC_CONTENTS="The \"buildbot\" user and the \"buildmaster\" init script has been added
to support starting buildbot through Gentoo's init system. To use this,
execute \"emerge --config =${CATEGORY}/${PF}\" to create a new instance.
The scripts can run as a different user if desired."
}
src_install() {
distutils-r1_src_install
doman docs/buildbot.1
if use examples; then
insinto /usr/share/doc/${PF}
doins -r docs/examples
fi
newconfd "${FILESDIR}/buildmaster.confd" buildmaster
newinitd "${FILESDIR}/buildmaster.initd" buildmaster
systemd_dounit "${FILESDIR}/buildmaster.target"
systemd_newunit "${FILESDIR}/buildmaster_at.service" "buildmaster@.service"
systemd_install_serviced "${FILESDIR}/buildmaster_at.service.conf" "buildmaster@.service"
readme.gentoo_create_doc
}
python_test() {
distutils_install_for_testing
esetup.py test || die "Tests failed under ${EPYTHON}"
}
pkg_postinst() {
readme.gentoo_print_elog
if [[ -n ${REPLACING_VERSIONS} ]]; then
ewarn
ewarn "Starting with buildbot-0.8.12-r2, more than one instance of buildmaster"
ewarn "can be run simultaneously. Note that \"BASEDIR\" in the buildbot configuration file"
ewarn "is now the common base directory for all instances. If you are migrating from an older"
ewarn "version, make sure that you copy the current contents of \"BASEDIR\" to a subdirectory."
ewarn "The name of the subdirectory corresponds to the name of the buildmaster instance."
ewarn "In order to start the service running OpenRC-based systems need to link to the init file:"
ewarn " ln --symbolic --relative /etc/init.d/buildmaster /etc/init.d/buildmaster.myinstance"
ewarn " rc-update add buildmaster.myinstance default"
ewarn " /etc/init.d/buildmaster.myinstance start"
ewarn "Systems using systemd can do the following:"
ewarn " systemctl enable buildmaster@myinstance.service"
ewarn " systemctl enable buildmaster.target"
ewarn " systemctl start buildmaster.target"
elog
elog "Upstream recommends the following when upgrading:"
elog "Each time you install a new version of Buildbot, you should run the"
elog "\"buildbot upgrade-master\" command on each of your pre-existing build masters."
elog "This will add files and fix (or at least detect) incompatibilities between"
elog "your old config and the new code."
fi
elog
elog "In order to create a new instance of buildmaster, execute:"
elog " emerge --config =${CATEGORY}/${PF}"
}
pkg_config() {
local buildmaster_path="/var/lib/buildmaster"
local log_path="/var/log/buildmaster"
einfo "This will prepare a new buildmaster instance in ${buildmaster_path}."
einfo "Press Control-C to abort."
einfo "Enter the name for the new instance: "
read instance_name
[[ -z "${instance_name}" ]] && die "Invalid instance name"
local instance_path="${buildmaster_path}/${instance_name}"
local instance_log_path="${log_path}/${instance_name}"
if [[ -e "${instance_path}" ]]; then
eerror "The instance with the specified name already exists:"
eerror "${instance_path}"
die "Instance already exists"
fi
local buildbot="/usr/bin/buildbot"
if [[ ! -d "${buildmaster_path}" ]]; then
mkdir --parents "${buildmaster_path}" || die "Unable to create directory ${buildmaster_path}"
fi
"${buildbot}" create-master "${instance_path}" &>/dev/null || die "Creating instance failed"
chown --recursive buildbot "${instance_path}" || die "Setting permissions for instance failed"
mv "${instance_path}/master.cfg.sample" "${instance_path}/master.cfg" \
|| die "Moving sample configuration failed"
ln --symbolic --relative "/etc/init.d/buildmaster" "/etc/init.d/buildmaster.${instance_name}" \
|| die "Unable to create link to init file"
if [[ ! -d "${instance_log_path}" ]]; then
mkdir --parents "${instance_log_path}" || die "Unable to create directory ${instance_log_path}"
fi
ln --symbolic --relative "${instance_log_path}/twistd.log" "${instance_path}/twistd.log" \
|| die "Unable to create link to log file"
einfo "Successfully created a buildmaster instance at ${instance_path}."
einfo "To change the default settings edit the master.cfg file in this directory."
}
@@ -8,3 +8,8 @@ USERNAME=buildbot
# Extra options to pass to twistd.
TWISTD_OPTS=""
# Optional specific python version to run in
# (if not the system default version)
# ie: RUNTIME_PYTHON="/usr/bin/python2.7"
RUNTIME_PYTHON=""
+2 -2
View File
@@ -1,5 +1,5 @@
#!/sbin/openrc-run
# Copyright 1999-2016 Gentoo Foundation
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
extra_started_commands="reload"
@@ -39,7 +39,7 @@ start() {
ebegin "Starting buildmaster in ${BUILDMASTER_PATH}"
start-stop-daemon --start -u "${USERNAME}" \
--pidfile "${BUILDMASTER_PATH}/buildmaster.pid" \
--exec /usr/bin/python2 -- /usr/bin/twistd \
--exec "${RUNTIME_PYTHON}" -- /usr/bin/twistd \
--no_save \
--logfile="${BUILDMASTER_PATH}/twistd.log" \
--pidfile="${BUILDMASTER_PATH}/buildmaster.pid" \