net-misc/gns3-gui: Remove py3.11 due to sentry-sdk losing it

Signed-off-by: Michał Górny <mgorny@gentoo.org>

net-misc/gns3-gui/gns3-gui-2.2.38-r1.ebuild

@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_11 )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 virtualx xdg
+
+DESCRIPTION="Graphical Network Simulator"
+HOMEPAGE="https://www.gns3.com/ https://github.com/GNS3/gns3-gui"
+SRC_URI="https://github.com/GNS3/gns3-gui/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+#net-misc/gns3-server version should always match gns3-gui version
+RDEPEND="
+	>=dev-python/distro-1.7.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4.17.3[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.9.4[${PYTHON_USEDEP}]
+	>=dev-python/sentry-sdk-1.12.1[${PYTHON_USEDEP}]
+	~net-misc/gns3-server-${PV}[${PYTHON_USEDEP}]
+	dev-python/PyQt5[gui,network,svg,websockets,widgets,${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# newer python packages are fine
+	sed -i -e 's/[<>=].*//' requirements.txt || die
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}