kde-apps/kate: 21.12.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2022-03-03 15:52:38 +01:00
parent c5bd6f49cd
commit 2cf11ce5bc
2 changed files with 107 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST kate-21.08.3.tar.xz 7291244 BLAKE2B 190f166be207b513f3e2d723b08886fd70711ef1e409f6d52b7fb4ae8a748ce7fb279c081e1a758884622b05243e4bc0044c757a2bb5e17a141823009b8fa9fe SHA512 2977db9224fb5b49b3a210d8789fa5d644614f2a6ff72fa504337718f017f30ee209dcffb990d3aee8e1f322184e62195ca98668700a2d9becf4de9d9dda65b3
DIST kate-21.12.2.tar.xz 7393316 BLAKE2B 6834124eed2c6f79966d088943074e5edab7d3384241bfa0b855c83117e5e7a9f108424858cf35c12bcb89344cb76e217f903a39eda99f95908950b7e22e5a04 SHA512 255efb34ad88ce8804f1669316b11a4efb0075011576efb6bdba289b09324e185b5ac73749ffa6a1b1620de828457fc9a868cac6dc8554fb0dc5089c9b185cf5
DIST kate-21.12.3.tar.xz 7497692 BLAKE2B 768f8b7055b922b2d10ef93e2935a38f8095f581115fad79760c240a7dc78f49a5b3a096ea173ec464564d7bb692cf1c5ece1a1d2dd4b1e8cbe7efed3524390d SHA512 998256a13896441c0068fa1be166ee373acc5475022badce0accb7123f1b308b7fadd06511d6eb7359f51b0bd72c09dd23cdfb6608dcebb97bcd854aeb941086
+106
View File
@@ -0,0 +1,106 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
ECM_TEST="true"
KFMIN=5.88.0
QTMIN=5.15.2
VIRTUALX_REQUIRED="test"
inherit ecm kde.org optfeature
DESCRIPTION="Multi-document editor with network transparency, Plasma integration and more"
HOMEPAGE="https://kate-editor.org/ https://apps.kde.org/kate/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="5"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
IUSE="activities +filebrowser lspclient +projects plasma +snippets sql telemetry"
# only addons/externaltools depends on kiconthemes, too small for USE
DEPEND="
>=dev-qt/qtconcurrent-${QTMIN}:5
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=dev-qt/qtxml-${QTMIN}:5
>=kde-frameworks/kcodecs-${KFMIN}:5
>=kde-frameworks/kcompletion-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kcrash-${KFMIN}:5
>=kde-frameworks/kdbusaddons-${KFMIN}:5
>=kde-frameworks/kguiaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/kitemviews-${KFMIN}:5
>=kde-frameworks/kjobwidgets-${KFMIN}:5
>=kde-frameworks/kparts-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/ktexteditor-${KFMIN}:5
>=kde-frameworks/ktextwidgets-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
filebrowser? ( >=kde-frameworks/kbookmarks-${KFMIN}:5 )
lspclient? ( >=kde-frameworks/kitemmodels-${KFMIN}:5 )
plasma? ( >=kde-frameworks/plasma-${KFMIN}:5 )
projects? (
>=kde-frameworks/knewstuff-${KFMIN}:5
>=kde-frameworks/threadweaver-${KFMIN}:5
)
snippets? ( >=kde-frameworks/knewstuff-${KFMIN}:5 )
sql? (
>=dev-qt/qtsql-${QTMIN}:5
>=kde-frameworks/kwallet-${KFMIN}:5
)
telemetry? ( dev-libs/kuserfeedback:5 )
"
RDEPEND="${DEPEND}"
src_prepare() {
ecm_src_prepare
# delete colliding kwrite translations
if [[ ${KDE_BUILD_TYPE} = release ]]; then
find po -type f -name "*po" -and -name "kwrite*" -delete || die
rm -rf po/*/docs/kwrite || die
fi
}
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package activities KF5Activities)
-DBUILD_filebrowser=$(usex filebrowser)
-DBUILD_lspclient=$(usex lspclient)
-DBUILD_sessionapplet=$(usex plasma)
-DBUILD_project=$(usex projects)
-DBUILD_snippets=$(usex snippets)
-DBUILD_katesql=$(usex sql)
-DBUILD_kwrite=FALSE
$(cmake_use_find_package telemetry KUserFeedback)
)
ecm_src_configure
}
src_test() {
# tests hang
local myctestargs=(
-E "(session_manager_test|sessions_action_test)"
)
ecm_src_test
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "Markdown text previews" kde-misc/markdownpart:${SLOT} kde-misc/kmarkdownwebview:${SLOT}
optfeature "DOT graph file previews" media-gfx/kgraphviewer
fi
ecm_pkg_postinst
}