dev-python/yara-python: add 4.5.5

Signed-off-by: Mario Haustein <mario.haustein@hrz.tu-chemnitz.de>
Part-of: https://github.com/gentoo/gentoo/pull/46156
Closes: https://github.com/gentoo/gentoo/pull/46156
Signed-off-by: Sam James <sam@gentoo.org>

dev-python/yara-python/Manifest

@@ -1 +1,2 @@
 DIST yara-python-4.5.4.gh.tar.gz 39313 BLAKE2B fc41fd378bcd2cd1da2ae442f794c413d52a2dae9c9766d03ee1a641f31a5ceb4fc50555d17e7167f080851aae68f1c248fcd09de981326797666d0669ead419 SHA512 fee87a2127284a2287c60b14bcd36facf061542da1321ccaa26dbe23c7e8534253434a78c8a65a0c2915bb1331acbdee78b12d02b748ec7d95a106913172a1a2
+DIST yara-python-4.5.5.gh.tar.gz 39314 BLAKE2B 743406b585f4dfb6b273fb10d13eeccb479e2f51f0642e1cdecf956ff190090ed5d44f25949d385fb6814ccac71be9b9cd6a959c0e324ca9babf3bcb35b84785 SHA512 fb73b52b22d5fc7b91eff6847e53ce794e18ca303687d237ebd805dcddc991c714d15c0103c856717004a07c5f1753c0b119dbfc07578679de823ff302276f8f

dev-python/yara-python/yara-python-4.5.5.ebuild

@@ -0,0 +1,40 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_EXT=1
+PYTHON_COMPAT=( python3_{11..14} )
+inherit distutils-r1
+
+DESCRIPTION="Python interface for a malware identification and classification tool"
+HOMEPAGE="https://github.com/VirusTotal/yara-python"
+
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/VirusTotal/yara-python.git"
+else
+	SRC_URI="https://github.com/virustotal/yara-python/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+
+RDEPEND="
+	=app-forensics/yara-$(ver_cut 1-2)*
+"
+DEPEND="${RDEPEND}"
+
+distutils_enable_tests unittest
+
+python_configure_all() {
+	cat >> setup.cfg <<-EOF
+	dynamic_linking = True
+	EOF
+}
+
+python_test() {
+	"${EPYTHON}" tests.py -v || die "Tests fail with ${EPYTHON}"
+}