dev-util/intel-graphics-system-controller: add 1.3.2

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

dev-util/intel-graphics-system-controller/Manifest

@@ -1 +1,2 @@
 DIST intel-graphics-system-controller-1.3.1.tar.gz 209189 BLAKE2B 70c67ceb9d1c6de4d64cd229eb11ca172ae2167f6ef8f650f1de3bd5b8bb5984a7c385ee0a0d2cada1ef253eb1326b45924cc83a83e30f61337ef938bb6026e9 SHA512 62490aab0bcee4efd67e76293b9b5ee0b5bb92431dd5aeb042cfee352a767ed00d8e424cbff4ec60aaca19e758c50a13ebb222bf4520c74741d6eee3f40b932c
+DIST intel-graphics-system-controller-1.3.2.tar.gz 209256 BLAKE2B 4a53c1ad69b665d992df8511eca3ea87df33a5ac2b3b03291e5c0f7596fc596f5a5800d54c5fb1a7db1ddcbd62881dcb2618a9add915a5289d02a1f951b7ec32 SHA512 c7027540a689bd97235c4f73e11820e93d1612a6d357c4443e7eb4ba6d5cd8039fef24ec008eea5f77439d8778fff4aa61b35a1f31cfd5479d5dccbbd3fc9ab3

dev-util/intel-graphics-system-controller/intel-graphics-system-controller-1.3.2.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="igsc"
+MY_P="${MY_PN}-${PV}"
+PYTHON_COMPAT=( python3_{10..15} )
+
+inherit cmake python-any-r1
+
+DESCRIPTION="Intel graphics system controller firmware update library"
+HOMEPAGE="https://github.com/intel/igsc"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/refs/tags/V${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Apache-2.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="+cli doc"
+
+RDEPEND=">=dev-libs/metee-6.2.5:="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		${PYTHON_DEPS}
+		app-text/doxygen
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
+	)
+"
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CLI="$(usex cli)"
+		-DENABLE_DOCS="$(usex doc)"
+		-DENABLE_PERF="OFF"
+		-DENABLE_WERROR="OFF"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DENABLE_TESTS="OFF"
+	)
+
+	cmake_src_configure
+}