app-misc/timew: add 1.9.1

Closes: https://bugs.gentoo.org/963619
Signed-off-by: Brett A C Sheffield <bacs@librecast.net>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/132
Signed-off-by: Sam James <sam@gentoo.org>

app-misc/timew/Manifest

@@ -1 +1,2 @@
 DIST timew-1.7.1.tar.gz 3102854 BLAKE2B e3ae527a5405bf27e92619f9cc02046646a8ef60ae721c1ad66e30560c9a8535e6e71388c7ea2eeb84b6b5bb8d7ce4845b77e6a36a54869e5f80021232a924ed SHA512 f28f6c47cc05d8055cc3fae9e96d1936554c685090a40f8af1995e5357947cb9bdfab0ec091f68693a566a876e06eda502de074900f7368a913e85d7e4cf87f1
+DIST timew-1.9.1.tar.gz 323991 BLAKE2B c0a9464233fd17560e5a7959fb0cf3726d475d42570345af43204d57e0fdbb0fa7b39ce4fe8c8b573b8e476d4515f6c69764fe42045b210587facfad1d6ea090 SHA512 4e69d2fda442b0ef7886cfecff4341fd7432f8f6ee6ea8f029f2f2f2d85be1fc801a32bd6d15dc8af58d482e8a999b1a9b8d0edf6b8b90ff8d3483324d31f428

app-misc/timew/timew-1.9.1.ebuild

@@ -0,0 +1,47 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake shell-completion
+
+DESCRIPTION="Tracks your time from the command line, and generates reports"
+HOMEPAGE="https://timewarrior.net/"
+SRC_URI="https://github.com/GothenburgBitFactory/timewarrior/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+src_configure() {
+	local mycmakeargs=(
+		-DTIMEW_DOCDIR=share/doc/${PF}
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${WORKDIR}"/"${P}"_build || die
+
+	eninja test
+}
+
+src_install() {
+	cmake_src_install
+
+	dodoc -r ext
+	docompress -x /usr/share/doc/${PF}/ext/{on-modify.timewarrior,README}
+
+	doman doc/man1/*.1
+	doman doc/man7/*.7
+	newbashcomp completion/timew-completion.bash timew
+	dofishcomp completion/timew.fish
+}
+
+pkg_postinst() {
+	elog "To integrate timewarrior with taskwarrior, issue the following commands:"
+	elog "cp /usr/share/doc/${PF}/ext/on-modify.timewarrior ~/.task/hooks/"
+	elog "chmod +x ~/.task/hooks/on-modify.timewarrior"
+	elog "see https://timewarrior.net/docs/taskwarrior/"
+}