x11-misc/mozo: Bump to 1.24.0

Package-Manager: Portage-2.3.82, Repoman-2.3.18
Signed-off-by: Adam Feldman <NP-Hardass@gentoo.org>

x11-misc/mozo/Manifest

@@ -1,3 +1,4 @@
 DIST mozo-1.22.0.tar.xz 178924 BLAKE2B 6cc74cbdb7342d926483948391798cc9b0be66b63bba758b7ec8cea3f5555ae01f1ecf279053612ed060a283076bdac1a9ef8bd15e3cfe61d96685aeee168ae0 SHA512 f3d60e94d9bf5fdd435320856563622f0687cc2844a3d51473bcef5c442f4938a4030533271ead2fd88fb0ce805c16b40d629e5a69fc642e7e670a1afd5745db
 DIST mozo-1.22.1.tar.xz 171976 BLAKE2B c4a1166b605d3fed68b71987dbf70b7f908aabc2c7266415b0d7ce4c8ccb93ad690c72ce83a708f9d3518cfba66128d2cd4bc5413432133299595cf4d2c5a43c SHA512 6cd4ed04d43ae064077fc78ed59644bf6efe4c65c26995742166c57333d470fbe95ca4f4037e786f16dc076e75d938868948e8c2e5c662f35d971b36992f1a9b
 DIST mozo-1.22.2.tar.xz 172644 BLAKE2B 15e643cfdceb1d62f7fd1499a42bb92a4dd8485adc764d304a2b3f31ffac962fa48f2af402564a6c1598fc97ae19288f4281bc19e9ba6855aeb329ec09bbe4ab SHA512 c5122b37036291ea7a2ecdb2a2ca37bf63d88404f8fb608c45917a28f4e5996d862764ea5e33544027f8f1f144387de40e204aa69b07d5a590b76aca29e1ad71
+DIST mozo-1.24.0.tar.xz 228180 BLAKE2B 6eb880b82dcb608f84efd8df74e77812f9da68dfa877ec896c6f04fa18088e8e4a82641c715e3620201dbb8a1bea8bb4ded09dd72f50770edae09c1326cbf453 SHA512 e0d217d2e7bb7d2c8df777e51bfb20e8bf4fa1bee0f9f3a9348ec1c8501b386a4afbd8848735ecfa61a0f9576382d784d3ef5b884a2a34af6ba33d3a126fe193

x11-misc/mozo/mozo-1.24.0.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{3_6,3_7} )
+PYTHON_REQ_USE="xml"
+
+inherit python-r1 mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="Mozo menu editor for MATE"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=dev-python/pygobject-3:3[${PYTHON_USEDEP}]
+	>=mate-base/mate-menus-1.21.0[introspection]
+	x11-libs/gdk-pixbuf:2[introspection]
+	>=x11-libs/gtk+-3.22:3[introspection]
+	!!x11-misc/mate-menu-editor
+"
+
+RDEPEND="${COMMON_DEPEND}
+	virtual/libintl
+"
+
+DEPEND="${COMMON_DEPEND}
+	>=sys-devel/gettext-0.19.8:*
+	virtual/pkgconfig:*
+"
+
+src_prepare() {
+	mate_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir mate_src_configure \
+		--disable-icon-update
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir emake check
+}
+
+src_install() {
+	installing() {
+		mate_src_install
+
+		# Massage shebang to make python_doscript happy
+		sed -e 's:#! '"${PYTHON}:#!/usr/bin/python:" \
+			-i mozo || die
+
+		python_doscript mozo
+		python_optimize
+	}
+
+	python_foreach_impl run_in_build_dir installing
+}