dev-python/docker-py: Bump to 4.3.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/docker-py/Manifest

@@ -1,2 +1,3 @@
 DIST docker-py-4.2.1.tar.gz 234562 BLAKE2B 4b554199f3675340602be27395e0194e827ad81dab48500bca0d4858c699e79ac5108f46eae09c3ac6ae1b580498fd5c78f026ecfd8549b938bb5c6e6cccbd94 SHA512 46ab02d4c247d41efa0ca75d3e13f8aef2d3fe4e6d8624c5a98a728f16c58d0dd8de742be710dc2b2f616dc2cc14a7a8796899e94a4b71a00554baeab105330f
 DIST docker-py-4.2.2.tar.gz 234729 BLAKE2B 06ebe27582ab6a8a61fdf655d01b01495724e03178c2b8291d38425f2678a3d1f826a836a5926ccf65b07c232fba38251cf8f0b1c644334d1b7611adb9d49e84 SHA512 d81f5a6d1cc15dd6d65e65c9e4f24fcae172ce41c8244e13c99adaad8627c9f0eece923d66108951b5e9aaa134e668f317481684b3c2bd51802321d1c4adbab1
+DIST docker-py-4.3.0.tar.gz 236399 BLAKE2B fd9cb6426697a105f58c1199809adb009943761fc17a9b1c0a0c091d0950faf15d6e097aeddc7012b4d39770a66fcdcde73de6874a081e2a2172acd6b5c6e816 SHA512 c790563c6a3a5042f5a0d602c22b2b2838ad6f54df3bc1691e32da06336d6b651d7560ca77677ae1cb3f4d4aab721f98984e0479f7fed25deafceb1dc1c24a7c

dev-python/docker-py/docker-py-4.3.0.ebuild

@@ -0,0 +1,45 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for Docker"
+HOMEPAGE="https://github.com/docker/docker-py"
+SRC_URI="https://github.com/docker/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	!~dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/websocket-client-0.32.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/paramiko-2.4.2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/recommonmark' \
+	'>=dev-python/sphinx-1.4.6'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# localhost has a better chance of being in /etc/hosts
+	sed -e 's:socket[.]gethostname():"localhost":' \
+		-i tests/unit/api_test.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	pytest -vv tests/unit/ || die "tests failed under ${EPYTHON}"
+}