www-apps/kibana-bin: add 7.17.10

Signed-off-by: Tomáš Mózes <hydrapolic@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/31059
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

www-apps/kibana-bin/Manifest

@@ -1 +1,2 @@
+DIST kibana-7.17.10-linux-x86_64.tar.gz 269001610 BLAKE2B f4f4dc6c560167fae23031c7456122b50572dea4cace924b2cf462ab8e463966b7fa6a348b6308056763c454d1bac29b337d238805c096e6b7ad48f87831d6d9 SHA512 d3d5e8906e64ae3c469e4df80e1c692ce1912e36f68ddf36b99b7019faf34aebaa329061904a6d2b6a32486c6e19d1c5f2ea30c25479a7960ed93bc1c0cb1691
 DIST kibana-7.17.9-linux-x86_64.tar.gz 268769436 BLAKE2B 7c40aeaa407f879e364bf0b3472fb14794fc2e340545bc5099af1bdfad9d9977bf2ebdd4a30bd8e27e6ca7afc294b05486958176f6242a891c9f7676245fd0d0 SHA512 f0f9f65b6ba3cc401a519f764314854f6f1f22a9c3b55dfc5a4921455d64fc0d5b8352d267217076da82157553f235ab3d2506497132f23789b126205177e86b

www-apps/kibana-bin/kibana-bin-7.17.10.ebuild

@@ -0,0 +1,94 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd
+
+MY_PN="${PN%-bin}"
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Analytics and search dashboard for Elasticsearch"
+HOMEPAGE="https://www.elastic.co/products/kibana"
+SRC_URI="https://artifacts.elastic.co/downloads/${MY_PN}/${MY_P}-linux-x86_64.tar.gz"
+
+# source: LICENSE.txt and NOTICE.txt
+LICENSE="Apache-2.0 Artistic-2 BSD BSD-2 CC-BY-3.0 CC-BY-4.0 Elastic-2.0 icu ISC MIT MPL-2.0 OFL-1.1 openssl public-domain Unlicense WTFPL-2 ZLIB"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+
+RDEPEND="
+	acct-group/kibana
+	acct-user/kibana
+	dev-libs/expat
+	dev-libs/nspr
+	dev-libs/nss
+	>=net-libs/nodejs-16.13.0
+	<net-libs/nodejs-18
+	sys-libs/glibc
+"
+
+# Do not complain about CFLAGS etc since we don't use them
+QA_FLAGS_IGNORED='.*'
+QA_PRESTRIPPED="
+	opt/kibana/x-pack/plugins/reporting/chromium/headless_shell-linux_x64/headless_shell
+	opt/kibana/x-pack/plugins/reporting/chromium/headless_shell-linux_x64/swiftshader/libEGL.so
+	opt/kibana/x-pack/plugins/reporting/chromium/headless_shell-linux_x64/swiftshader/libGLESv2.so
+	opt/kibana/node_modules/re2/build/Release/re2.node
+"
+
+S="${WORKDIR}/${MY_P}-linux-x86_64"
+
+src_prepare() {
+	default
+
+	# remove unused directory
+	rm -r data || die
+
+	# remove bundled nodejs
+	rm -r node || die
+	sed -i 's@\(^NODE="\).*@\1/usr/bin/node"@g' \
+		bin/kibana || die
+
+	# move plugins to /var/lib/kibana
+	rm -r plugins || die
+
+	# handle node.js version with RDEPEND
+	sed -i /node_version_validator/d \
+		src/setup_node_env/no_transpilation_dist.js || die
+}
+
+src_install() {
+	insinto /etc/${MY_PN}
+	doins -r config/.
+	rm -r config || die
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${MY_PN}.logrotate ${MY_PN}
+
+	newconfd "${FILESDIR}"/${MY_PN}.confd ${MY_PN}
+	newinitd "${FILESDIR}"/${MY_PN}.initd-r1 ${MY_PN}
+	systemd_dounit "${FILESDIR}"/${MY_PN}.service
+
+	insinto /opt/${MY_PN}
+	doins -r .
+
+	fperms -R +x /opt/${MY_PN}/bin
+
+	diropts -m 0750 -o ${MY_PN} -g ${MY_PN}
+	keepdir /var/lib/${MY_PN}/plugins
+	keepdir /var/log/${MY_PN}
+
+	dosym ../../var/lib/kibana/plugins /opt/kibana/plugins
+}
+
+pkg_postinst() {
+	elog "This version of Kibana is compatible with Elasticsearch $(ver_cut 1-2) and"
+	elog "Node.js 16. Some plugins may fail with other versions of Node.js (Bug #656008)."
+	elog
+	elog "To set a customized Elasticsearch instance:"
+	elog "  OpenRC: set ES_INSTANCE in /etc/conf.d/${MY_PN}"
+	elog "  systemd: set elasticsearch.url in /etc/${MY_PN}/kibana.yml"
+	elog
+	elog "Elasticsearch can run local or remote."
+}