mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-06 00:48:18 -07:00
www-client/links: bump to 2.25
Package-Manager: Portage-3.0.26, Repoman-3.0.3 Signed-off-by: Ben Kohler <bkohler@gentoo.org>
This commit is contained in:
Ben Kohler
@@ -1,2 +1,3 @@
|
||||
DIST links-2.23.tar.bz2 6521143 BLAKE2B baefdadddc0d44511488ca1a085a45f3235b9c58ae6013c1efce495a33e86b96575eba6a15df4f14ea82b7d1ffb69ea312d5d5223ba9c605709bdb5d153ef6cb SHA512 3c233dab2e7e5ca72f582c5af9c5799b3d6c1a5a64d4e9e0209f78f347a245dc760c2340f71839fd42e1c9f358599b8baa12aa024938f2ab1b6424c8fb0b9a7d
|
||||
DIST links-2.24.tar.bz2 6470666 BLAKE2B f6ae42f64283e250afc2041efbb1d8680ef860ea83d0592f9f92bb90a2c2a23e470cc6be4a8538bcbed5162bfb42be30336ac48b7d19e1b4b79c64deb9073f55 SHA512 093e24d8504faf95fa9e6ce50b4e6b01284995fa8ee156b5c8b2b52b4ca3bdbcdf95965c8f9c8b72adcfbedf8a5216467c85c122778381c3b148f5696b709fd1
|
||||
DIST links-2.25.tar.bz2 6505187 BLAKE2B 3efe9d43b9a8dad498101800ccdefd094a6371a2c74b264aaaaac2abf951db38729abcf00f74a45fdb7f0d24196413996aa02cd9d2ea3ee2cf008faf4062e365 SHA512 b094e3b2096b07da8385d6021e5a5794f5b602c90ec824c48b897e6b69def6d69cb879af3008a4af43effaa7d9359bf09e4feb8ed5371bb7ff22ffcb0794f690
|
||||
|
||||
170
www-client/links/links-2.25.ebuild
Normal file
170
www-client/links/links-2.25.ebuild
Normal file
@@ -0,0 +1,170 @@
|
||||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit autotools desktop xdg-utils
|
||||
|
||||
DESCRIPTION="A fast and lightweight web browser running in both graphics and text mode"
|
||||
HOMEPAGE="http://links.twibright.com/"
|
||||
SRC_URI="http://${PN}.twibright.com/download/${P}.tar.bz2"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="2"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
|
||||
IUSE="brotli bzip2 fbcon freetype gpm ipv6 jpeg libevent livecd lzip lzma ssl suid svga tiff unicode X zlib zstd"
|
||||
|
||||
GRAPHICS_DEPEND="media-libs/libpng:0="
|
||||
|
||||
RDEPEND="
|
||||
brotli? (
|
||||
app-arch/brotli
|
||||
)
|
||||
bzip2? (
|
||||
app-arch/bzip2
|
||||
)
|
||||
fbcon? (
|
||||
${GRAPHICS_DEPEND}
|
||||
)
|
||||
freetype? (
|
||||
media-libs/fontconfig
|
||||
media-libs/freetype
|
||||
)
|
||||
gpm? (
|
||||
sys-libs/gpm
|
||||
)
|
||||
jpeg? (
|
||||
virtual/jpeg:0
|
||||
)
|
||||
libevent? (
|
||||
dev-libs/libevent:0=
|
||||
)
|
||||
livecd? (
|
||||
${GRAPHICS_DEPEND}
|
||||
sys-libs/gpm
|
||||
virtual/jpeg:0
|
||||
)
|
||||
lzip? (
|
||||
app-arch/lzip
|
||||
)
|
||||
lzma? (
|
||||
app-arch/xz-utils
|
||||
)
|
||||
ssl? (
|
||||
dev-libs/openssl:0=
|
||||
)
|
||||
svga? (
|
||||
${GRAPHICS_DEPEND}
|
||||
media-libs/svgalib
|
||||
)
|
||||
tiff? (
|
||||
media-libs/tiff:0
|
||||
)
|
||||
X? (
|
||||
${GRAPHICS_DEPEND}
|
||||
x11-libs/libXext
|
||||
)
|
||||
zlib? (
|
||||
sys-libs/zlib
|
||||
)
|
||||
zstd? (
|
||||
app-arch/zstd
|
||||
)"
|
||||
|
||||
DEPEND="${RDEPEND}
|
||||
fbcon? ( virtual/os-headers )
|
||||
livecd? ( virtual/os-headers )"
|
||||
|
||||
BDEPEND="virtual/pkgconfig"
|
||||
|
||||
IDEPEND="X? ( dev-util/desktop-file-utils )"
|
||||
|
||||
REQUIRED_USE="!livecd? ( fbcon? ( gpm ) )
|
||||
svga? ( suid )"
|
||||
|
||||
DOCS=( AUTHORS BRAILLE_HOWTO ChangeLog KEYS NEWS README SITES )
|
||||
|
||||
src_prepare() {
|
||||
use X && xdg_environment_reset
|
||||
|
||||
if use unicode; then
|
||||
pushd intl > /dev/null || die
|
||||
./gen-intl || die
|
||||
./synclang || die
|
||||
popd > /dev/null || die
|
||||
fi
|
||||
|
||||
# error: conditional "am__fastdepCXX" was never defined (for eautoreconf)
|
||||
sed -i \
|
||||
-e '/AC_PROG_CXX/s:dnl ::' \
|
||||
-e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' \
|
||||
configure.in || die #467020
|
||||
|
||||
# Upstream configure produced by broken autoconf-2.13. This also fixes
|
||||
# toolchain detection.
|
||||
mv configure.in configure.ac || die
|
||||
|
||||
default
|
||||
eautoreconf #131440 and #103483#c23
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local myconf
|
||||
|
||||
if use livecd; then
|
||||
export ac_cv_lib_gpm_Gpm_Open=yes
|
||||
myconf+=' --with-fb --with-libjpeg'
|
||||
else
|
||||
export ac_cv_lib_gpm_Gpm_Open=$(usex gpm)
|
||||
fi
|
||||
|
||||
if use X || use fbcon || use svga || use livecd; then
|
||||
myconf+=' --enable-graphics'
|
||||
fi
|
||||
|
||||
econf \
|
||||
--without-directfb \
|
||||
--without-librsvg \
|
||||
$(use_with brotli) \
|
||||
$(use_with bzip2) \
|
||||
$(use_with fbcon fb) \
|
||||
$(use_with freetype) \
|
||||
$(use_with ipv6) \
|
||||
$(use_with jpeg libjpeg) \
|
||||
$(use_with libevent) \
|
||||
$(use_with lzip) \
|
||||
$(use_with lzma) \
|
||||
$(use_with ssl) \
|
||||
$(use_with svga svgalib) \
|
||||
$(use_with tiff libtiff) \
|
||||
$(use_with X x) \
|
||||
$(use_with zlib) \
|
||||
$(use_with zstd) \
|
||||
${myconf}
|
||||
}
|
||||
|
||||
src_install() {
|
||||
HTML_DOCS="doc/links_cal/*"
|
||||
default
|
||||
|
||||
if use X; then
|
||||
newicon Links_logo.png links.png
|
||||
make_desktop_entry 'links -g %u' Links links 'Network;WebBrowser'
|
||||
local d="${ED}"/usr/share/applications
|
||||
echo 'MimeType=x-scheme-handler/http;' >> "${d}"/*.desktop || die
|
||||
if use ssl; then
|
||||
sed -i -e 's:x-scheme-handler/http;:&x-scheme-handler/https;:' \
|
||||
"${d}"/*.desktop || die
|
||||
fi
|
||||
fi
|
||||
|
||||
use suid && fperms 4755 /usr/bin/links
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
use X && xdg_desktop_database_update
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
use X && xdg_desktop_database_update
|
||||
}
|
||||
Reference in New Issue
Block a user