app-text/evince: Version bump to 41.3

Signed-off-by: Matt Turner <mattst88@gentoo.org>

app-text/evince/Manifest

@@ -1,2 +1,3 @@
 DIST evince-40.2.tar.xz 2928072 BLAKE2B 86051e8568044ec484a7a3c036a523ee44d22e46bdf5e75c6052d3302f92a27d48cb26e2408b176cfee3fafd3879a8771f4bf29a51f6b8085c31fa28f4885660 SHA512 f3ee19053a0bc6989a50fc790d1d54747d7aac5cbf0cd1e0eaea6cb743c0ebbbdf2565e88ea995fbba31c7f97e4279f9c0fa44c386bcf635a500033f6105ca9f
 DIST evince-40.4.tar.xz 2928100 BLAKE2B 491b2333e21093b032ec9c4f24c61cdaa31e4a46ee058b0f109b0998fb7216ada2c933e6202eae1d6193caad0cfa94a77434ef042555bab7cf4aeed959be759b SHA512 dbec3828f1e8f0b9b48dd90ce605ce83312e53cbeb8f8e7358c1318f1701680a69a9bcd26b7cf1da4b53679ae11e334ce514f5df4c5bbcc976581441e0d654cd
+DIST evince-41.3.tar.xz 2889368 BLAKE2B c6ef9b4c126f938ef8b50aa65d8591e0ce02e7404dd1984bce27e0acce6e62462d42665ad19992cb2fa22afd09d6da49ecdbbb51eb209518d415966824523628 SHA512 b00422ef0fd752e5afacea2db852ad71d8d16514945a9a54c54967cecd2b1f5058b762ec53eb9057b8f583d5e1e3363c2b7ae1f4434fa6637ad45c5217f082cd

app-text/evince/evince-41.3.ebuild

@@ -0,0 +1,120 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson systemd xdg
+
+DESCRIPTION="Simple document viewer for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evince"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+# subslot = evd3.(suffix of libevdocument3)-evv3.(suffix of libevview3)
+SLOT="0/evd3.4-evv3.3"
+IUSE="cups djvu dvi gstreamer gnome gnome-keyring gtk-doc +introspection nautilus postscript spell t1lib tiff xps"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
+
+# atk used in libview
+# bundles unarr
+DEPEND="
+	dev-libs/atk
+	>=dev-libs/glib-2.44.0:2
+	>=gui-libs/libhandy-1.0:1=
+	>=dev-libs/libxml2-2.5:2
+	sys-libs/zlib:=
+	>=x11-libs/gdk-pixbuf-2.40:2
+	>=x11-libs/gtk+-3.22.0:3[cups?,introspection?]
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/cairo-1.10:=
+	>=app-text/poppler-0.76.0[cairo]
+	>=app-arch/libarchive-3.2.0
+	djvu? ( >=app-text/djvu-3.5.22:= )
+	dvi? (
+		>=app-text/libspectre-0.2:=
+		dev-libs/kpathsea:=
+		t1lib? ( >=media-libs/t1lib-5:= ) )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-libs/gst-plugins-good:1.0 )
+	gnome? ( gnome-base/gnome-desktop:3= )
+	gnome-keyring? ( >=app-crypt/libsecret-0.5 )
+	introspection? ( >=dev-libs/gobject-introspection-1:= )
+	nautilus? ( >=gnome-base/nautilus-3.28.0 )
+	postscript? ( >=app-text/libspectre-0.2:= )
+	spell? ( >=app-text/gspell-1.6.0:= )
+	tiff? ( >=media-libs/tiff-3.6:0= )
+	xps? ( >=app-text/libgxps-0.2.1:= )
+"
+RDEPEND="${DEPEND}
+	gnome-base/gvfs
+	gnome-base/librsvg
+	|| (
+		>=x11-themes/adwaita-icon-theme-2.17.1
+		>=x11-themes/hicolor-icon-theme-0.10
+	)
+"
+BDEPEND="
+	gtk-doc? ( >=dev-util/gtk-doc-1.33 )
+	app-text/docbook-xml-dtd:4.3
+	dev-libs/appstream-glib
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	xdg_src_prepare
+
+	# Do not depend on adwaita-icon-theme, bug #326855, #391859
+	# https://gitlab.freedesktop.org/xdg/default-icon-theme/issues/7
+	sed -i '/adwaita_icon_theme_dep/d' meson.build shell/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddevelopment=false
+		-Dplatform=gnome
+
+		-Dviewer=true
+		-Dpreviewer=true
+		-Dthumbnailer=true
+		$(meson_use nautilus)
+
+		-Dcomics=enabled
+		$(meson_feature djvu)
+		$(meson_feature dvi)
+		-Dpdf=enabled
+		$(meson_feature postscript ps)
+		$(meson_feature tiff)
+		$(meson_feature xps)
+
+		$(meson_use gtk-doc gtk_doc)
+		-Duser_doc=true
+		$(meson_use introspection)
+		-Ddbus=true
+		$(meson_feature gnome-keyring keyring)
+		$(meson_feature cups gtk_unix_print)
+		$(meson_feature gnome thumbnail_cache)
+		$(meson_feature gstreamer multimedia)
+		$(meson_feature spell gspell)
+
+		-Dinternal_synctex=true
+		$(meson_feature t1lib)
+
+		-Dsystemduserunitdir="$(systemd_get_userunitdir)"
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}