sys-devel/pmake: Port to EAPI 7

Closes: https://bugs.gentoo.org/724214
Package-Manager: Portage-3.0.7, Repoman-3.0.1
Signed-off-by: David Seifert <soap@gentoo.org>

sys-devel/pmake/pmake-1.111.3.3.ebuild

@@ -1,43 +1,37 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=4
+EAPI=7
 
-inherit eutils toolchain-funcs versionator linux-info
+inherit toolchain-funcs linux-info
 
-MY_P="${PN}-$(get_version_component_range 1-2)"
-DEBIAN_SOURCE="${PN}_$(get_version_component_range 1-2).orig.tar.gz"
-DEBIAN_PATCH="${PN}_$(replace_version_separator 2 '-').debian.tar.gz"
+MY_P="${PN}-$(ver_cut 1-2)"
+DEBIAN_SOURCE="${PN}_$(ver_cut 1-2).orig.tar.gz"
+DEBIAN_PATCH="${PN}_$(ver_rs 2 '-').debian.tar.gz"
 
 DESCRIPTION="BSD build tool to create programs in parallel. Debian's version of NetBSD's make"
 HOMEPAGE="http://www.netbsd.org/"
-SRC_URI="mirror://debian/pool/main/p/pmake/${DEBIAN_SOURCE}
+SRC_URI="
+	mirror://debian/pool/main/p/pmake/${DEBIAN_SOURCE}
 	mirror://debian/pool/main/p/pmake/${DEBIAN_PATCH}"
 
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm ~arm64 ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux"
-IUSE=""
-
-RDEPEND=""
-DEPEND=""
 
 S="${WORKDIR}/${PN}"
 
-src_prepare() {
-	EPATCH_FORCE="yes" \
-		EPATCH_OPTS="-g0 -E --no-backup-if-mismatch -p1" \
-		EPATCH_SUFFIX="diff" \
-		epatch "${WORKDIR}/debian/patches"
+PATCHES=(
+	"${WORKDIR}"/debian/patches
 
 	# pmake makes the assumption that . and .. are the first two
 	# entries in a directory, which doesn't always appear to be the
 	# case on ext3...  (05 Apr 2004 agriffis)
-	epatch "${FILESDIR}/${PN}-1.98-skipdots.patch"
+	"${FILESDIR}"/${PN}-1.98-skipdots.patch
 
 	# Don't ignore ldflags
-	epatch "${FILESDIR}/${PN}-1.111.1-ldflags.patch"
-}
+	"${FILESDIR}"/${PN}-1.111.1-ldflags.patch
+)
 
 src_compile() {
 	# The following CFLAGS are almost directly from Red Hat 8.0 and
@@ -62,18 +56,20 @@ src_compile() {
 
 src_install() {
 	# Don't install these on BSD, else they conflict
-	if [[ "${USERLAND}" == "GNU" ]]; then
+	if [[ ${USERLAND} == GNU ]]; then
 		insinto /usr/share/mk/${PN}
-		doins mk/*
+		doins -r mk/.
 	fi
 
 	newbin bmake pmake
 	dobin mkdep
-	mv make.1 pmake.1
-	doman mkdep.1 pmake.1
+
+	doman mkdep.1
+	newman make.1 pmake.1
+
 	dodoc PSD.doc/tutorial.ms
 
-	if [[ "${USERLAND}" == "BSD" ]]; then
+	if [[ ${USERLAND} == BSD ]]; then
 		dosym pmake /usr/bin/make
 		dosym pmake.1.gz /usr/share/man/man1/make.1.gz
 	fi