dev-ruby/facter: 3.14.21 bump

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>
This commit is contained in:
Matthew Thode
2021-10-30 21:42:04 -05:00
parent 82fb773349
commit 2cc54cfb0c
2 changed files with 100 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST facter-3.14.19.tar.gz 409345 BLAKE2B f977bb36ec8042ac950babd19ed398b8bd4fece854304a8a7a5f6b7608c3ad6ba4999b9038e401d599883da5bad63304b502fef164d1988d68a8477f1ff302a1 SHA512 65efc0237edc8198165e8229ca5d64e165a36e58718a863e14df9de9b64d4c9fb911d084e23daa982473f0703077b2cb0a5de8c544161591a894d537312c30f0
DIST facter-3.14.20.tar.gz 410552 BLAKE2B 8ff8422e9066ab6fabe00e22dedb4c2970e126eb06e307df52ab2b4f989f18a8f6b405fff405702720b6d25503b663791f5d0ec94b07d32759387bebbdc302e6 SHA512 14073dbd628e0c211fc95b5dab2a65bd549429a933c9f745cfa62c6bec7a810f444626c165117efc05ad67b3aef2dae5398112911059826f1b5d2bee9b27eedd
DIST facter-3.14.21.tar.gz 410594 BLAKE2B 30b502debaec476d7ba03a73ad3a251aeabf3347c2c552204e825dea8d85807d50cd6d06de03be32a5977e5e8cefe4869e2cc453b1ea79b9045c80369df6a0d7 SHA512 69618e54d2c46ae1230fa99ead88413ca8d5be6a01c149fcc00a7485767b9e624283fdf6064679e825a1ecb426be59a86e7ef903cd0ffca58383006ba5e9cf7f
+99
View File
@@ -0,0 +1,99 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
USE_RUBY="ruby24 ruby25 ruby26 ruby27"
# git-r3 goes after ruby-ng so that it overrides src_unpack properly
inherit cmake eutils ruby-ng
DESCRIPTION="A cross-platform ruby library for retrieving facts from operating systems"
HOMEPAGE="http://www.puppetlabs.com/puppet/related-projects/facter/"
LICENSE="Apache-2.0"
SLOT="0"
IUSE="test"
if [[ ${PV} == 9999 ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/puppetlabs/facter.git"
EGIT_BRANCH="master"
else
[[ "${PV}" = *_rc* ]] || \
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
SRC_URI="https://github.com/puppetlabs/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
fi
RESTRICT="!test? ( test )"
ruby_add_bdepend "test? ( dev-ruby/rake dev-ruby/rspec:2 dev-ruby/mocha:0.14 )"
RDEPEND="
>=dev-cpp/cpp-hocon-0.2.1:=
>=dev-libs/leatherman-1.0.0:=
dev-libs/openssl:0=
sys-apps/util-linux
app-emulation/virt-what
net-misc/curl
dev-libs/boost:=[nls]
>=dev-cpp/yaml-cpp-0.5.1
!<app-admin/puppet-4.0.0"
DEPEND="${RDEPEND}"
# restore ${S} and override all phases exported by ruby-ng.eclass
S="${WORKDIR}/${P}"
PATCHES=(
"${FILESDIR}"/${PN}-3.14.6-fix-static-libcpp-hocon.patch
# be explicit about the version of rspec we test with
"${FILESDIR}"/${PN}-3.14.8-explicit-rspec-2.patch
)
pkg_setup() {
ruby-ng_pkg_setup
}
src_unpack() {
default
if [[ ${PV} == 9999 ]] ; then
git-r3_src_unpack
fi
}
src_prepare() {
cmake_src_prepare
}
each_ruby_configure() {
# hack for correct calculation of relative path from facter.rb to
# libfacter.so
my_ruby_sitelibdir=$(ruby_rbconfig_value 'sitelibdir')
}
src_configure() {
ruby-ng_src_configure
local mycmakeargs=(
-DRUBY_LIB_INSTALL=${my_ruby_sitelibdir}
-DBLKID_LIBRARYDIR="${EPREFIX}/$(get_libdir)"
)
cmake_src_configure
}
src_compile() {
addpredict /proc/self/oom_score_adj
cmake_src_compile
}
src_test() {
cmake_src_test
}
each_ruby_install() {
doruby "${BUILD_DIR}"/lib/facter.rb
}
src_install() {
cmake_src_install
ruby-ng_src_install
}